xref: /OK3568_Linux_fs/yocto/poky/meta/recipes-support/attr/acl_2.3.1.bb (revision 4882a59341e53eb6f0b4789bf948001014eff981) 
1SUMMARY = "Utilities for managing POSIX Access Control Lists"
2DESCRIPTION = "ACL allows you to provide different levels of access to files \
3and folders for different users."
4
5HOMEPAGE = "http://savannah.nongnu.org/projects/acl/"
6BUGTRACKER = "http://savannah.nongnu.org/bugs/?group=acl"
7
8SECTION = "libs"
9
10LICENSE = "LGPL-2.1-or-later & GPL-2.0-or-later"
11LICENSE:${PN} = "GPL-2.0-or-later"
12LICENSE:lib${BPN} = "LGPL-2.1-or-later"
13LIC_FILES_CHKSUM = "file://doc/COPYING;md5=c781d70ed2b4d48995b790403217a249 \
14                    file://doc/COPYING.LGPL;md5=9e9a206917f8af112da634ce3ab41764"
15
16DEPENDS = "attr"
17
18SRC_URI = "${SAVANNAH_GNU_MIRROR}/acl/${BP}.tar.gz \
19           file://run-ptest \
20           file://0001-tests-do-not-hardcode-the-build-path-into-a-helper-l.patch \
21           file://0001-test-patch-out-failing-bits.patch \
22           "
23
24SRC_URI[sha256sum] = "760c61c68901b37fdd5eefeeaf4c0c7a26bdfdd8ac747a1edff1ce0e243c11af"
25
26inherit autotools gettext ptest
27
28PACKAGES =+ "lib${BPN}"
29
30FILES:lib${BPN} = "${libdir}/lib*${SOLIBS}"
31
32PTEST_BUILD_HOST_FILES = "builddefs"
33PTEST_BUILD_HOST_PATTERN = "^RPM"
34
35do_compile_ptest() {
36        oe_runmake libtestlookup.la
37}
38
39do_install_ptest() {
40	cp -rf ${S}/test/ ${D}${PTEST_PATH}
41	cp -rf ${S}/build-aux/ ${D}${PTEST_PATH}
42        mkdir -p ${D}${PTEST_PATH}/.libs
43	cp -rf ${B}/.libs/libtestlookup* ${D}${PTEST_PATH}/.libs
44        cp ${B}/Makefile ${D}${PTEST_PATH}
45
46        sed -e 's,--sysroot=${STAGING_DIR_TARGET},,g' \
47            -e 's|${DEBUG_PREFIX_MAP}||g' \
48            -e 's:${HOSTTOOLS_DIR}/::g' \
49            -e 's:${RECIPE_SYSROOT_NATIVE}::g' \
50            -e 's:${BASE_WORKDIR}/${MULTIMACH_TARGET_SYS}::g' \
51            -i ${D}${PTEST_PATH}/Makefile
52
53        sed -i "s|^srcdir =.*|srcdir = \.|g" ${D}${PTEST_PATH}/Makefile
54        sed -i "s|^abs_srcdir =.*|abs_srcdir = \.|g" ${D}${PTEST_PATH}/Makefile
55        sed -i "s|^abs_top_srcdir =.*|abs_top_srcdir = \.\.|g" ${D}${PTEST_PATH}/Makefile
56        sed -i "s|^Makefile:.*|Makefile:|g" ${D}${PTEST_PATH}/Makefile
57
58        rm ${D}${PTEST_PATH}/.libs/libtestlookup.lai
59}
60
61RDEPENDS:${PN}-ptest = "acl \
62                        bash \
63                        coreutils \
64                        perl \
65                        perl-module-filehandle \
66                        perl-module-getopt-std \
67                        perl-module-posix \
68                        shadow \
69                        make \
70                        gawk \
71                        e2fsprogs-mke2fs \
72                        perl-module-cwd \
73                        perl-module-file-basename \
74                        perl-module-file-path \
75                        perl-module-file-spec \
76                       "
77
78BBCLASSEXTEND = "native nativesdk"
79