xref: /OK3568_Linux_fs/yocto/poky/meta/recipes-kernel/linux/linux-yocto-rt_5.15.bb (revision 4882a59341e53eb6f0b4789bf948001014eff981) 
1KBRANCH ?= "v5.15/standard/preempt-rt/base"
2
3require recipes-kernel/linux/linux-yocto.inc
4
5# Skip processing of this recipe if it is not explicitly specified as the
6# PREFERRED_PROVIDER for virtual/kernel. This avoids errors when trying
7# to build multiple virtual/kernel providers, e.g. as dependency of
8# core-image-rt-sdk, core-image-rt.
9python () {
10    if d.getVar("KERNEL_PACKAGE_NAME") == "kernel" and d.getVar("PREFERRED_PROVIDER_virtual/kernel") != "linux-yocto-rt":
11        raise bb.parse.SkipRecipe("Set PREFERRED_PROVIDER_virtual/kernel to linux-yocto-rt to enable it")
12}
13
14SRCREV_machine ?= "e1ca9a177aff19013178aa30a8eccb4d7b2b67d7"
15SRCREV_meta ?= "441f5fe00073620cec471166cf6e94c4ef9c69b2"
16
17SRC_URI = "git://git.yoctoproject.org/linux-yocto.git;branch=${KBRANCH};name=machine \
18           git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-5.15;destsuffix=${KMETA}"
19
20LINUX_VERSION ?= "5.15.103"
21
22LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
23
24DEPENDS += "${@bb.utils.contains('ARCH', 'x86', 'elfutils-native', '', d)}"
25DEPENDS += "openssl-native util-linux-native"
26
27PV = "${LINUX_VERSION}+git${SRCPV}"
28
29KMETA = "kernel-meta"
30KCONF_BSP_AUDIT_LEVEL = "1"
31
32LINUX_KERNEL_TYPE = "preempt-rt"
33
34COMPATIBLE_MACHINE = "^(qemux86|qemux86-64|qemuarm|qemuarmv5|qemuarm64|qemuppc|qemumips)$"
35
36KERNEL_DEVICETREE:qemuarmv5 = "versatile-pb.dtb"
37
38# Functionality flags
39KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc features/taskstats/taskstats.scc"
40KERNEL_FEATURES:append = " ${KERNEL_EXTRA_FEATURES}"
41KERNEL_FEATURES:append:qemuall=" cfg/virtio.scc features/drm-bochs/drm-bochs.scc"
42KERNEL_FEATURES:append:qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc"
43KERNEL_FEATURES:append:qemux86-64=" cfg/sound.scc cfg/paravirt_kvm.scc"
44KERNEL_FEATURES:append = "${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/scsi/scsi-debug.scc", "", d)}"
45KERNEL_FEATURES:append = "${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/gpio/mockup.scc", "", d)}"
46