1SUMMARY = "Perl interface to the libxml2 library"
2DESCRIPTION = "This module is an interface to libxml2, providing XML and HTML parsers \
3with DOM, SAX and XMLReader interfaces, a large subset of DOM Layer 3 \
4interface and a XML::XPath-like interface to XPath API of libxml2. \
5The module is split into several packages which are not described in this \
6section; unless stated otherwise, you only need to use XML::LibXML; in \
7your programs."
8
9HOMEPAGE = "http://search.cpan.org/dist/XML-LibXML-1.99/"
10SECTION = "libs"
11LICENSE = "Artistic-1.0 | GPL-1.0-or-later"
12DEPENDS += "libxml2 \
13        libxml-sax-perl-native \
14        zlib \
15"
16RDEPENDS:${PN} += "\
17    libxml2 \
18    libxml-sax-perl \
19    libxml-sax-base-perl \
20    perl-module-encode \
21    perl-module-data-dumper \
22    zlib \
23"
24
25SRC_URI = "http://search.cpan.org/CPAN/authors/id/S/SH/SHLOMIF/XML-LibXML-${PV}.tar.gz;name=libxml \
26    file://disable-libxml2-check.patch \
27    file://fix-CATALOG-conditional-compile.patch \
28    file://using-DOCB-conditional.patch \
29"
30LIC_FILES_CHKSUM = "file://debian/copyright;md5=64eda1bc135f0ece1d1187f2a8ac82c1 \
31    file://LICENSE;md5=97871bde150daeb5e61ad95137ff2446 \
32"
33SRC_URI[libxml.md5sum] = "dce687dd8b7e82d1c359fd74b1852f64"
34SRC_URI[libxml.sha256sum] = "f0bca4d0c2da35d879fee4cd13f352014186cedab27ab5e191f39b5d7d4f46cf"
35
36S = "${WORKDIR}/XML-LibXML-${PV}"
37
38inherit cpan ptest-perl
39
40EXTRA_CPANFLAGS = "INC=-I${STAGING_INCDIR}/libxml2 LIBS=-L${STAGING_LIBDIR}"
41
42BBCLASSEXTEND = "native"
43
44CFLAGS += " -D_GNU_SOURCE "
45BUILD_CFLAGS += " -D_GNU_SOURCE "
46
47FILES:${PN}-dbg =+ "${libdir}/perl/vendor_perl/*/auto/XML/LibXML/.debug/"
48
49RDEPENDS:${PN}-ptest += " \
50    liburi-perl \
51    perl-module-encode-byte \
52    perl-module-encode-unicode \
53    perl-module-locale \
54    perl-module-perlio-scalar \
55    perl-module-test-more \
56"
57
58do_install:prepend() {
59	# test requires "-T" (taint) command line option
60	rm -rf ${B}/t/pod.t
61	# this only applies to author build
62	rm -rf ${B}/t/pod-files-presence.t
63}
64
65do_install_ptest() {
66	cp -r ${B}/t/data ${D}${PTEST_PATH}/t/
67	cp -r ${B}/t/lib ${D}${PTEST_PATH}/t/
68	cp -r ${B}/example ${D}${PTEST_PATH}
69	cp -r ${B}/test ${D}${PTEST_PATH}
70	chown -R root:root ${D}${PTEST_PATH}
71}
72