1SUMMARY = "Open-source IoT platform for data collection, processing, visualization, and device management"
2DESCRIPTION = "\
3The Thingsboard IoT Gateway is an open-source solution that allows you \
4to integrate devices connected to legacy and third-party systems with Thingsboard."
5HOMEPAGE = "https://thingsboard.io/"
6
7LICENSE = "Apache-2.0"
8LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/Apache-2.0;md5=89aea4e17d99a7cacdbeed46a0096b10"
9
10SRC_URI[sha256sum] = "3341188a386726a5feb87e5fa04edb999de69e38ee8b4ea5b7d59165729ba0be"
11
12inherit pypi setuptools3
13
14PYPI_PACKAGE = "thingsboard-gateway"
15
16RDEPENDS:${PN} += " python3-jsonpath-rw \
17                    python3-regex \
18                    python3-paho-mqtt \
19                    python3-pyyaml \
20                    python3-simplejson \
21                    python3-requests \
22                    python3-pip \
23                    python3-pyrsistent \
24"
25
26SRC_URI += "file://bacnet.json \
27            file://ble.json \
28            file://can.json \
29            file://custom_serial.json \
30            file://modbus.json \
31            file://modbus_serial.json \
32            file://mqtt.json \
33            file://opcua.json \
34            file://odbc.json \
35            file://request.json \
36            file://rest.json \
37            file://snmp.json \
38            file://tb_gateway.yaml \
39            file://logs.conf \
40            file://thingsboard-gateway.service \
41            "
42
43
44inherit systemd
45
46SYSTEMD_PACKAGES = "${PN}"
47SYSTEMD_SERVICE:${PN} = "thingsboard-gateway.service"
48
49FILES:${PN} += "/etc \
50                /lib \
51                /usr \
52"
53
54do_install:append(){
55
56    install -d ${D}${sysconfdir}/thingsboard-gateway/config
57
58    for file in $(find ${WORKDIR} -maxdepth 1 -type f -name *.json); do
59        install -m 0644 "$file" ${D}${sysconfdir}/thingsboard-gateway/config
60    done
61
62    install -m 0644 ${WORKDIR}/tb_gateway.yaml ${D}${sysconfdir}/thingsboard-gateway/config
63    install -m 0644 ${WORKDIR}/logs.conf ${D}${sysconfdir}/thingsboard-gateway/config
64
65    install -d ${D}${systemd_unitdir}/system/
66    install -m 0644 ${WORKDIR}/thingsboard-gateway.service     ${D}${systemd_system_unitdir}/thingsboard-gateway.service
67}
68