xref: /rk3399_ARM-atf/bl31/bl31.ld.S (revision f0e240d7f59cbf1cb99fc358ddec967cad8bf3df) 
1/*
2 * Copyright (c) 2013-2014, ARM Limited and Contributors. All rights reserved.
3 *
4 * Redistribution and use in source and binary forms, with or without
5 * modification, are permitted provided that the following conditions are met:
6 *
7 * Redistributions of source code must retain the above copyright notice, this
8 * list of conditions and the following disclaimer.
9 *
10 * Redistributions in binary form must reproduce the above copyright notice,
11 * this list of conditions and the following disclaimer in the documentation
12 * and/or other materials provided with the distribution.
13 *
14 * Neither the name of ARM nor the names of its contributors may be used
15 * to endorse or promote products derived from this software without specific
16 * prior written permission.
17 *
18 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
19 * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
20 * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
21 * ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE
22 * LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
23 * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
24 * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
25 * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
26 * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
27 * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
28 * POSSIBILITY OF SUCH DAMAGE.
29 */
30
31#include <platform_def.h>
32
33OUTPUT_FORMAT(PLATFORM_LINKER_FORMAT)
34OUTPUT_ARCH(PLATFORM_LINKER_ARCH)
35ENTRY(bl31_entrypoint)
36
37
38MEMORY {
39    RAM (rwx): ORIGIN = BL31_BASE, LENGTH = BL31_LIMIT
40}
41
42
43SECTIONS
44{
45    . = BL31_BASE;
46    ASSERT(. == ALIGN(4096),
47           "BL31_BASE address is not aligned on a page boundary.")
48
49    ro . : {
50        __RO_START__ = .;
51        *bl31_entrypoint.o(.text*)
52        *(.text*)
53        *(.rodata*)
54
55        /* Ensure 8-byte alignment for descriptors and ensure inclusion */
56        . = ALIGN(8);
57        __RT_SVC_DESCS_START__ = .;
58        KEEP(*(rt_svc_descs))
59        __RT_SVC_DESCS_END__ = .;
60
61        *(.vectors)
62        __RO_END_UNALIGNED__ = .;
63        /*
64         * Memory page(s) mapped to this section will be marked as read-only,
65         * executable.  No RW data from the next section must creep in.
66         * Ensure the rest of the current memory page is unused.
67         */
68        . = NEXT(4096);
69        __RO_END__ = .;
70    } >RAM
71
72    .data . : {
73        __DATA_START__ = .;
74        *(.data*)
75        __DATA_END__ = .;
76    } >RAM
77
78#ifdef BL31_PROGBITS_LIMIT
79    ASSERT(. <= BL31_PROGBITS_LIMIT, "BL3-1 progbits has exceeded its limit.")
80#endif
81
82    stacks (NOLOAD) : {
83        __STACKS_START__ = .;
84        *(tzfw_normal_stacks)
85        __STACKS_END__ = .;
86    } >RAM
87
88    /*
89     * The .bss section gets initialised to 0 at runtime.
90     * Its base address must be 16-byte aligned.
91     */
92    .bss : ALIGN(16) {
93        __BSS_START__ = .;
94        *(.bss*)
95        *(COMMON)
96        __BSS_END__ = .;
97    } >RAM
98
99    /*
100     * The xlat_table section is for full, aligned page tables (4K).
101     * Removing them from .bss avoids forcing 4K alignment on
102     * the .bss section and eliminates the unecessary zero init
103     */
104    xlat_table (NOLOAD) : {
105        *(xlat_table)
106    } >RAM
107
108    /*
109     * The base address of the coherent memory section must be page-aligned (4K)
110     * to guarantee that the coherent data are stored on their own pages and
111     * are not mixed with normal data.  This is required to set up the correct
112     * memory attributes for the coherent data page tables.
113     */
114    coherent_ram (NOLOAD) : ALIGN(4096) {
115        __COHERENT_RAM_START__ = .;
116        *(tzfw_coherent_mem)
117        __COHERENT_RAM_END_UNALIGNED__ = .;
118        /*
119         * Memory page(s) mapped to this section will be marked
120         * as device memory.  No other unexpected data must creep in.
121         * Ensure the rest of the current memory page is unused.
122         */
123        . = NEXT(4096);
124        __COHERENT_RAM_END__ = .;
125    } >RAM
126
127    __BL31_END__ = .;
128
129    __BSS_SIZE__ = SIZEOF(.bss);
130    __COHERENT_RAM_UNALIGNED_SIZE__ =
131        __COHERENT_RAM_END_UNALIGNED__ - __COHERENT_RAM_START__;
132
133    ASSERT(. <= BL31_LIMIT, "BL3-1 image has exceeded its limit.")
134}
135