xref: /OK3568_Linux_fs/yocto/meta-openembedded/meta-networking/recipes-support/nis/yp-tools_4.2.3.bb (revision 4882a59341e53eb6f0b4789bf948001014eff981) 
1# This package builds tools to manage NIS
2# The source package is utils/net/NIS/yp-tools
3#
4require nis.inc
5
6SUMMARY = "NIS client programs"
7DESCRIPTION = " \
8Network Information Service tools.  \
9This package contains ypcat, ypmatch, ypset, \
10ypwhich, yppasswd, domainname, nisdomainname \
11and ypdomainname. \
12"
13
14# v4.2.3
15SRCREV = "1bfda29c342a81b97cb1995ffd9e8da5de63e7ab"
16
17SRC_URI = "git://github.com/thkukuk/yp-tools;branch=master;protocol=https \
18           file://domainname.service \
19           "
20
21S = "${WORKDIR}/git"
22
23DEPENDS = "libtirpc libnsl2 virtual/crypt"
24
25inherit autotools systemd
26SYSTEMD_SERVICE:${PN} = "domainname.service"
27
28RPROVIDES:${PN} += "${PN}-systemd"
29RREPLACES:${PN} += "${PN}-systemd"
30RCONFLICTS:${PN} += "${PN}-systemd"
31
32CACHED_CONFIGUREVARS += "ac_cv_prog_STRIP=/bin/true"
33
34EXTRA_OECONF = " \
35                --disable-rpath --disable-domainname \
36               "
37CFLAGS:append:libc-musl = " -Wno-error=cpp"
38
39FILES:${PN} += " ${libdir}/yp-nis/*.so.*.* ${libdir}/yp-nis/pkgconfig/"
40FILES:${PN}-dbg += " ${libdir}/yp-nis/.debug"
41FILES:${PN}-dev += " ${libdir}/yp-nis/*.so ${libdir}/yp-nis/*.so.[12] ${libdir}/yp-nis/*.la"
42FILES:${PN}-staticdev += " ${libdir}/yp-nis/*.a"
43
44do_install:append() {
45    install -d ${D}${systemd_unitdir}/system
46    install -m 0644 ${WORKDIR}/domainname.service ${D}${systemd_unitdir}/system
47}
48