xref: /rk3399_ARM-atf/bl2/bl2.ld.S (revision 0a0a7a9ac82cb79af91f098cedc69cc67bca3978) 
1/*
2 * Copyright (c) 2013-2020, ARM Limited and Contributors. All rights reserved.
3 *
4 * SPDX-License-Identifier: BSD-3-Clause
5 */
6
7#include <common/bl_common.ld.h>
8#include <lib/xlat_tables/xlat_tables_defs.h>
9
10OUTPUT_FORMAT(PLATFORM_LINKER_FORMAT)
11OUTPUT_ARCH(PLATFORM_LINKER_ARCH)
12ENTRY(bl2_entrypoint)
13
14MEMORY {
15    RAM (rwx): ORIGIN = BL2_BASE, LENGTH = BL2_LIMIT - BL2_BASE
16}
17
18
19SECTIONS
20{
21    . = BL2_BASE;
22    ASSERT(. == ALIGN(PAGE_SIZE),
23           "BL2_BASE address is not aligned on a page boundary.")
24
25#if SEPARATE_CODE_AND_RODATA
26    .text . : {
27        __TEXT_START__ = .;
28        *bl2_entrypoint.o(.text*)
29        *(SORT_BY_ALIGNMENT(.text*))
30        *(.vectors)
31        . = ALIGN(PAGE_SIZE);
32        __TEXT_END__ = .;
33     } >RAM
34
35     /* .ARM.extab and .ARM.exidx are only added because Clang need them */
36     .ARM.extab . : {
37        *(.ARM.extab* .gnu.linkonce.armextab.*)
38     } >RAM
39
40     .ARM.exidx . : {
41        *(.ARM.exidx* .gnu.linkonce.armexidx.*)
42     } >RAM
43
44    .rodata . : {
45        __RODATA_START__ = .;
46        *(SORT_BY_ALIGNMENT(.rodata*))
47
48	RODATA_COMMON
49
50        . = ALIGN(PAGE_SIZE);
51        __RODATA_END__ = .;
52    } >RAM
53#else
54    ro . : {
55        __RO_START__ = .;
56        *bl2_entrypoint.o(.text*)
57        *(SORT_BY_ALIGNMENT(.text*))
58        *(SORT_BY_ALIGNMENT(.rodata*))
59
60	RODATA_COMMON
61
62        *(.vectors)
63        __RO_END_UNALIGNED__ = .;
64        /*
65         * Memory page(s) mapped to this section will be marked as
66         * read-only, executable.  No RW data from the next section must
67         * creep in.  Ensure the rest of the current memory page is unused.
68         */
69        . = ALIGN(PAGE_SIZE);
70        __RO_END__ = .;
71    } >RAM
72#endif
73
74    /*
75     * Define a linker symbol to mark start of the RW memory area for this
76     * image.
77     */
78    __RW_START__ = . ;
79
80    /*
81     * .data must be placed at a lower address than the stacks if the stack
82     * protector is enabled. Alternatively, the .data.stack_protector_canary
83     * section can be placed independently of the main .data section.
84     */
85    .data . : {
86        __DATA_START__ = .;
87        *(SORT_BY_ALIGNMENT(.data*))
88        __DATA_END__ = .;
89    } >RAM
90
91    stacks (NOLOAD) : {
92        __STACKS_START__ = .;
93        *(tzfw_normal_stacks)
94        __STACKS_END__ = .;
95    } >RAM
96
97    /*
98     * The .bss section gets initialised to 0 at runtime.
99     * Its base address should be 16-byte aligned for better performance of the
100     * zero-initialization code.
101     */
102    .bss : ALIGN(16) {
103        __BSS_START__ = .;
104        *(SORT_BY_ALIGNMENT(.bss*))
105        *(COMMON)
106        __BSS_END__ = .;
107    } >RAM
108
109    XLAT_TABLE_SECTION >RAM
110
111#if USE_COHERENT_MEM
112    /*
113     * The base address of the coherent memory section must be page-aligned (4K)
114     * to guarantee that the coherent data are stored on their own pages and
115     * are not mixed with normal data.  This is required to set up the correct
116     * memory attributes for the coherent data page tables.
117     */
118    coherent_ram (NOLOAD) : ALIGN(PAGE_SIZE) {
119        __COHERENT_RAM_START__ = .;
120        *(tzfw_coherent_mem)
121        __COHERENT_RAM_END_UNALIGNED__ = .;
122        /*
123         * Memory page(s) mapped to this section will be marked
124         * as device memory.  No other unexpected data must creep in.
125         * Ensure the rest of the current memory page is unused.
126         */
127        . = ALIGN(PAGE_SIZE);
128        __COHERENT_RAM_END__ = .;
129    } >RAM
130#endif
131
132    /*
133     * Define a linker symbol to mark end of the RW memory area for this
134     * image.
135     */
136    __RW_END__ = .;
137    __BL2_END__ = .;
138
139    __BSS_SIZE__ = SIZEOF(.bss);
140
141#if USE_COHERENT_MEM
142    __COHERENT_RAM_UNALIGNED_SIZE__ =
143        __COHERENT_RAM_END_UNALIGNED__ - __COHERENT_RAM_START__;
144#endif
145
146    ASSERT(. <= BL2_LIMIT, "BL2 image has exceeded its limit.")
147}
148