1SUMMARY = "ModemManager is a daemon controlling broadband devices/connections"
2DESCRIPTION = "ModemManager is a DBus-activated daemon which controls mobile broadband (2G/3G/4G) devices and connections"
3HOMEPAGE = "http://www.freedesktop.org/wiki/Software/ModemManager/"
4LICENSE = "GPL-2.0-or-later & LGPL-2.1-or-later"
5LIC_FILES_CHKSUM = " \
6    file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
7    file://COPYING.LIB;md5=4fbd65380cdd255951079008b364516c \
8"
9
10GNOMEBASEBUILDCLASS = "meson"
11inherit gnomebase gettext systemd gobject-introspection bash-completion
12
13DEPENDS = "glib-2.0 libgudev libxslt-native dbus"
14
15SRCREV ?= "0d8b5e93fc62eb0f41e18a2d9d845331d7af36ec"
16
17# Patch 0001 will be in ModemManager > 1.19
18SRC_URI = " \
19    git://gitlab.freedesktop.org/mobile-broadband/ModemManager.git;protocol=https;branch=mm-1-18 \
20    file://0001-core-switch-bash-shell-scripts-to-use-bin-sh-for-use.patch \
21"
22
23S = "${WORKDIR}/git"
24
25# strict, permissive
26MODEMMANAGER_POLKIT_TYPE ??= "permissive"
27
28PACKAGECONFIG ??= "vala mbim qmi \
29    ${@bb.utils.filter('DISTRO_FEATURES', 'systemd polkit', d)} \
30"
31
32PACKAGECONFIG[at] = "-Dat_command_via_dbus=true"
33PACKAGECONFIG[systemd] = " \
34    -Dsystemdsystemunitdir=${systemd_unitdir}/system/, \
35    -Dsystemdsystemunitdir=no -Dsystemd_journal=false -Dsystemd_suspend_resume=false \
36"
37PACKAGECONFIG[polkit] = "-Dpolkit=${MODEMMANAGER_POLKIT_TYPE},-Dpolkit=no,polkit"
38# Support WWAN modems and devices which speak the Mobile Interface Broadband Model (MBIM) protocol.
39PACKAGECONFIG[mbim] = "-Dmbim=true,-Dmbim=false -Dplugin_dell=disabled -Dplugin_foxconn=disabled,libmbim"
40# Support WWAN modems and devices which speak the Qualcomm MSM Interface (QMI) protocol.
41PACKAGECONFIG[qmi] = "-Dqmi=true,-Dqmi=false,libqmi"
42PACKAGECONFIG[qrtr] = "-Dqrtr=true,-Dqrtr=false,libqrtr-glib"
43PACKAGECONFIG[vala] = "-Dvapi=true,-Dvapi=false"
44
45inherit ${@bb.utils.contains('PACKAGECONFIG', 'vala', 'vala', '', d)}
46
47EXTRA_OEMESON = " \
48    -Dudevdir=${nonarch_base_libdir}/udev \
49    -Dqrtr=false \
50"
51
52FILES:${PN} += " \
53    ${datadir}/icons \
54    ${datadir}/polkit-1 \
55    ${datadir}/dbus-1 \
56    ${datadir}/ModemManager \
57    ${libdir}/ModemManager \
58    ${systemd_unitdir}/system \
59"
60
61SYSTEMD_SERVICE:${PN} = "ModemManager.service"
62