1require ${BPN}.inc
2
3DEPENDS = " \
4    ${BPN}-native intltool-native gperf-native \
5    glib-2.0 gtk+3 libgdata libxml2 icu \
6    dbus db virtual/libiconv zlib libsoup-2.4 libical nss libsecret \
7"
8
9inherit pkgconfig gsettings gobject-introspection features_check cmake gtk-doc gettext perlnative vala
10
11REQUIRED_DISTRO_FEATURES = "x11"
12
13SRC_URI += " \
14    file://0001-cmake-Do-not-export-CC-into-gir-compiler.patch \
15    file://0001-CMakeLists.txt-Remove-TRY_RUN-for-iconv.patch \
16    file://0002-CMakeLists.txt-remove-CHECK_C_SOURCE_RUNS-check.patch \
17    file://0003-contact-Replace-the-Novell-sample-contact-with-somet.patch \
18    file://0004-call-native-helpers.patch \
19    file://iconv-detect.h \
20"
21
22LKSTRFTIME = "HAVE_LKSTRFTIME=ON"
23LKSTRFTIME:libc-musl = "HAVE_LKSTRFTIME=OFF"
24
25EXTRA_OECMAKE = " \
26    -DSYSCONF_INSTALL_DIR=${sysconfdir} \
27    -DWITH_KRB5=OFF \
28    -DENABLE_GOA=OFF \
29    -DENABLE_GOOGLE_AUTH=OFF \
30    -DENABLE_WEATHER=OFF \
31    -DVAPIGEN=${STAGING_BINDIR_NATIVE}/vapigen \
32    ${@bb.utils.contains('GI_DATA_ENABLED', 'True', '-DENABLE_INTROSPECTION=ON -DENABLE_VALA_BINDINGS=ON', '-DENABLE_INTROSPECTION=OFF', d)} \
33    -D${LKSTRFTIME} \
34    -DLIB_SUFFIX=${@d.getVar('baselib').replace('lib', '')} \
35"
36
37EXTRA_OECMAKE:append:class-target = " -DG_IR_COMPILER=${STAGING_BINDIR}/g-ir-compiler-wrapper"
38EXTRA_OECMAKE:append:class-target = " -DG_IR_SCANNER=${STAGING_BINDIR}/g-ir-scanner-wrapper"
39
40PACKAGECONFIG[canberra] = "-DENABLE_CANBERRA=ON,-DENABLE_CANBERRA=OFF,libcanberra"
41PACKAGECONFIG[oauth]    = "-DENABLE_OAUTH2=ON,-DENABLE_OAUTH2=OFF,webkitgtk json-glib"
42PACKAGECONFIG[goa]    = "-DENABLE_GOA=ON,-DENABLE_GOA=OFF,gnome-online-accounts"
43
44# BROKEN: due missing pkg-config in openldap eds' cmake finds host-libs when
45# searching for openldap-libs
46PACKAGECONFIG[openldap] = "-DWITH_OPENLDAP=ON,-DWITH_OPENLDAP=OFF,openldap"
47
48# -ldb needs this on some platforms
49LDFLAGS += "-lpthread -lgmodule-2.0 -lgthread-2.0"
50
51# invokes libraries from build host
52GI_DATA_ENABLED:libc-musl="False"
53
54do_configure:append () {
55    cp ${WORKDIR}/iconv-detect.h ${S}/src
56    # avoid writing perl-native path into csv2vcard shebang
57    sed -i "s|@PERL@|${bindir}/perl|" ${S}/src/tools/addressbook-export/csv2vcard.in
58}
59
60FILES:${PN} =+ " \
61    ${datadir}/dbus-1 \
62    ${datadir}/evolution-data-server-*/ui/ \
63    ${systemd_user_unitdir} \
64"
65
66RDEPENDS:${PN} += "perl"
67