1SUMMARY = "Memory Efficient Serialization Library"
2HOMEPAGE = "https://github.com/google/flatbuffers"
3SECTION = "console/tools"
4LICENSE = "Apache-2.0"
5
6inherit python3-dir
7
8PACKAGE_BEFORE_PN = "${PN}-compiler ${PN}-${PYTHON_PN}"
9
10RDEPENDS:${PN}-compiler = "${PN}"
11RDEPENDS:${PN}-${PYTHON_PN} = "${PN}"
12RDEPENDS:${PN}-dev += "${PN}-compiler"
13
14LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=3b83ef96387f14655fc854ddc3c6bd57"
15
16SRCREV = "a9a295fecf3fbd5a4f571f53b01f63202a3e2113"
17SRC_URI = "git://github.com/google/flatbuffers.git;branch=master;protocol=https"
18S = "${WORKDIR}/git"
19
20CVE_CHECK_IGNORE += "CVE-2020-35864"
21
22CXXFLAGS += "-fPIC"
23BUILD_CXXFLAGS += "-fPIC"
24
25# BUILD_TYPE=Release is required, otherwise flatc is not installed
26EXTRA_OECMAKE += "\
27    -DCMAKE_BUILD_TYPE=Release \
28    -DFLATBUFFERS_BUILD_TESTS=OFF \
29    -DFLATBUFFERS_BUILD_SHAREDLIB=ON \
30"
31
32inherit cmake
33
34do_install:append() {
35    install -d ${D}${PYTHON_SITEPACKAGES_DIR}
36    cp -rf ${S}/python/flatbuffers ${D}${PYTHON_SITEPACKAGES_DIR}
37}
38
39FILES:${PN}-compiler = "${bindir}"
40
41FILES:${PN}-${PYTHON_PN} = "${PYTHON_SITEPACKAGES_DIR}"
42
43BBCLASSEXTEND = "native nativesdk"
44