1SUMMARY = "Authen::Radius - provide simple Radius client facilities"
2DESCRIPTION = "The Authen::Radius module provides a simple class that \
3    allows you to send/receive Radius requests/responses to/from a \
4    Radius server. \
5"
6
7HOMEPAGE = "http://search.cpan.org/~manowar/RadiusPerl"
8SECTION = "libs"
9
10LICENSE = "Artistic-2.0"
11LIC_FILES_CHKSUM = "file://LICENSE;md5=78ab6ea0cba1f1ec1680ebb149e3bc11"
12
13DEPENDS = "perl"
14
15SRC_URI = "http://search.cpan.org/CPAN/authors/id/M/MA/MANOWAR/RadiusPerl-${PV}.tar.gz \
16           file://test.pl-adjust-for-ptest.patch \
17           file://run-ptest \
18"
19SRC_URI[md5sum] = "d1fe2d6ecf7ea99299e4e3a8f945aad8"
20SRC_URI[sha256sum] = "3b276506986ccaa4949d92b13ce053a0017ad11562a991cc753364923fe81ca7"
21
22S = "${WORKDIR}/Authen-Radius-${PV}"
23
24inherit cpan ptest
25
26do_install_ptest() {
27    install -m 0755 ${S}/test.pl ${D}${PTEST_PATH}
28}
29
30RDEPENDS:${PN} += "\
31    libdata-hexdump-perl \
32    perl-module-digest-md5 \
33    perl-module-data-dumper \
34    perl-module-io-select \
35    perl-module-io-socket \
36"
37RDEPENDS:${PN}-ptest += " \
38    ${@bb.utils.contains('PTEST_ENABLED', '1', 'freeradius', '', d)} \
39"
40
41BBCLASSEXTEND = "native"
42
43python() {
44    if bb.utils.contains('PTEST_ENABLED', '1', 'True', 'False', d) and \
45       'networking-layer' not in d.getVar('BBFILE_COLLECTIONS').split():
46        raise bb.parse.SkipRecipe('ptest requires meta-networking to be present.')
47}
48