1SUMMARY = "Password and keyring managing daemon"
2HOMEPAGE = "http://www.gnome.org/"
3BUGTRACKER = "https://bugzilla.gnome.org/"
4SECTION = "x11/gnome"
5
6LICENSE = "GPL-2.0-or-later & LGPL-2.0-or-later & LGPL-2.1-or-later"
7LIC_FILES_CHKSUM = " \
8    file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
9    file://COPYING.LIB;md5=4fbd65380cdd255951079008b364516c \
10"
11
12DEPENDS = " \
13    glib-2.0-native \
14    gtk+3 \
15    gcr \
16    libgcrypt \
17    ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)} \
18"
19
20inherit gnomebase gsettings features_check remove-libtool gettext
21
22REQUIRED_DISTRO_FEATURES = "x11"
23
24SRC_URI[archive.sha256sum] = "a3d24db08ee2fdf240fbbf0971a98c8ee295aa0e1a774537f4ea938038a3b931"
25SRC_URI += " \
26    file://0001-Set-paths-to-ssh-agent-and-ssh-add-by-configure-opti.patch \
27    file://musl.patch \
28"
29
30PACKAGECONFIG ??= "ssh-agent"
31PACKAGECONFIG[ssh-agent] = "--enable-ssh-agent --with-ssh-agent-path=${bindir}/ssh-agent --with-ssh-add-path=${bindir}/ssh-add,--disable-ssh-agent,,openssh-misc"
32
33EXTRA_OECONF = " \
34    --disable-doc \
35    ${@bb.utils.contains('DISTRO_FEATURES', 'pam', '--enable-pam --with-pam-dir=${base_libdir}/security', '--disable-pam', d)} \
36"
37
38FILES:${PN} += " \
39    ${datadir}/dbus-1/services \
40    ${datadir}/p11-kit \
41    ${datadir}/xdg-desktop-portal \
42    ${base_libdir}/security/*${SOLIBSDEV} \
43    ${libdir}/pkcs11/gnome-keyring-pkcs11.so \
44"
45# fix | gnome-keyring-daemon: insufficient process capabilities, unsecure memory might get used
46pkg_postinst:${PN} () {
47    setcap cap_ipc_lock+ep $D/${bindir}/gnome-keyring-daemon
48}
49PACKAGE_WRITE_DEPS += "libcap-native"
50