1TARGET = qtgeoservices_mapboxgl
2
3QT += \
4    quick-private \
5    location-private \
6    positioning-private \
7    network \
8    sql
9
10HEADERS += \
11    qgeoserviceproviderpluginmapboxgl.h \
12    qgeomappingmanagerenginemapboxgl.h \
13    qgeomapmapboxgl.h \
14    qgeomapmapboxgl_p.h \
15    qmapboxglstylechange_p.h \
16    qsgmapboxglnode.h
17
18SOURCES += \
19    qgeoserviceproviderpluginmapboxgl.cpp \
20    qgeomappingmanagerenginemapboxgl.cpp \
21    qgeomapmapboxgl.cpp \
22    qmapboxglstylechange.cpp \
23    qsgmapboxglnode.cpp
24
25# Mapbox GL Native is always a static
26# library linked to this plugin
27QMAKE_CXXFLAGS += \
28    -DQT_MAPBOXGL_STATIC
29
30RESOURCES += mapboxgl.qrc
31
32OTHER_FILES += \
33    mapboxgl_plugin.json
34
35INCLUDEPATH += ../../../3rdparty/mapbox-gl-native/platform/qt/include
36
37include(../../../3rdparty/zlib_dependency.pri)
38
39load(qt_build_paths)
40LIBS_PRIVATE += -L$$MODULE_BASE_OUTDIR/lib -lqmapboxgl$$qtPlatformTargetSuffix()
41
42qtConfig(icu) {
43    QMAKE_USE_PRIVATE += icu
44}
45
46PLUGIN_TYPE = geoservices
47PLUGIN_CLASS_NAME = QGeoServiceProviderFactoryMapboxGL
48load(qt_plugin)
49