1SUMMARY = "pam-ssh-agent-auth"
2DESCRIPTION = "A PAM module which permits authentication via ssh-agent."
3HOMEPAGE = "http://sourceforge.net/projects/pamsshagentauth/"
4SECTION = "libs"
5LICENSE = "OpenSSL & BSD-2-Clause & BSD-3-Clause"
6LIC_FILES_CHKSUM = "file://LICENSE.OpenSSL;md5=8ab01146141ded59b75f8ba7811ed05a \
7                    file://OPENSSH_LICENSE;md5=7ae09218173be1643c998a4b71027f9b \
8"
9
10SRC_URI = "http://sourceforge.net/projects/pamsshagentauth/files/pam_ssh_agent_auth/v${PV}/pam_ssh_agent_auth-${PV}.tar.bz2 \
11           file://0001-Adapt-to-OpenSSL-1.1.1.patch \
12           file://0002-Check-against-the-correct-OPENSSL_VERSION_NUMBER.patch \
13           "
14SRC_URI[md5sum] = "8dbe90ab3625e545036333e6f51ccf1d"
15SRC_URI[sha256sum] = "3c53d358d6eaed1b211239df017c27c6f9970995d14102ae67bae16d4f47a763"
16
17DEPENDS += "libpam openssl"
18
19inherit features_check
20REQUIRED_DISTRO_FEATURES = "pam"
21
22# This gets us ssh-agent, which we are almost certain to want.
23#
24RDEPENDS:${PN} += "openssh-misc"
25
26# Kind of unfortunate to have underscores in the name.
27#
28S = "${WORKDIR}/pam_ssh_agent_auth-${PV}"
29
30inherit autotools-brokensep perlnative
31
32# Avoid autoreconf.  Override the --libexec oe_runconf specifies so that
33# the module is put with the other pam modules.  Because it cannot, in general,
34# do a runtime test, configure wants to use rpl_malloc() and rpl_realloc()
35# instead of malloc() and realloc().  We set variables to tell it not to because
36# these functions do not exist.
37#
38do_configure () {
39    install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.guess ${S}
40    install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.sub ${S}
41    oe_runconf --without-openssl-header-check  --libexecdir=${base_libdir}/security \
42               ac_cv_func_malloc_0_nonnull=yes ac_cv_func_realloc_0_nonnull=yes
43}
44
45# Link with CC.  Configure cannot figure out the correct AR.
46#
47do_compile () {
48    oe_runmake  LD="${CC}" AR="${AR}"
49}
50
51# This stuff is not any place looked at by default.
52#
53FILES:${PN} += "${base_libdir}/security/pam*"
54FILES:${PN}-dbg += "${base_libdir}/security/.debug"
55