xref: /OK3568_Linux_fs/yocto/poky/meta/classes/nativesdk.bbclass (revision 4882a59341e53eb6f0b4789bf948001014eff981) 
1# SDK packages are built either explicitly by the user,
2# or indirectly via dependency.  No need to be in 'world'.
3EXCLUDE_FROM_WORLD = "1"
4
5STAGING_BINDIR_TOOLCHAIN = "${STAGING_DIR_NATIVE}${bindir_native}/${SDK_ARCH}${SDK_VENDOR}-${SDK_OS}"
6
7# libc for the SDK can be different to that of the target
8NATIVESDKLIBC ?= "libc-glibc"
9LIBCOVERRIDE = ":${NATIVESDKLIBC}"
10CLASSOVERRIDE = "class-nativesdk"
11MACHINEOVERRIDES = ""
12MACHINE_FEATURES = ""
13
14MULTILIBS = ""
15
16# we need consistent staging dir whether or not multilib is enabled
17STAGING_DIR_HOST = "${WORKDIR}/recipe-sysroot"
18STAGING_DIR_TARGET = "${WORKDIR}/recipe-sysroot"
19RECIPE_SYSROOT = "${WORKDIR}/recipe-sysroot"
20
21#
22# Update PACKAGE_ARCH and PACKAGE_ARCHS
23#
24PACKAGE_ARCH = "${SDK_ARCH}-${SDKPKGSUFFIX}"
25PACKAGE_ARCHS = "${SDK_PACKAGE_ARCHS}"
26
27#
28# We need chrpath >= 0.14 to ensure we can deal with 32 and 64 bit
29# binaries
30#
31DEPENDS:append = " chrpath-replacement-native"
32EXTRANATIVEPATH += "chrpath-native"
33
34PKGDATA_DIR = "${PKGDATA_DIR_SDK}"
35
36HOST_ARCH = "${SDK_ARCH}"
37HOST_VENDOR = "${SDK_VENDOR}"
38HOST_OS = "${SDK_OS}"
39HOST_PREFIX = "${SDK_PREFIX}"
40HOST_CC_ARCH = "${SDK_CC_ARCH}"
41HOST_LD_ARCH = "${SDK_LD_ARCH}"
42HOST_AS_ARCH = "${SDK_AS_ARCH}"
43#HOST_SYS = "${HOST_ARCH}${TARGET_VENDOR}-${HOST_OS}"
44
45TARGET_ARCH = "${SDK_ARCH}"
46TARGET_VENDOR = "${SDK_VENDOR}"
47TARGET_OS = "${SDK_OS}"
48TARGET_PREFIX = "${SDK_PREFIX}"
49TARGET_CC_ARCH = "${SDK_CC_ARCH}"
50TARGET_LD_ARCH = "${SDK_LD_ARCH}"
51TARGET_AS_ARCH = "${SDK_AS_ARCH}"
52TARGET_CPPFLAGS = "${BUILDSDK_CPPFLAGS}"
53TARGET_CFLAGS = "${BUILDSDK_CFLAGS}"
54TARGET_CXXFLAGS = "${BUILDSDK_CXXFLAGS}"
55TARGET_LDFLAGS = "${BUILDSDK_LDFLAGS}"
56TARGET_FPU = ""
57EXTRA_OECONF_GCC_FLOAT = ""
58TUNE_FEATURES = ""
59
60CPPFLAGS = "${BUILDSDK_CPPFLAGS}"
61CFLAGS = "${BUILDSDK_CFLAGS}"
62CXXFLAGS = "${BUILDSDK_CXXFLAGS}"
63LDFLAGS = "${BUILDSDK_LDFLAGS}"
64
65# Change to place files in SDKPATH
66base_prefix = "${SDKPATHNATIVE}"
67prefix = "${SDKPATHNATIVE}${prefix_nativesdk}"
68exec_prefix = "${SDKPATHNATIVE}${prefix_nativesdk}"
69baselib = "lib"
70sbindir = "${bindir}"
71
72export PKG_CONFIG_DIR = "${STAGING_DIR_HOST}${libdir}/pkgconfig"
73export PKG_CONFIG_SYSROOT_DIR = "${STAGING_DIR_HOST}"
74
75python nativesdk_virtclass_handler () {
76    pn = e.data.getVar("PN")
77    if not (pn.endswith("-nativesdk") or pn.startswith("nativesdk-")):
78        return
79
80    # Set features here to prevent appends and distro features backfill
81    # from modifying nativesdk distro features
82    features = set(d.getVar("DISTRO_FEATURES_NATIVESDK").split())
83    filtered = set(bb.utils.filter("DISTRO_FEATURES", d.getVar("DISTRO_FEATURES_FILTER_NATIVESDK"), d).split())
84    d.setVar("DISTRO_FEATURES", " ".join(sorted(features | filtered)))
85
86    e.data.setVar("MLPREFIX", "nativesdk-")
87    e.data.setVar("PN", "nativesdk-" + e.data.getVar("PN").replace("-nativesdk", "").replace("nativesdk-", ""))
88}
89
90python () {
91    pn = d.getVar("PN")
92    if not pn.startswith("nativesdk-"):
93        return
94
95    import oe.classextend
96
97    clsextend = oe.classextend.NativesdkClassExtender("nativesdk", d)
98    clsextend.rename_packages()
99    clsextend.rename_package_variables((d.getVar("PACKAGEVARS") or "").split())
100
101    clsextend.map_depends_variable("DEPENDS")
102    clsextend.map_packagevars()
103    clsextend.map_variable("PROVIDES")
104    clsextend.map_regexp_variable("PACKAGES_DYNAMIC")
105    d.setVar("LIBCEXTENSION", "")
106    d.setVar("ABIEXTENSION", "")
107}
108
109addhandler nativesdk_virtclass_handler
110nativesdk_virtclass_handler[eventmask] = "bb.event.RecipePreFinalise"
111
112do_packagedata[stamp-extra-info] = ""
113
114USE_NLS = "${SDKUSE_NLS}"
115
116OLDEST_KERNEL = "${SDK_OLDEST_KERNEL}"
117
118PATH:prepend = "${COREBASE}/scripts/nativesdk-intercept:"
119