xref: /OK3568_Linux_fs/yocto/poky/meta/recipes-kernel/lttng/lttng-ust_2.13.5.bb (revision 4882a59341e53eb6f0b4789bf948001014eff981) 
1SUMMARY = "Linux Trace Toolkit Userspace Tracer 2.x"
2DESCRIPTION = "The LTTng UST 2.x package contains the userspace tracer library to trace userspace codes."
3HOMEPAGE = "http://lttng.org/ust"
4BUGTRACKER = "https://bugs.lttng.org/projects/lttng-ust"
5
6LICENSE = "LGPL-2.1-or-later & MIT & GPL-2.0-only"
7LIC_FILES_CHKSUM = "file://LICENSE;md5=a46577a38ad0c36ff6ff43ccf40c480f"
8
9PYTHON_OPTION = "am_cv_python_pyexecdir='${PYTHON_SITEPACKAGES_DIR}' \
10                 am_cv_python_pythondir='${PYTHON_SITEPACKAGES_DIR}' \
11                 PYTHON_INCLUDE='-I${STAGING_INCDIR}/python${PYTHON_BASEVERSION}${PYTHON_ABI}' \
12"
13
14inherit autotools lib_package manpages python3native pkgconfig
15
16include lttng-platforms.inc
17
18EXTRA_OECONF = "--disable-numa"
19CPPFLAGS:append:arm = "${@oe.utils.vartrue('DEBUG_BUILD', '-DUATOMIC_NO_LINK_ERROR', '', d)}"
20
21DEPENDS = "liburcu util-linux"
22RDEPENDS:${PN}-bin = "python3-core"
23
24# For backwards compatibility after rename
25RPROVIDES:${PN} = "lttng2-ust"
26RREPLACES:${PN} = "lttng2-ust"
27RCONFLICTS:${PN} = "lttng2-ust"
28
29PE = "2"
30
31SRC_URI = "https://lttng.org/files/lttng-ust/lttng-ust-${PV}.tar.bz2 \
32           file://0001-python-lttngust-Makefile.am-Add-install-lib-to-setup.patch \
33           file://0001-lttng-ust-common-link-with-liburcu-explicitly.patch \
34           file://0001-Makefile.am-update-rpath-link.patch \
35           "
36
37SRC_URI[sha256sum] = "f1d7bb4984a3dc5dacd3b7bcb4c10c04b041b0eecd7cba1fef3d8f86aff02bd6"
38
39CVE_PRODUCT = "ust"
40
41PACKAGECONFIG[examples] = "--enable-examples, --disable-examples,"
42PACKAGECONFIG[manpages] = "--enable-man-pages, --disable-man-pages, asciidoc-native xmlto-native libxslt-native"
43PACKAGECONFIG[python3-agent] = "--enable-python-agent ${PYTHON_OPTION}, --disable-python-agent, python3, python3"
44
45FILES:${PN} += " ${PYTHON_SITEPACKAGES_DIR}/*"
46FILES:${PN}-staticdev += " ${PYTHON_SITEPACKAGES_DIR}/*.a"
47FILES:${PN}-dev += " ${PYTHON_SITEPACKAGES_DIR}/*.la"
48
49do_install:append() {
50        # Patch python tools to use Python 3; they should be source compatible, but
51        # still refer to Python 2 in the shebang
52        sed -i -e '1s,#!.*python.*,#!${bindir}/python3,' ${D}${bindir}/lttng-gen-tp
53}
54