1SUMMARY = "The network configuration abstraction renderer"
2DESCRIPTION = "Netplan is a utility for easily configuring networking on a \
3linux system. You simply create a YAML description of the required network \
4interfaces and what each should be configured to do. From this description \
5Netplan will generate all the necessary configuration for your chosen renderer \
6tool."
7HOMEPAGE = "https://netplan.io"
8SECTION = "net/misc"
9
10LICENSE = "GPL-3.0-only"
11LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
12
13S = "${WORKDIR}/git"
14SRCREV = "3e522b7255310bdecca6c781137741dfc4abc021"
15PV = "0.104"
16
17SRC_URI = "git://github.com/CanonicalLtd/netplan.git;branch=main;protocol=https \
18           file://0001-Makefile-do-not-use-Werror.patch \
19           file://0001-Makefile-fix-parallel-build-failure.patch \
20           "
21
22SRC_URI:append:libc-musl = " file://0001-don-t-fail-if-GLOB_BRACE-is-not-defined.patch"
23
24DEPENDS = "glib-2.0 libyaml ${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}"
25
26PACKAGECONFIG ?= ""
27
28PACKAGECONFIG[tests] = ",,,python3-nose python3-coverage python3-netifaces python3-pycodestyle python3-pyflakes python3-pyyaml"
29
30RDEPENDS:${PN} = "python3 python3-core python3-netifaces python3-pyyaml util-linux-libuuid libnetplan"
31
32inherit pkgconfig systemd
33
34TARGET_CC_ARCH += "${LDFLAGS}"
35
36EXTRA_OEMAKE = "generate netplan/_features.py"
37EXTRA_OEMAKE =+ "${@bb.utils.contains('DISTRO_FEATURES','systemd','netplan-dbus dbus/io.netplan.Netplan.service','',d)}"
38
39do_install() {
40	install -d ${D}${sbindir} ${D}${libdir} ${D}${base_libdir}/netplan ${D}${datadir}/netplan/netplan/cli/commands ${D}${sysconfdir}/netplan
41	install -m 755 ${S}/generate ${D}${base_libdir}/netplan/
42	install -m 644 ${S}/netplan/*.py ${D}${datadir}/netplan/netplan
43	install -m 644 ${S}/netplan/cli/*.py ${D}${datadir}/netplan/netplan/cli
44	install -m 644 ${S}/netplan/cli/commands/*.py ${D}${datadir}/netplan/netplan/cli/commands
45	install -m 755 ${S}/src/netplan.script ${D}${datadir}/netplan/
46	ln -srf ${D}${datadir}/netplan/netplan.script ${D}${sbindir}/netplan
47	sed -i -e "s#/lib/netplan/generate#${base_libdir}/netplan/generate#" ${D}${datadir}/netplan/netplan/cli/utils.py
48
49	install -d ${D}/${systemd_unitdir}/system ${D}${systemd_unitdir}/system-generators
50	ln -srf ${D}/${base_libdir}/netplan/generate ${D}${systemd_unitdir}/system-generators
51
52	if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
53		install -d ${D}${datadir}/dbus-1/system.d ${D}${datadir}/dbus-1/system-services
54		install -m 755 ${S}/netplan-dbus ${D}${base_libdir}/netplan
55		install -m 644 ${S}/dbus/io.netplan.Netplan.conf ${D}${datadir}/dbus-1/system.d
56		install -m 644 ${S}/dbus/io.netplan.Netplan.service ${D}${datadir}/dbus-1/system-services
57		sed -i -e "s#^Exec=/lib/#Exec=${base_libdir}/#" ${D}${datadir}/dbus-1/system-services/io.netplan.Netplan.service
58	fi
59
60	install -m 755 ${S}/libnetplan.so.0.0 ${D}${libdir}
61        ln -rfs ${D}${libdir}/libnetplan.so.0.0 ${D}${libdir}/libnetplan.so
62}
63
64PACKAGES += "${PN}-dbus libnetplan"
65
66FILES:libnetplan = "${libdir}/libnetplan.so.0.0"
67FILES:${PN} = "${sbindir} ${base_libdir}/netplan/generate ${datadir}/netplan ${sysconfdir}/netplan ${systemd_unitdir}"
68FILES:${PN}-dbus = "${base_libdir}/netplan/netplan-dbus ${datadir}/dbus-1"
69