xref: /rk3399_ARM-atf/bl2/bl2.ld.S (revision 649dbf6f3666fa4ec8bad318d01b946fb89063e0) 
1/*
2 * Copyright (c) 2013-2014, ARM Limited and Contributors. All rights reserved.
3 *
4 * Redistribution and use in source and binary forms, with or without
5 * modification, are permitted provided that the following conditions are met:
6 *
7 * Redistributions of source code must retain the above copyright notice, this
8 * list of conditions and the following disclaimer.
9 *
10 * Redistributions in binary form must reproduce the above copyright notice,
11 * this list of conditions and the following disclaimer in the documentation
12 * and/or other materials provided with the distribution.
13 *
14 * Neither the name of ARM nor the names of its contributors may be used
15 * to endorse or promote products derived from this software without specific
16 * prior written permission.
17 *
18 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
19 * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
20 * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
21 * ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE
22 * LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
23 * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
24 * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
25 * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
26 * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
27 * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
28 * POSSIBILITY OF SUCH DAMAGE.
29 */
30
31#include <platform_def.h>
32
33OUTPUT_FORMAT(PLATFORM_LINKER_FORMAT)
34OUTPUT_ARCH(PLATFORM_LINKER_ARCH)
35ENTRY(bl2_entrypoint)
36
37MEMORY {
38    RAM (rwx): ORIGIN = BL2_BASE, LENGTH = BL2_LIMIT - BL2_BASE
39}
40
41
42SECTIONS
43{
44    . = BL2_BASE;
45    ASSERT(. == ALIGN(4096),
46           "BL2_BASE address is not aligned on a page boundary.")
47
48    ro . : {
49        __RO_START__ = .;
50        *bl2_entrypoint.o(.text*)
51        *(.text*)
52        *(.rodata*)
53
54        /* Ensure 8-byte alignment for descriptors and ensure inclusion */
55        . = ALIGN(8);
56        __PARSER_LIB_DESCS_START__ = .;
57        KEEP(*(.img_parser_lib_descs))
58        __PARSER_LIB_DESCS_END__ = .;
59
60        *(.vectors)
61        __RO_END_UNALIGNED__ = .;
62        /*
63         * Memory page(s) mapped to this section will be marked as
64         * read-only, executable.  No RW data from the next section must
65         * creep in.  Ensure the rest of the current memory page is unused.
66         */
67        . = NEXT(4096);
68        __RO_END__ = .;
69    } >RAM
70
71    /*
72     * Define a linker symbol to mark start of the RW memory area for this
73     * image.
74     */
75    __RW_START__ = . ;
76
77    .data . : {
78        __DATA_START__ = .;
79        *(.data*)
80        __DATA_END__ = .;
81    } >RAM
82
83    stacks (NOLOAD) : {
84        __STACKS_START__ = .;
85        *(tzfw_normal_stacks)
86        __STACKS_END__ = .;
87    } >RAM
88
89    /*
90     * The .bss section gets initialised to 0 at runtime.
91     * Its base address must be 16-byte aligned.
92     */
93    .bss : ALIGN(16) {
94        __BSS_START__ = .;
95        *(SORT_BY_ALIGNMENT(.bss*))
96        *(COMMON)
97        __BSS_END__ = .;
98    } >RAM
99
100    /*
101     * The xlat_table section is for full, aligned page tables (4K).
102     * Removing them from .bss avoids forcing 4K alignment on
103     * the .bss section and eliminates the unecessary zero init
104     */
105    xlat_table (NOLOAD) : {
106        *(xlat_table)
107    } >RAM
108
109#if USE_COHERENT_MEM
110    /*
111     * The base address of the coherent memory section must be page-aligned (4K)
112     * to guarantee that the coherent data are stored on their own pages and
113     * are not mixed with normal data.  This is required to set up the correct
114     * memory attributes for the coherent data page tables.
115     */
116    coherent_ram (NOLOAD) : ALIGN(4096) {
117        __COHERENT_RAM_START__ = .;
118        *(tzfw_coherent_mem)
119        __COHERENT_RAM_END_UNALIGNED__ = .;
120        /*
121         * Memory page(s) mapped to this section will be marked
122         * as device memory.  No other unexpected data must creep in.
123         * Ensure the rest of the current memory page is unused.
124         */
125        . = NEXT(4096);
126        __COHERENT_RAM_END__ = .;
127    } >RAM
128#endif
129
130    /*
131     * Define a linker symbol to mark end of the RW memory area for this
132     * image.
133     */
134    __RW_END__ = .;
135    __BL2_END__ = .;
136
137    __BSS_SIZE__ = SIZEOF(.bss);
138
139#if USE_COHERENT_MEM
140    __COHERENT_RAM_UNALIGNED_SIZE__ =
141        __COHERENT_RAM_END_UNALIGNED__ - __COHERENT_RAM_START__;
142#endif
143
144    ASSERT(. <= BL2_LIMIT, "BL2 image has exceeded its limit.")
145}
146