xref: /OK3568_Linux_fs/yocto/meta-openembedded/meta-gnome/recipes-gnome/mutter/mutter_42.0.bb (revision 4882a59341e53eb6f0b4789bf948001014eff981) 
1SUMMARY = "Window and compositing manager based on Clutter"
2LICENSE = "GPL-2.0-only"
3LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
4
5DEPENDS = " \
6    xserver-xorg-cvt-native \
7    wayland-native \
8    virtual/libx11 \
9    graphene \
10    gtk+3 \
11    gdk-pixbuf \
12    cairo \
13    pango \
14    gsettings-desktop-schemas \
15    json-glib \
16    gnome-desktop \
17    gnome-settings-daemon \
18    libxtst \
19    libxkbfile \
20    xinerama \
21    xwayland \
22"
23
24GNOMEBASEBUILDCLASS = "meson"
25
26inherit gnomebase gsettings gobject-introspection gettext features_check
27
28SRC_URI[archive.sha256sum] = "d1e240446b7f8cd8a3ff9daae336c1c9016193ba7e0769c79a5e6c03849022e5"
29
30# x11 is still manadatory - see meson.build
31REQUIRED_DISTRO_FEATURES = "wayland x11 polkit"
32
33# systemd can be replaced by libelogind (not available atow - make systemd
34# mandatory distro feature)
35LOGIND ?= "systemd"
36REQUIRED_DISTRO_FEATURES += "systemd"
37
38# profiler requires sysprof 3.34 which is not willing to build atow
39PACKAGECONFIG ??= " \
40    native-backend \
41    ${@bb.utils.contains('DISTRO_FEATURES', 'opengl x11', 'opengl glx', '', d)} \
42    sm \
43    startup-notification \
44"
45
46EXTRA_OEMESON += " \
47    -Dtests=false \
48    -Dnative_tests=false \
49    -Dxwayland_path=${bindir}/Xwayland \
50"
51
52# combi-config - see meson_options.txt for more details
53PACKAGECONFIG[native-backend] = "-Dnative_backend=true -Dudev=true, -Dnative_backend=false -Dudev=false, libdrm virtual/libgbm libinput ${LOGIND} virtual/egl virtual/libgles2 udev"
54PACKAGECONFIG[opengl] = "-Dopengl=true, -Dopengl=true, virtual/libgl"
55PACKAGECONFIG[glx] = "-Dglx=true, -Dglx=false"
56PACKAGECONFIG[libwacom] = "-Dlibwacom=true, -Dlibwacom=false, libwacom"
57# Remove depending on pipewire-0.2 when mutter is upgraded to 3.36+
58PACKAGECONFIG[remote-desktop] = "-Dremote_desktop=true, -Dremote_desktop=false, pipewire"
59PACKAGECONFIG[sm] = "-Dsm=true, -Dsm=false, libsm"
60PACKAGECONFIG[profiler] = "-Dprofiler=true,-Dprofiler=false,sysprof"
61PACKAGECONFIG[startup-notification] = "-Dstartup_notification=true, -Dstartup_notification=false, startup-notification, startup-notification"
62
63MUTTER_API_NAME = "mutter-10"
64
65do_install:append() {
66    # Add gir links in standard paths. That makes dependents life much easier
67    # to find them
68    install -d ${D}${datadir}/gir-1.0
69    for gir_full in `find ${D}${libdir}/${MUTTER_API_NAME} -name '*.gir'`; do
70        gir=`basename "$gir_full"`
71        ln -sr "${D}${libdir}/${MUTTER_API_NAME}/$gir" "${D}${datadir}/gir-1.0/$gir"
72    done
73}
74
75GSETTINGS_PACKAGE = "${PN}-gsettings"
76
77PACKAGES =+ "${PN}-tests ${PN}-gsettings"
78
79FILES:${PN} += " \
80    ${datadir}/gnome-control-center \
81    ${libdir}/${MUTTER_API_NAME}/lib*${SOLIBS} \
82    ${libdir}/${MUTTER_API_NAME}/*.typelib \
83    ${libdir}/${MUTTER_API_NAME}/plugins \
84"
85
86FILES:${PN}-tests += " \
87    ${datadir}/installed-tests \
88    ${datadir}/${MUTTER_API_NAME}/tests \
89    ${libexecdir}/installed-tests/${MUTTER_API_NAME} \
90"
91
92FILES:${PN}-dev += " \
93    ${libdir}/${MUTTER_API_NAME}/*.gir \
94    ${libdir}/${MUTTER_API_NAME}/lib*.so \
95"
96
97RDEPENDS:${PN} += "zenity ${PN}-gsettings"
98
99