1SUMMARY = "Control and monitor storage systems using S.M.A.R.T"
2DESCRIPTION = "\
3The smartmontools package contains two utility programs (smartctl \
4and smartd) to control and monitor storage systems using the Self-\
5Monitoring, Analysis and Reporting Technology System (SMART) built \
6into most modern ATA and SCSI hard disks. In many cases, these \
7utilities will provide advanced warning of disk degradation and failure."
8
9HOMEPAGE = "http://smartmontools.sourceforge.net/"
10SECTION = "console/utils"
11
12LICENSE = "GPL-2.0-only"
13LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
14
15SRC_URI = "${SOURCEFORGE_MIRROR}/smartmontools/smartmontools-${PV}.tar.gz \
16           file://initd.smartd \
17           file://smartmontools.default \
18           file://smartd.service \
19           file://0001-configure.ac-Define-SOURCE_DATE_EPOCH-in-CPPFLAGS.patch \
20           "
21
22PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'libcap-ng selinux', d)}"
23PACKAGECONFIG[libcap-ng] = "--with-libcap-ng=yes,--with-libcap-ng=no,libcap-ng"
24PACKAGECONFIG[selinux] = "--with-selinux=yes,--with-selinux=no,libselinux"
25
26SRC_URI[sha256sum] = "a544f8808d0c58cfb0e7424ca1841cb858a974922b035d505d4e4c248be3a22b"
27
28inherit autotools update-rc.d systemd
29
30SYSTEMD_SERVICE:${PN} = "smartd.service"
31SYSTEMD_AUTO_ENABLE = "disable"
32
33do_install:append () {
34    #install the init.d/smartd
35    install -d ${D}${sysconfdir}/init.d
36    install -p -m 0755 ${WORKDIR}/initd.smartd ${D}${sysconfdir}/init.d/smartd
37    install -d ${D}${sysconfdir}/default
38    install -p -m 0644 ${WORKDIR}/smartmontools.default ${D}${sysconfdir}/default/smartmontools
39
40    #install systemd service file
41    install -d ${D}${systemd_unitdir}/system
42    install -m 0644 ${WORKDIR}/smartd.service ${D}${systemd_unitdir}/system
43    sed -i -e 's,@BASE_BINDIR@,${base_bindir},g' \
44        -e 's,@SYSCONFDIR@,${sysconfdir},g' \
45        -e 's,@SBINDIR@,${sbindir},g' \
46        ${D}${systemd_unitdir}/system/smartd.service
47}
48
49INITSCRIPT_NAME = "smartd"
50INITSCRIPT_PARAMS = "start 60 2 3 4 5 . stop 60 0 1 6 ."
51
52RRECOMMENDS:${PN} += "s-nail"
53