1SUMMARY = "Linux Console Project"
2DESCRIPTION = "This project maintains the Linux Console tools, which include \
3utilities to test and configure joysticks, connect legacy devices to the kernel's \
4input subsystem (providing support for serial mice, touchscreens etc.), and test \
5the input event layer."
6HOMEPAGE = "https://sourceforge.net/projects/linuxconsole"
7
8LICENSE = "GPL-2.0-only"
9LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
10
11DEPENDS = "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}"
12
13SRC_URI = "\
14    ${SOURCEFORGE_MIRROR}/linuxconsole/linuxconsoletools-${PV}.tar.bz2 \
15    file://0001-utils-Use-name-of-the-first-prerequisite-in-rule.patch \
16    file://51-these-are-not-joysticks-rm.rules \
17    file://60-joystick.rules \
18    file://inputattachctl \
19    file://inputattach.service \
20"
21
22SRC_URI[sha256sum] = "bd4d4b7e37da02fc67e47ddf20b6f1243c0a7af7b02b918d5e72138ea8727547"
23
24S = "${WORKDIR}/linuxconsoletools-${PV}"
25
26inherit systemd pkgconfig
27
28EXTRA_OEMAKE = "DESTDIR=${D} PREFIX=${prefix} -C utils"
29EXTRA_OEMAKE += "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'SYSTEMD_SUPPORT=1', '', d)}"
30
31SYSTEMD_PACKAGES += "inputattach"
32SYSTEMD_SERVICE:inputattach = "inputattach.service"
33SYSTEMD_AUTO_ENABLE:inputattach = "enable"
34
35PROVIDES += "joystick"
36
37PACKAGECONFIG ??= "sdl"
38PACKAGECONFIG[sdl] = ",,libsdl2"
39
40do_compile() {
41    if ! ${@bb.utils.contains('PACKAGECONFIG', 'sdl', 'true', 'false', d)}; then
42        # drop ffmvforce so that we don't need libsdl2
43        sed '/^PROGRAMS/s/ffmvforce *//g' -i ${S}/utils/Makefile
44    fi
45    # respect nonarch_base_libdir path to keep QA check happy
46    sed 's#DESTDIR)/lib/udev#DESTDIR)/${nonarch_base_libdir}/udev#g' -i ${S}/utils/Makefile
47    oe_runmake
48}
49
50do_install() {
51    oe_runmake install
52
53    install -Dm 0644 ${WORKDIR}/51-these-are-not-joysticks-rm.rules ${D}${nonarch_base_libdir}/udev/rules.d/51-these-are-not-joysticks-rm.rules
54    install -Dm 0644 ${WORKDIR}/60-joystick.rules ${D}${nonarch_base_libdir}/udev/rules.d/60-joystick.rules
55
56    install -Dm 0644 ${WORKDIR}/inputattach.service ${D}${systemd_system_unitdir}/inputattach.service
57    install -Dm 0755 ${WORKDIR}/inputattachctl ${D}${bindir}/inputattachctl
58}
59
60PACKAGES += "inputattach joystick-jscal joystick"
61
62# We won't package any file here as we are following the same packaging schema
63# Debian does and we are splitting it in 'inputattach' and 'joystick' packages.
64FILES:${PN} = ""
65
66FILES:inputattach += "\
67    ${bindir}/inputattach \
68    ${bindir}/inputattachctl \
69    ${systemd_system_unitdir}/inputattach.service \
70"
71
72FILES:joystick += "\
73    ${bindir}/evdev-joystick \
74    ${bindir}/ffcfstress \
75    ${bindir}/ffmvforce \
76    ${bindir}/ffset \
77    ${bindir}/fftest \
78    ${bindir}/jstest \
79    ${nonarch_base_libdir}/udev/rules.d/51-these-are-not-joysticks-rm.rules \
80    ${nonarch_base_libdir}/udev/js-set-enum-leds \
81    ${nonarch_base_libdir}/udev/rules.d/60-joystick.rules \
82    ${nonarch_base_libdir}/udev/rules.d/80-stelladaptor-joystick.rules \
83"
84
85FILES:joystick-jscal = " \
86    ${datadir}/joystick \
87    ${bindir}/jscal \
88    ${bindir}/jscal-restore \
89    ${bindir}/jscal-store \
90"
91
92RDEPENDS:inputattach += "inputattach-config"
93
94RDEPENDS:joystick-jscal += "\
95    bash \
96    gawk \
97"
98