xref: /OK3568_Linux_fs/yocto/poky/meta/recipes-support/nettle/nettle_3.7.3.bb (revision 4882a59341e53eb6f0b4789bf948001014eff981) 
1SUMMARY = "A low level cryptographic library"
2DESCRIPTION = "Nettle is a cryptographic library that is designed to fit easily in more or less any context: In crypto toolkits for object-oriented languages (C++, Python, Pike, ...), in applications like LSH or GNUPG, or even in kernel space."
3HOMEPAGE = "http://www.lysator.liu.se/~nisse/nettle/"
4DESCRIPTION = "It tries to solve a problem of providing a common set of \
5cryptographic algorithms for higher-level applications by implementing a \
6context-independent set of cryptographic algorithms"
7SECTION = "libs"
8LICENSE = "LGPL-3.0-or-later | GPL-2.0-or-later"
9
10LIC_FILES_CHKSUM = "file://COPYING.LESSERv3;md5=6a6a8e020838b23406c81b19c1d46df6 \
11                    file://COPYINGv2;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
12                    file://serpent-decrypt.c;beginline=14;endline=36;md5=ca0d220bc413e1842ecc507690ce416e \
13                    file://serpent-set-key.c;beginline=14;endline=36;md5=ca0d220bc413e1842ecc507690ce416e"
14
15DEPENDS += "gmp"
16
17SRC_URI = "${GNU_MIRROR}/${BPN}/${BP}.tar.gz \
18           file://Add-target-to-only-build-tests-not-run-them.patch \
19           file://run-ptest \
20           file://check-header-files-of-openssl-only-if-enable_.patch \
21           "
22
23SRC_URI:append:class-target = "\
24            file://dlopen-test.patch \
25            "
26
27SRC_URI[sha256sum] = "661f5eb03f048a3b924c3a8ad2515d4068e40f67e774e8a26827658007e3bcf0"
28
29UPSTREAM_CHECK_REGEX = "nettle-(?P<pver>\d+(\.\d+)+)\.tar"
30
31inherit autotools ptest multilib_header
32
33EXTRA_AUTORECONF += "--exclude=aclocal"
34
35EXTRA_OECONF = "--disable-openssl"
36
37do_compile_ptest() {
38        oe_runmake buildtest
39}
40
41do_install:append() {
42    oe_multilib_header nettle/version.h
43}
44
45do_install_ptest() {
46        install -d ${D}${PTEST_PATH}/testsuite/
47        install ${S}/testsuite/gold-bug.txt ${D}${PTEST_PATH}/testsuite/
48        install ${S}/testsuite/*-test ${D}${PTEST_PATH}/testsuite/
49        # tools can be found in PATH, not in ../tools/
50        sed -i -e 's|../tools/||' ${D}${PTEST_PATH}/testsuite/*-test
51        install ${B}/testsuite/*-test ${D}${PTEST_PATH}/testsuite/
52}
53
54RDEPENDS:${PN}-ptest += "${PN}-dev"
55INSANE_SKIP:${PN}-ptest += "dev-deps"
56
57BBCLASSEXTEND = "native nativesdk"
58