1SUMMARY = "The Linux Kernel Stream Control Transmission Protocol (lksctp) project"
2HOMEPAGE = "http://lksctp.org"
3SECTION = "net"
4LICENSE = "LGPL-2.1-only & GPL-2.0-only"
5
6LIC_FILES_CHKSUM = " \
7    file://COPYING.lib;md5=0a1b79af951c42a9c8573533fbba9a92 \
8    file://COPYING;md5=0c56db0143f4f80c369ee3af7425af6e \
9"
10
11SRCREV = "05b50d379ff0037de4957bb2a1befcce88b70225"
12
13PV .= "+git${SRCPV}"
14LK_REL = "1.0.19"
15
16SRC_URI = " \
17    git://github.com/sctp/lksctp-tools.git;branch=master;protocol=https \
18    file://run-ptest \
19    file://v4test.sh \
20    file://v6test.sh \
21"
22
23S = "${WORKDIR}/git"
24
25BBCLASSEXTEND = "native"
26
27inherit autotools-brokensep pkgconfig binconfig ptest
28
29do_install_ptest () {
30    install -m 0755 ${WORKDIR}/v4test.sh ${D}${PTEST_PATH}
31    install -m 0755 ${WORKDIR}/v6test.sh ${D}${PTEST_PATH}
32    for testcase in `find ${B}/src/apps/.libs ${B}/src/func_tests/.libs -maxdepth 1 -type f -executable`; do
33        install $testcase ${D}${PTEST_PATH}
34    done
35}
36
37SOLIBVERSION="${LK_REL}"
38SOLIBMAJORVERSION="1"
39
40PACKAGES =+ "${PN}-withsctp ${PN}-utils"
41
42FILES:${PN} = " \
43    ${libdir}/libsctp.so.${SOLIBVERSION} \
44    ${libdir}/libsctp.so.${SOLIBMAJORVERSION} \
45"
46
47FILES:${PN}-withsctp = " \
48    ${libdir}/lksctp-tools/libwithsctp.so.${SOLIBVERSION} \
49    ${libdir}/lksctp-tools/libwithsctp.so.${SOLIBMAJORVERSION} \
50"
51
52FILES:${PN}-dev += " \
53    ${libdir}/libsctp.so \
54    ${libdir}/lksctp-tools/libwithsctp.so \
55    ${datadir}/lksctp-tools/*.c \
56    ${datadir}/lksctp-tools/*.h \
57"
58
59FILES:${PN}-utils = "${bindir}/*"
60
61RRECOMMENDS:${PN} += "kernel-module-sctp"
62RRECOMMENDS:${PN}-utils += "kernel-module-sctp"
63RRECOMMENDS:${PN}-ptest += "kernel-module-sctp"
64