1SECTION = "console/network"
2SUMMARY = "Internet Software Consortium DHCP Relay Agent"
3DESCRIPTION = "A DHCP relay agent passes DHCP requests from one \
4LAN to another, so that a DHCP server is not needed on every LAN."
5
6HOMEPAGE = "http://www.isc.org/"
7
8LICENSE = "MPL-2.0"
9LIC_FILES_CHKSUM = "file://LICENSE;md5=c463f4afde26d9eb60f14f50aeb85f8f"
10
11DEPENDS = "openssl libcap zlib"
12
13SRC_URI = "https://downloads.isc.org/isc/dhcp/${PV}/dhcp-${PV}.tar.gz \
14           file://default-relay \
15           file://init-relay \
16           file://dhcrelay.service \
17           file://0001-Makefile.am-only-build-dhcrelay.patch \
18           file://0002-bind-Makefile.in-disable-backtrace.patch \
19           file://0003-bind-Makefile.in-regenerate-configure.patch \
20           file://CVE-2022-2928.patch \
21           file://CVE-2022-2929.patch \
22           "
23
24SRC_URI[sha256sum] = "0e3ec6b4c2a05ec0148874bcd999a66d05518378d77421f607fb0bc9d0135818"
25
26UPSTREAM_CHECK_URI = "http://ftp.isc.org/isc/dhcp/"
27UPSTREAM_CHECK_REGEX = "(?P<pver>\d+\.\d+\.(\d+?))/"
28
29S = "${WORKDIR}/dhcp-${PV}"
30
31inherit autotools-brokensep systemd pkgconfig
32
33SYSTEMD_SERVICE:${PN} = "dhcrelay.service"
34SYSTEMD_AUTO_ENABLE:${PN} = "disable"
35
36CFLAGS += "-D_GNU_SOURCE -fcommon"
37LDFLAGS:append = " -pthread"
38
39EXTRA_OECONF = "--enable-paranoia \
40                --disable-static \
41                --enable-libtool \
42                --with-randomdev=/dev/random \
43               "
44
45# Enable shared libs per dhcp README
46do_configure:prepend () {
47    cp configure.ac+lt configure.ac
48}
49
50do_install:append () {
51    install -Dm 0644 ${WORKDIR}/default-relay ${D}${sysconfdir}/default/dhcp-relay
52
53    if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
54        install -d ${D}${systemd_unitdir}/system
55        install -m 0644 ${WORKDIR}/dhcrelay.service ${D}${systemd_unitdir}/system
56        sed -i -e 's,@SBINDIR@,${sbindir},g' ${D}${systemd_unitdir}/system/dhcrelay.service
57        sed -i -e 's,@SYSCONFDIR@,${sysconfdir},g' ${D}${systemd_unitdir}/system/dhcrelay.service
58    else
59        install -d ${D}${sysconfdir}/init.d
60        install -m 0755 ${WORKDIR}/init-relay ${D}${sysconfdir}/init.d/dhcp-relay
61    fi
62}
63
64PARALLEL_MAKE = ""
65