1SUMMARY = "Phoronix Test Suite"
2DESCRIPTION = "The Phoronix Test Suite is designed to carry out both qualitative \
3and quantitative benchmarks in a clean, reproducible, and easy-to-use manner."
4LICENSE = "GPL-3.0-only"
5LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
6SECTION = "console/tests"
7
8SRC_URI = "http://www.phoronix-test-suite.com/releases/${BP}.tar.gz \
9           file://CVE-2022-40704.patch \
10          "
11
12
13SRC_URI[md5sum] = "459c3c45b39bb3d720ddc8ba5f944332"
14SRC_URI[sha256sum] = "86681343d20415831ab16ef6c3d1c317e2345e771925e0698ae920a03a9eaab6"
15
16S = "${WORKDIR}/phoronix-test-suite"
17
18inherit systemd allarch mime mime-xdg
19
20do_install() {
21    DESTDIR=${D} ./install-sh ${exec_prefix}
22
23    if [ "${systemd_unitdir}" != "/usr/lib/systemd" ]; then
24        install -d ${D}/${systemd_unitdir}/system/
25        mv ${D}/usr/lib/systemd/system/* ${D}/${systemd_unitdir}/system/
26        rm -rf ${D}/usr/lib/
27    fi
28}
29
30# It is not advisable to enable these services by default since they can cause
31# continual target reboots if they encounter network problems.
32#
33SYSTEMD_AUTO_ENABLE = "disable"
34SYSTEMD_SERVICE:${PN} = "phoromatic-client.service phoromatic-server.service"
35
36RDEPENDS:${PN} += "bash python3-core php-cli util-linux-lscpu os-release lsb-release"
37
38FILES:${PN} += " \
39    ${datadir}/phoronix-test-suite \
40    ${datadir}/appdata/phoronix-test-suite.appdata.xml \
41    ${datadir}/icons/hicolor/48x48/apps/phoronix-test-suite.png \
42    ${datadir}/icons/hicolor/64x64/mimetypes/application-x-openbenchmarking.png \
43    ${datadir}/mime/packages/openbenchmarking-mime.xml \
44    ${systemd_unitdir}/* \
45"
46