1SUMMARY = "Open source MQTT implementation"
2DESCRIPTION = "Mosquitto is an open source (Eclipse licensed) message broker \
3that implements the MQ Telemetry Transport protocol version 3.1, 3.1.1 and \
45, providing both an MQTT broker and several command-line clients. MQTT \
5provides a lightweight method of carrying out messaging using a \
6publish/subscribe model. "
7HOMEPAGE = "http://mosquitto.org/"
8SECTION = "console/network"
9LICENSE = "EPL-2.0 | EDL-1.0"
10LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=ca9a8f366c6babf593e374d0d7d58749 \
11                    file://edl-v10;md5=9f6accb1afcb570f8be65039e2fcd49e \
12                    file://epl-v20;md5=2dd765ca47a05140be15ebafddbeadfe \
13                    file://NOTICE.md;md5=a7a91b4754c6f7995020d1b49bc829c6 \
14"
15DEPENDS = "uthash cjson"
16
17SRC_URI = "http://mosquitto.org/files/source/mosquitto-${PV}.tar.gz \
18           file://mosquitto.init \
19           file://1571.patch \
20"
21
22SRC_URI[sha256sum] = "d0dde8fdb12caf6e2426b4f28081919a2fce3448773bdb8af0d3cd5fe5776925"
23
24inherit systemd update-rc.d useradd cmake pkgconfig
25
26PACKAGECONFIG ??= "ssl dlt websockets \
27                  ${@bb.utils.filter('DISTRO_FEATURES','systemd', d)} \
28                  "
29
30PACKAGECONFIG[manpages] = "-DDOCUMENTATION=ON,-DDOCUMENTATION=OFF,libxslt-native docbook-xsl-stylesheets-native"
31PACKAGECONFIG[dns-srv] = "-DWITH_SRV=ON,-DWITH_SRV=OFF,c-ares"
32PACKAGECONFIG[ssl] = "-DWITH_TLS=ON -DWITH_TLS_PSK=ON -DWITH_EC=ON,-DWITH_TLS=OFF -DWITH_TLS_PSK=OFF -DWITH_EC=OFF,openssl"
33PACKAGECONFIG[systemd] = "-DWITH_SYSTEMD=ON,-DWITH_SYSTEMD=OFF,systemd"
34PACKAGECONFIG[websockets] = "-DWITH_WEBSOCKETS=ON,-DWITH_WEBSOCKETS=OFF,libwebsockets"
35PACKAGECONFIG[dlt] = "-DWITH_DLT=ON,-DWITH_DLT=OFF,dlt-daemon"
36
37EXTRA_OECMAKE = " \
38    -DWITH_BUNDLED_DEPS=OFF \
39    -DWITH_ADNS=ON \
40"
41
42do_install:append() {
43    install -d ${D}${systemd_unitdir}/system/
44    install -m 0644 ${S}/service/systemd/mosquitto.service.notify ${D}${systemd_unitdir}/system/mosquitto.service
45
46    install -d ${D}${sysconfdir}/init.d/
47    install -m 0755 ${WORKDIR}/mosquitto.init ${D}${sysconfdir}/init.d/mosquitto
48    sed -i -e 's,@SBINDIR@,${sbindir},g' \
49        -e 's,@BASE_SBINDIR@,${base_sbindir},g' \
50        -e 's,@LOCALSTATEDIR@,${localstatedir},g' \
51        -e 's,@SYSCONFDIR@,${sysconfdir},g' \
52        ${D}${sysconfdir}/init.d/mosquitto
53}
54
55PACKAGES += "libmosquitto1 libmosquittopp1 ${PN}-clients"
56
57PACKAGE_BEFORE_PN = "${PN}-examples"
58
59FILES:${PN} = "${sbindir}/mosquitto \
60               ${bindir}/mosquitto_passwd \
61               ${bindir}/mosquitto_ctrl \
62               ${libdir}/mosquitto_dynamic_security.so \
63               ${sysconfdir}/mosquitto \
64               ${sysconfdir}/init.d \
65               ${systemd_unitdir}/system/mosquitto.service \
66"
67
68CONFFILES:${PN} += "${sysconfdir}/mosquitto/mosquitto.conf"
69
70FILES:libmosquitto1 = "${libdir}/libmosquitto.so.*"
71
72FILES:libmosquittopp1 = "${libdir}/libmosquittopp.so.*"
73
74FILES:${PN}-clients = "${bindir}/mosquitto_pub \
75                       ${bindir}/mosquitto_sub \
76                       ${bindir}/mosquitto_rr \
77"
78
79FILES:${PN}-examples = "${sysconfdir}/mosquitto/*.example"
80
81SYSTEMD_SERVICE:${PN} = "mosquitto.service"
82
83INITSCRIPT_NAME = "mosquitto"
84INITSCRIPT_PARAMS = "defaults 30"
85
86USERADD_PACKAGES = "${PN}"
87USERADD_PARAM:${PN} = "--system --no-create-home --shell /bin/false \
88                       --user-group mosquitto"
89
90BBCLASSEXTEND += "native nativesdk"
91