1SUMMARY = "X screen saver and locker"
2HOMEPAGE = "https://www.jwz.org/xscreensaver/"
3LICENSE = "0BSD"
4LIC_FILES_CHKSUM = "file://driver/xscreensaver.h;endline=10;md5=c3ce41cdff745eb1dc9d4fcfbffb4d51"
5
6SRC_URI = "https://www.jwz.org/${BPN}/${BP}.tar.gz"
7SRC_URI[sha256sum] = "085484665d91f60b4a1dedacd94bcf9b74b0fb096bcedc89ff1c245168e5473b"
8
9SRC_URI += " \
10    file://xscreensaver.service \
11    file://0001-build-Do-not-build-po-files.patch \
12    file://tweak-app-defaults.patch \
13"
14
15DEPENDS = "intltool-native libx11 libxext libxt libxft libxi glib-2.0-native bc-native libpam"
16# These are only needed as part of the stopgap screensaver implementation:
17RDEPENDS:${PN} = " \
18    liberation-fonts \
19    xuser-account \
20"
21
22inherit systemd perlnative pkgconfig gettext autotools-brokensep features_check
23
24
25EXTRA_OECONF += "--with-app-defaults=${datadir}/X11/app-defaults --libdir=${STAGING_LIBDIR} \
26                 --includedir=${STAGING_INCDIR} --with-pam --with-login-manager"
27
28EXTRA_OEMAKE += "install_prefix=${D}"
29REQUIRED_DISTRO_FEATURES = "x11 pam"
30
31do_install:append() {
32    install -D ${WORKDIR}/xscreensaver.service ${D}${systemd_unitdir}/system/xscreensaver.service
33    for f in xscreensaver-getimage-file xscreensaver-getimage-video webcollage xscreensaver-text vidwhacker
34    do
35        sed -i -e "s|${STAGING_BINDIR_NATIVE}/perl-native/perl|/usr/bin/perl|g" ${D}/${libexecdir}/${PN}/$f
36    done
37}
38
39PACKAGES =+ "${PN}-perl"
40
41FILES:${PN}-perl = "\
42    ${libexecdir}/${PN}/xscreensaver-getimage-file \
43    ${libexecdir}/${PN}/xscreensaver-getimage-video \
44    ${libexecdir}/${PN}/webcollage \
45    ${libexecdir}/${PN}/xscreensaver-text \
46    ${libexecdir}/${PN}/vidwhacker \
47    "
48FILES:${PN} += "${datadir}/X11/app-defaults/XScreenSaver ${datadir}/fonts"
49SYSTEMD_SERVICE:${PN} = "xscreensaver.service"
50
51RDEPENDS:${PN}-perl = "perl"
52
53CLEANBROKEN = "1"
54