1DESCRIPTION = "netkit-rpc includes rpcinfo and rpcgen."
2HOMEPAGE = "http://ftp.linux.org.uk/pub/linux/Networking/netkit"
3SECTION = "net"
4LICENSE = "SPL-1.0"
5LIC_FILES_CHKSUM = "file://rpcinfo/rpcinfo.c;beginline=2;endline=3;md5=3e6339e3ce266e1122c5ba293e04bc89"
6
7DEPENDS += "libtirpc"
8SRC_URI = "http://sources.openembedded.org/${BPN}-${PV}.tar.gz \
9           file://gcc4.patch \
10           file://0001-rpcgen-Fix-printf-formats.patch \
11           "
12SRC_URI[md5sum] = "67212720482ea1aea9182a98653a9642"
13SRC_URI[sha256sum] = "421d63b414162237a72867061f1bd3e3752a0d962cd5d30b5e933ddad8a14d3b"
14
15inherit update-alternatives
16
17CFLAGS += "-I${STAGING_INCDIR}/tirpc"
18LIBS += "-ltirpc"
19
20do_configure () {
21    ./configure --prefix=${prefix}
22    echo "LDFLAGS=${LDFLAGS}" > MCONFIG
23    echo "CC=${CC}" >> MCONFIG
24    echo "LD=${LD}" >> MCONFIG
25    echo "CFLAGS=${CFLAGS}" >> MCONFIG
26    echo "LDFLAGS=${LDFLAGS}" >> MCONFIG
27    echo "LIBS=${LIBS}" >> MCONFIG
28}
29
30do_compile () {
31    oe_runmake 'CC=${CC}' 'LD=${LD}' 'LDFLAGS=${LDFLAGS}'
32}
33
34do_install () {
35    install -d ${D}${bindir}
36    install -d ${D}${mandir}/man1
37    install -d ${D}${mandir}/man8
38
39    # remove strip flag
40    sed -i 's/install -s/install/' rpcinfo/Makefile
41    sed -i 's/install -s/install/' rpcgen/Makefile
42
43    oe_runmake 'INSTALLROOT=${D}' 'BINMODE=0755' \
44    'DAEMONMODE=0755' 'MANMODE=0644' \
45    'BINDIR=${bindir}' 'SBINDIR=${sbindir}' \
46    'MANDIR=${mandir}' install
47}
48ALTERNATIVE_PRIORITY = "100"
49
50ALTERNATIVE:${PN} = "rpcinfo"
51ALTERNATIVE_LINK_NAME[rpcinfo] = "${bindir}/rpcinfo"
52