xref: /OK3568_Linux_fs/yocto/meta-openembedded/meta-webserver/recipes-httpd/monkey/monkey_1.6.9.bb (revision 4882a59341e53eb6f0b4789bf948001014eff981) 
1SUMMARY = "Fast and Lightweight HTTP Server for Linux"
2HOMEPAGE = "http://monkey-project.com"
3BUGTRACKER = "https://github.com/monkey/monkey/issues"
4
5LICENSE = "Apache-2.0"
6LIC_FILES_CHKSUM = "file://LICENSE;md5=2ee41112a44fe7014dce33e26468ba93"
7
8SECTION = "net"
9
10SRC_URI = "git://github.com/monkey/monkey;branch=1.6;protocol=https \
11           file://0001-fastcgi-Use-value-instead-of-address-of-sin6_port.patch \
12           file://monkey.service \
13           file://monkey.init"
14
15SRCREV = "7999b487fded645381d387ec0e057e92407b0d2c"
16S = "${WORKDIR}/git"
17
18UPSTREAM_CHECK_URI = "https://github.com/monkey/monkey/releases"
19UPSTREAM_CHECK_REGEX = "v(?P<pver>\d+(\.\d+)+).tar.gz"
20
21EXTRA_OECMAKE = "-DINSTALL_LOGDIR=${localstatedir}/log/monkey/ \
22                 -DPID_FILE=/run/monkey.pid \
23                 -DINSTALL_SYSCONFDIR=${sysconfdir}/monkey/ \
24                 -DWITH_PLUGINS=* \
25                 -DWITHOUT_PLUGINS=mbedtls \
26                 -DWITH_DEBUG=1 \
27                 -DDEFAULT_USER='www-data' \
28                 -DWITH_SYSTEM_MALLOC=1 \
29                "
30
31EXTRA_OECMAKE:append:libc-musl = " -DWITH_MUSL=1 "
32
33# GCC-10+ defaults to -fno-common
34CFLAGS += "-fcommon"
35
36DISABLE_STATIC = ""
37
38inherit cmake pkgconfig update-rc.d systemd
39
40OECMAKE_GENERATOR = "Unix Makefiles"
41
42do_install:append() {
43    rmdir ${D}${localstatedir}/log/${BPN} ${D}${localstatedir}/run ${D}${localstatedir}/log
44    rmdir --ignore-fail-on-non-empty ${D}${localstatedir}
45    install -Dm 0755 ${WORKDIR}/monkey.init ${D}${sysconfdir}/init.d/monkey
46    # Create /var/log/monkey in runtime.
47    if [ "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}" ]; then
48        install -d ${D}${nonarch_libdir}/tmpfiles.d
49        echo "d ${localstatedir}/log/${BPN} 0755 ${BPN} ${BPN} -" > ${D}${nonarch_libdir}/tmpfiles.d/${BPN}.conf
50    fi
51    if [ "${@bb.utils.filter('DISTRO_FEATURES', 'sysvinit', d)}" ]; then
52        install -d ${D}${sysconfdir}/default/volatiles
53        echo "d ${BPN} ${BPN} 0755 ${localstatedir}/log/${BPN} none" > ${D}${sysconfdir}/default/volatiles/99_${BPN}
54    fi
55    if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
56        install -Dm 644 ${WORKDIR}/monkey.service ${D}/${systemd_unitdir}/system/monkey.service
57    fi
58}
59
60INITSCRIPT_NAME = "monkey"
61INITSCRIPT_PARAMS = "defaults 70"
62
63SYSTEMD_SERVICE:${PN} = "monkey.service"
64
65PACKAGES += "${PN}-plugins"
66
67FILES:${PN}-plugins = "${libdir}/monkey-*.so"
68
69FILES:${PN} += "${nonarch_libdir}/tmpfiles.d"
70
71CONFFILES:${PN} = "${sysconfdir}/monkey/monkey.conf \
72                   ${sysconfdir}/monkey/sites/default \
73                   ${sysconfdir}/monkey/monkey.mime \
74                   ${sysconfdir}/monkey/plugins.load \
75                   ${sysconfdir}/monkey/plugins/proxy_reverse/proxy_reverse.conf \
76                   ${sysconfdir}/monkey/plugins/mandril/mandril.conf \
77                   ${sysconfdir}/monkey/plugins/fastcgi/fastcgi.conf \
78                   ${sysconfdir}/monkey/plugins/logger/logger.conf \
79                   ${sysconfdir}/monkey/plugins/cgi/cgi.conf \
80                   ${sysconfdir}/monkey/plugins/cheetah/cheetah.conf \
81                   ${sysconfdir}/monkey/plugins/dirlisting/dirhtml.conf \
82                   ${sysconfdir}/monkey/plugins/dirlisting/themes/guineo/header.theme \
83                   ${sysconfdir}/monkey/plugins/dirlisting/themes/guineo/footer.theme \
84                   ${sysconfdir}/monkey/plugins/dirlisting/themes/guineo/entry.theme \
85                   ${sysconfdir}/monkey/plugins/auth/README \
86                   ${sysconfdir}/monkey/plugins/auth/monkey.users \
87                   "
88
89