1SUMMARY = "Various tools relating to the Simple Network Management Protocol"
2HOMEPAGE = "http://www.net-snmp.org/"
3SECTION = "net"
4LICENSE = "BSD-3-Clause & MIT"
5
6LIC_FILES_CHKSUM = "file://COPYING;md5=9d100a395a38584f2ec18a8275261687"
7
8DEPENDS = "openssl"
9DEPENDS:append:class-target = " pciutils"
10
11SRC_URI = "${SOURCEFORGE_MIRROR}/net-snmp/net-snmp-${PV}.tar.gz \
12           file://init \
13           file://snmpd.conf \
14           file://snmptrapd.conf \
15           file://snmpd.service \
16           file://snmptrapd.service \
17           file://net-snmp-add-knob-whether-nlist.h-are-checked.patch \
18           file://fix-libtool-finish.patch \
19           file://net-snmp-testing-add-the-output-format-for-ptest.patch \
20           file://run-ptest \
21           file://0001-config_os_headers-Error-Fix.patch \
22           file://0001-snmplib-keytools.c-Don-t-check-for-return-from-EVP_M.patch \
23           file://0001-get_pid_from_inode-Include-limit.h.patch \
24           file://0004-configure-fix-incorrect-variable.patch \
25           file://net-snmp-5.7.2-fix-engineBoots-value-on-SIGHUP.patch \
26           file://net-snmp-fix-for-disable-des.patch \
27           file://reproducibility-have-printcap.patch \
28           file://0001-ac_add_search_path.m4-keep-consistent-between-32bit.patch \
29           file://CVE-2022-44792-CVE-2022-44793.patch \
30           "
31SRC_URI[sha256sum] = "2097f29b7e1bf3f1300b4bae52fa2308d0bb8d5d3998dbe02f9462a413a2ef0a"
32
33UPSTREAM_CHECK_URI = "https://sourceforge.net/projects/net-snmp/files/net-snmp/"
34UPSTREAM_CHECK_REGEX = "/net-snmp/(?P<pver>\d+(\.\d+)+)/"
35
36inherit autotools-brokensep update-rc.d siteinfo systemd pkgconfig perlnative ptest multilib_script multilib_header
37
38EXTRA_OEMAKE = "INSTALL_PREFIX=${D} OTHERLDFLAGS='${LDFLAGS}' HOST_CPPFLAGS='${BUILD_CPPFLAGS}'"
39
40PARALLEL_MAKE = ""
41CCACHE = ""
42CLEANBROKEN = "1"
43
44TARGET_CC_ARCH += "${LDFLAGS}"
45
46PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'ipv6 systemd', d)} des smux"
47PACKAGECONFIG[des] = "--enable-des, --disable-des"
48PACKAGECONFIG[elfutils] = "--with-elf, --without-elf, elfutils"
49PACKAGECONFIG[ipv6] = "--enable-ipv6, --disable-ipv6"
50PACKAGECONFIG[libnl] = "--with-nl, --without-nl, libnl"
51PACKAGECONFIG[perl] = "--enable-embedded-perl --with-perl-modules=yes, --disable-embedded-perl --with-perl-modules=no, perl"
52PACKAGECONFIG[smux] = ""
53PACKAGECONFIG[systemd] = "--with-systemd, --without-systemd"
54
55EXTRA_OECONF = " \
56    --enable-shared \
57    --disable-manuals \
58    --with-defaults \
59    --with-install-prefix=${D} \
60    --with-persistent-directory=${localstatedir}/lib/net-snmp \
61    --with-endianness=${@oe.utils.conditional('SITEINFO_ENDIANNESS', 'le', 'little', 'big', d)} \
62    --with-mib-modules='${MIB_MODULES}' \
63"
64
65MIB_MODULES = ""
66MIB_MODULES:append = " ${@bb.utils.filter('PACKAGECONFIG', 'smux', d)}"
67
68CACHED_CONFIGUREVARS = " \
69    ac_cv_header_valgrind_valgrind_h=no \
70    ac_cv_header_valgrind_memcheck_h=no \
71    ac_cv_ETC_MNTTAB=/etc/mtab \
72    lt_cv_shlibpath_overrides_runpath=yes \
73    ac_cv_path_UNAMEPROG=${base_bindir}/uname \
74    ac_cv_path_PSPROG=${base_bindir}/ps \
75    ac_cv_file__etc_printcap=no \
76    NETSNMP_CONFIGURE_OPTIONS= \
77"
78PERLPROG = "${bindir}/env perl"
79PERLPROG:class-native = "${bindir_native}/env perl"
80PERLPROG:append = "${@bb.utils.contains('PACKAGECONFIG', 'perl', ' -I${WORKDIR}', '', d)}"
81export PERLPROG
82
83HAS_PERL = "${@bb.utils.contains('PACKAGECONFIG', 'perl', '1', '0', d)}"
84
85PTEST_BUILD_HOST_FILES += "net-snmp-config gen-variables"
86
87do_configure:prepend() {
88    sed -i -e "s|I/usr/include|I${STAGING_INCDIR}|g" \
89        "${S}"/configure \
90        "${S}"/configure.d/config_os_libs2
91
92    if [ "${HAS_PERL}" = "1" ]; then
93        # this may need to be changed when package perl has any change.
94        cp -f ${STAGING_DIR_TARGET}/usr/lib*/perl?/*/Config.pm ${WORKDIR}/
95        cp -f ${STAGING_DIR_TARGET}/usr/lib*/perl?/*/*/Config_heavy.pl ${WORKDIR}/
96        sed -e "s@libpth => '/usr/lib.*@libpth => '${STAGING_DIR_TARGET}/${libdir} ${STAGING_DIR_TARGET}/${base_libdir}',@g" \
97            -e "s@privlibexp => '/usr@privlibexp => '${STAGING_DIR_TARGET}/usr@g" \
98            -e "s@scriptdir => '/usr@scriptdir => '${STAGING_DIR_TARGET}/usr@g" \
99            -e "s@sitearchexp => '/usr@sitearchexp => '${STAGING_DIR_TARGET}/usr@g" \
100            -e "s@sitelibexp => '/usr@sitearchexp => '${STAGING_DIR_TARGET}/usr@g" \
101            -e "s@vendorarchexp => '/usr@vendorarchexp => '${STAGING_DIR_TARGET}/usr@g" \
102            -e "s@vendorlibexp => '/usr@vendorlibexp => '${STAGING_DIR_TARGET}/usr@g" \
103            -i ${WORKDIR}/Config.pm
104    fi
105
106}
107
108do_configure:append() {
109    sed -e "s@^NSC_INCLUDEDIR=.*@NSC_INCLUDEDIR=${STAGING_DIR_TARGET}\$\{includedir\}@g" \
110        -e "s@^NSC_LIBDIR=-L.*@NSC_LIBDIR=-L${STAGING_DIR_TARGET}\$\{libdir\}@g" \
111        -e "s@^NSC_LDFLAGS=\"-L.* @NSC_LDFLAGS=\"-L${STAGING_DIR_TARGET}\$\{libdir\} @g" \
112        -i ${B}/net-snmp-config
113}
114
115do_install:append() {
116    install -d ${D}${sysconfdir}/snmp
117    install -d ${D}${sysconfdir}/init.d
118    install -m 755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/snmpd
119    install -m 644 ${WORKDIR}/snmpd.conf ${D}${sysconfdir}/snmp/
120    install -m 644 ${WORKDIR}/snmptrapd.conf ${D}${sysconfdir}/snmp/
121    install -d ${D}${systemd_unitdir}/system
122    install -m 0644 ${WORKDIR}/snmpd.service ${D}${systemd_unitdir}/system
123    install -m 0644 ${WORKDIR}/snmptrapd.service ${D}${systemd_unitdir}/system
124    sed -e "s@^NSC_SRCDIR=.*@NSC_SRCDIR=.@g" \
125        -i ${D}${bindir}/net-snmp-create-v3-user
126    sed -e 's@^NSC_SRCDIR=.*@NSC_SRCDIR=.@g' \
127        -e 's@[^ ]*-ffile-prefix-map=[^ "]*@@g' \
128        -e 's@[^ ]*-fdebug-prefix-map=[^ "]*@@g' \
129        -e 's@[^ ]*-fmacro-prefix-map=[^ "]*@@g' \
130        -e 's@[^ ]*--sysroot=[^ "]*@@g' \
131        -e 's@[^ ]*--with-libtool-sysroot=[^ "]*@@g' \
132        -e 's@[^ ]*--with-install-prefix=[^ "]*@@g' \
133        -e 's@[^ ]*PKG_CONFIG_PATH=[^ "]*@@g' \
134        -e 's@[^ ]*PKG_CONFIG_LIBDIR=[^ "]*@@g' \
135        -i ${D}${bindir}/net-snmp-config
136
137    sed -e 's@[^ ]*-ffile-prefix-map=[^ "]*@@g' \
138        -e 's@[^ ]*-fdebug-prefix-map=[^ "]*@@g' \
139        -e 's@[^ ]*-fmacro-prefix-map=[^ "]*@@g' \
140        -i ${D}${libdir}/pkgconfig/netsnmp*.pc
141
142    # ${STAGING_DIR_HOST} is empty for native builds, and the sed command below
143    # will result in errors if run for native.
144    if [ "${STAGING_DIR_HOST}" ]; then
145        sed -e 's@${STAGING_DIR_HOST}@@g' \
146            -i ${D}${bindir}/net-snmp-config ${D}${libdir}/pkgconfig/netsnmp*.pc
147    fi
148
149    sed -e "s@^NSC_INCLUDEDIR=.*@NSC_INCLUDEDIR=\$\{includedir\}@g" \
150        -e "s@^NSC_LIBDIR=-L.*@NSC_LIBDIR=-L\$\{libdir\}@g" \
151        -e "s@^NSC_LDFLAGS=\"-L.* @NSC_LDFLAGS=\"-L\$\{libdir\} @g" \
152        -i ${D}${bindir}/net-snmp-config
153
154    oe_multilib_header net-snmp/net-snmp-config.h
155
156    if [ "${HAS_PERL}" = "1" ]; then
157        find ${D}${libdir}/ -type f -name "perllocal.pod" | xargs rm -f
158    fi
159}
160
161do_install_ptest() {
162    install -d ${D}${PTEST_PATH}
163    for i in ${S}/dist ${S}/include ${B}/include ${S}/mibs ${S}/configure \
164        ${B}/net-snmp-config ${S}/testing; do
165        if [ -e "$i" ]; then
166            cp -R --no-dereference --preserve=mode,links -v "$i" ${D}${PTEST_PATH}
167        fi
168    done
169    echo `autoconf -V|awk '/autoconf/{print $NF}'` > ${D}${PTEST_PATH}/dist/autoconf-version
170
171    rmdlist="${D}${PTEST_PATH}/dist/net-snmp-solaris-build"
172    for i in $rmdlist; do
173        if [ -d "$i" ]; then
174            rm -rf "$i"
175        fi
176    done
177}
178
179SYSROOT_PREPROCESS_FUNCS += "net_snmp_sysroot_preprocess"
180SNMP_DBGDIR = "/usr/src/debug/${PN}/${EXTENDPE}${PV}-${PR}"
181
182net_snmp_sysroot_preprocess () {
183    if [ -e ${D}${bindir}/net-snmp-config ]; then
184        install -d ${SYSROOT_DESTDIR}${bindir_crossscripts}/
185        install -m 755 ${D}${bindir}/net-snmp-config ${SYSROOT_DESTDIR}${bindir_crossscripts}/
186        sed -e "s@-I/usr/include@-I${STAGING_INCDIR}@g" \
187            -e "s@^prefix=.*@prefix=${STAGING_DIR_HOST}${prefix}@g" \
188            -e "s@^exec_prefix=.*@exec_prefix=${STAGING_EXECPREFIXDIR}@g" \
189            -e "s@^includedir=.*@includedir=${STAGING_INCDIR}@g" \
190            -e "s@^libdir=.*@libdir=${STAGING_LIBDIR}@g" \
191            -e "s@^NSC_SRCDIR=.*@NSC_SRCDIR=${S}@g" \
192            -e "s@-ffile-prefix-map=${SNMP_DBGDIR}@-ffile-prefix-map=${WORKDIR}=${SNMP_DBGDIR}@g" \
193            -e "s@-fdebug-prefix-map=${SNMP_DBGDIR}@-fdebug-prefix-map=${WORKDIR}=${SNMP_DBGDIR}@g" \
194            -e "s@-fdebug-prefix-map= -fdebug-prefix-map=@-fdebug-prefix-map=${STAGING_DIR_NATIVE}= \
195                  -fdebug-prefix-map=${STAGING_DIR_HOST}=@g" \
196            -e "s@--sysroot=@--sysroot=${STAGING_DIR_HOST}@g" \
197            -e "s@--with-libtool-sysroot=@--with-libtool-sysroot=${STAGING_DIR_HOST}@g" \
198            -e "s@--with-install-prefix=@--with-install-prefix=${D}@g" \
199          -i  ${SYSROOT_DESTDIR}${bindir_crossscripts}/net-snmp-config
200    fi
201}
202
203PACKAGES += "${PN}-libs ${PN}-mibs ${PN}-server ${PN}-client \
204             ${PN}-server-snmpd ${PN}-server-snmptrapd \
205             ${PN}-lib-netsnmp ${PN}-lib-agent ${PN}-lib-helpers \
206             ${PN}-lib-mibs ${PN}-lib-trapd"
207
208# perl module
209PACKAGES += "${@bb.utils.contains('PACKAGECONFIG', 'perl', '${PN}-perl-modules', '', d)}"
210
211ALLOW_EMPTY:${PN} = "1"
212ALLOW_EMPTY:${PN}-server = "1"
213ALLOW_EMPTY:${PN}-libs = "1"
214
215FILES:${PN}-perl-modules = "${libdir}/perl?/*"
216RDEPENDS:${PN}-perl-modules = "perl"
217
218FILES:${PN}-libs = ""
219FILES:${PN}-mibs = "${datadir}/snmp/mibs"
220FILES:${PN}-server-snmpd = "${sbindir}/snmpd \
221                            ${sysconfdir}/snmp/snmpd.conf \
222                            ${sysconfdir}/init.d \
223                            ${systemd_unitdir}/system/snmpd.service \
224"
225
226FILES:${PN}-server-snmptrapd = "${sbindir}/snmptrapd \
227                                ${sysconfdir}/snmp/snmptrapd.conf \
228                                ${systemd_unitdir}/system/snmptrapd.service \
229"
230
231FILES:${PN}-lib-netsnmp = "${libdir}/libnetsnmp${SOLIBS}"
232FILES:${PN}-lib-agent = "${libdir}/libnetsnmpagent${SOLIBS}"
233FILES:${PN}-lib-helpers = "${libdir}/libnetsnmphelpers${SOLIBS}"
234FILES:${PN}-lib-mibs = "${libdir}/libnetsnmpmibs${SOLIBS}"
235FILES:${PN}-lib-trapd = "${libdir}/libnetsnmptrapd${SOLIBS}"
236
237FILES:${PN} = ""
238FILES:${PN}-client = "${bindir}/* ${datadir}/snmp/"
239FILES:${PN}-dbg += "${libdir}/.debug/ ${sbindir}/.debug/ ${bindir}/.debug/"
240FILES:${PN}-dev += "${bindir}/mib2c \
241                    ${bindir}/mib2c-update \
242                    ${bindir}/net-snmp-config \
243                    ${bindir}/net-snmp-create-v3-user \
244"
245
246CONFFILES:${PN}-server-snmpd = "${sysconfdir}/snmp/snmpd.conf"
247CONFFILES:${PN}-server-snmptrapd = "${sysconfdir}/snmp/snmptrapd.conf"
248
249INITSCRIPT_PACKAGES = "${PN}-server-snmpd"
250INITSCRIPT_NAME:${PN}-server-snmpd = "snmpd"
251INITSCRIPT_PARAMS:${PN}-server-snmpd = "start 90 2 3 4 5 . stop 60 0 1 6 ."
252
253SYSTEMD_PACKAGES = "${PN}-server-snmpd \
254                    ${PN}-server-snmptrapd"
255
256SYSTEMD_SERVICE:${PN}-server-snmpd = "snmpd.service"
257SYSTEMD_SERVICE:${PN}-server-snmptrapd =  "snmptrapd.service"
258
259RDEPENDS:${PN} += "${@bb.utils.contains('PACKAGECONFIG', 'perl', 'net-snmp-perl-modules', '', d)}"
260RDEPENDS:${PN} += "net-snmp-client"
261RDEPENDS:${PN}-server-snmpd += "net-snmp-mibs"
262RDEPENDS:${PN}-server-snmptrapd += "net-snmp-server-snmpd ${PN}-lib-trapd"
263RDEPENDS:${PN}-server += "net-snmp-server-snmpd net-snmp-server-snmptrapd"
264RDEPENDS:${PN}-client += "net-snmp-mibs net-snmp-libs"
265RDEPENDS:${PN}-libs += "libpci \
266                        ${PN}-lib-netsnmp \
267                        ${PN}-lib-agent \
268                        ${PN}-lib-helpers \
269                        ${PN}-lib-mibs \
270"
271RDEPENDS:${PN}-ptest += "perl \
272                         perl-module-test \
273                         perl-module-file-basename \
274                         perl-module-getopt-long \
275                         perl-module-file-temp \
276                         perl-module-data-dumper \
277"
278RDEPENDS:${PN}-dev = "net-snmp-client (= ${EXTENDPKGV}) net-snmp-server (= ${EXTENDPKGV})"
279RRECOMMENDS:${PN}-dbg = "net-snmp-client (= ${EXTENDPKGV}) net-snmp-server (= ${EXTENDPKGV})"
280
281RPROVIDES:${PN}-server-snmpd += "${PN}-server-snmpd-systemd"
282RREPLACES:${PN}-server-snmpd += "${PN}-server-snmpd-systemd"
283RCONFLICTS:${PN}-server-snmpd += "${PN}-server-snmpd-systemd"
284
285RPROVIDES:${PN}-server-snmptrapd += "${PN}-server-snmptrapd-systemd"
286RREPLACES:${PN}-server-snmptrapd += "${PN}-server-snmptrapd-systemd"
287RCONFLICTS:${PN}-server-snmptrapd += "${PN}-server-snmptrapd-systemd"
288
289LEAD_SONAME = "libnetsnmp.so"
290
291MULTILIB_SCRIPTS = "${PN}-dev:${bindir}/net-snmp-config"
292
293BBCLASSEXTEND = "native"
294