1SUMMARY = "A new modern implementation of traceroute(8) utility for Linux systems"
2DESCRIPTION = "The traceroute utility displays the route used by IP packets on \
3their way to a specified network (or Internet) host.  Traceroute displays \
4the IP number and host name (if possible) of the machines along the \
5route taken by the packets.  Traceroute is used as a network debugging \
6tool.  If you're having network connectivity problems, traceroute will \
7show you where the trouble is coming from along the route."
8SECTION = "net"
9HOMEPAGE = "http://traceroute.sourceforge.net/"
10LICENSE = "GPL-2.0-or-later & LGPL-2.1-or-later"
11LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
12                    file://COPYING.LIB;md5=4fbd65380cdd255951079008b364516c"
13
14inherit update-alternatives
15
16UPSTREAM_CHECK_URI = "https://sourceforge.net/projects/traceroute/files/traceroute/"
17
18SRC_URI = "${SOURCEFORGE_MIRROR}/traceroute/traceroute/${BP}/${BP}.tar.gz \
19"
20SRC_URI[md5sum] = "84d329d67abc3fb83fc8cb12aeaddaba"
21SRC_URI[sha256sum] = "3669d22a34d3f38ed50caba18cd525ba55c5c00d5465f2d20d7472e5d81603b6"
22
23EXTRA_OEMAKE = "VPATH=${STAGING_LIBDIR}"
24LTOEXTRA += "-flto-partition=none"
25
26do_compile() {
27    oe_runmake "env=yes"
28}
29
30do_install() {
31    install -d ${D}${bindir}
32    install -m755 ${BPN}/${BPN} ${D}${bindir}
33
34    install -m755 wrappers/tcptraceroute ${D}${bindir}
35
36    install -d ${D}${mandir}/man8
37    install -p -m644 ${BPN}/${BPN}.8 ${D}${mandir}/man8
38    ln -s ${BPN}.8 ${D}${mandir}/man8/${BPN}6.8
39    ln -s ${BPN}.8 ${D}${mandir}/man8/tcptraceroute.8
40
41}
42
43ALTERNATIVE_PRIORITY = "100"
44ALTERNATIVE:${PN} = "traceroute"
45ALTERNATIVE_LINK_NAME[traceroute] = "${bindir}/traceroute"
46