xref: /OK3568_Linux_fs/yocto/meta-qt5/recipes-qt/maliit/maliit-framework-qt5_git.bb (revision 4882a59341e53eb6f0b4789bf948001014eff981) 
1DESCRIPTION = "A virtual keyboard for touch-screen based user interfaces"
2HOMEPAGE = "https://wiki.maliit.org/Main_Page"
3
4LICENSE = "LGPL-2.1-only"
5LIC_FILES_CHKSUM = "file://LICENSE.LGPL;md5=5c917f6ce94ceb8d8d5e16e2fca5b9ad"
6
7inherit qmake5 qmake5_paths pkgconfig
8
9SRC_URI = "git://github.com/maliit/framework.git;branch=master;protocol=https \
10           file://0001-Fix-MALIIT_INSTALL_PRF-to-allow-the-build-with-opene.patch \
11           file://maliit-server.desktop \
12           file://0001-config.pri-Use-O1-optimization-in-DEBUG-flags.patch \
13           file://0001-Drop-tr1-namespace-its-not-there-in-c-11-and-newer.patch \
14           file://0001-examples-plugins-Replace-obsolete-screenGeometry.patch \
15           file://0001-Fix-test-installations.patch \
16           "
17
18SRCREV = "60b1b10de14f932420313c547ab801daf522d539"
19PV = "0.99.0+git${SRCPV}"
20
21
22PACKAGES =+ "${PN}-gtk"
23GTKIMMODULES_PACKAGES = "${PN}-gtk"
24
25DEPENDS = "qtdeclarative"
26
27RRECOMMENDS:${PN} = "maliit-plugins-qt5"
28
29FILES:${PN} += "\
30    ${libdir}/*.so* \
31    ${bindir} \
32    ${datadir}/applications/maliit-server.desktop \
33    ${datadir}/dbus-1 \
34    ${OE_QMAKE_PATH_PLUGINS}/platforminputcontexts \
35"
36
37FILES:${PN}-dbg += "\
38    ${libdir}/maliit-framework-tests \
39"
40
41FILES:${PN}-dev += "\
42    ${includedir}/maliit \
43    ${libdir}/pkgconfig \
44    ${OE_QMAKE_PATH_QT_ARCHDATA}/mkspecs \
45"
46
47EXTRA_QMAKEVARS_PRE = "\
48    PREFIX=${OE_QMAKE_PATH_PREFIX} \
49    LIBDIR=${OE_QMAKE_PATH_LIBS} \
50    DATADIR=${OE_QMAKE_PATH_DATA} \
51    QT_INSTALL_PLUGINS=${OE_QMAKE_PATH_PLUGINS} \
52    MALIIT_INSTALL_PRF=${OE_QMAKE_PATH_QT_ARCHDATA}/mkspecs/features \
53    SCHEMADIR=${sysconfdir}/gconf/schemas \
54    CONFIG+=disable-gconf \
55    CONFIG+=disable-gtk-cache-update \
56    CONFIG+=local-install \
57    CONFIG+=nosdk \
58    CONFIG+=nodoc \
59    CONFIG+=noxcb \
60    CONFIG+=enable-dbus-activation \
61    CONFIG+=qt5-inputcontext \
62"
63
64# tests fail to build with gcc12/clang
65EXTRA_QMAKEVARS_PRE:append = " CONFIG+=notests"
66
67EXTRA_OEMAKE += "INSTALL_ROOT=${D}"
68
69do_install:append() {
70    #Fix absolute paths
71    sed -i -e "s|/usr|${STAGING_DIR_TARGET}${prefix}|" ${D}/${OE_QMAKE_PATH_QT_ARCHDATA}/mkspecs/features/maliit-framework.prf
72    sed -i -e "s|/usr|${STAGING_DIR_TARGET}${prefix}|" ${D}/${OE_QMAKE_PATH_QT_ARCHDATA}/mkspecs/features/maliit-plugins.prf
73
74    install -d ${D}${datadir}/applications
75    install -m 644 ${WORKDIR}/maliit-server.desktop ${D}${datadir}/applications
76}
77
78pkg_postinst_ontarget:${PN} () {
79#!/bin/sh
80# should run online
81echo "export QT_IM_MODULE=Maliit" >> /etc/xprofile
82ln -s /usr/share/applications/maliit-server.desktop /etc/xdg/autostart/maliit-server.desktop
83}
84
85pkg_postrm:${PN} () {
86#!/bin/sh
87# should run online
88if [ "x$D" = "x" ]; then
89    if [ -e "/etc/xprofile" ]; then
90        sed -i -e "g|export QT_IM_MODULE=Maliit|d" /etc/xprofile
91    fi
92    rm -f /etc/xdg/autostart/maliit-server.desktop
93fi
94}
95
96S = "${WORKDIR}/git"
97