1TEMPLATE = subdirs
2
3QT_FOR_CONFIG += location-private
4include($$OUT_PWD/location/qtlocation-config.pri)
5include($$OUT_PWD/positioning/qtpositioning-config.pri)
6
7clip2tri.subdir = 3rdparty/clip2tri
8poly2tri.subdir = 3rdparty/poly2tri
9clipper.subdir = 3rdparty/clipper
10
11SUBDIRS += clip2tri clipper poly2tri
12clip2tri.depends = clipper poly2tri
13
14SUBDIRS += positioning
15positioning.depends = clip2tri
16
17qtHaveModule(quick) {
18    SUBDIRS += positioningquick location
19    positioningquick.depends += positioning
20    location.depends += positioningquick clip2tri
21
22    plugins.depends += location
23
24    SUBDIRS += imports
25    imports.depends += positioningquick positioning location
26}
27plugins.depends += positioning
28SUBDIRS += plugins
29
30!android:contains(QT_CONFIG, private_tests) {
31    SUBDIRS += positioning_doc_snippets
32    positioning_doc_snippets.subdir = positioning/doc/snippets
33
34    #plugin dependency required during static builds
35    positioning_doc_snippets.depends = positioning plugins
36
37    qtHaveModule(quick) {
38        SUBDIRS += location_doc_snippets
39        location_doc_snippets.subdir = location/doc/snippets
40
41        #plugin dependency required during static builds
42        location_doc_snippets.depends = location plugins
43    }
44}
45