xref: /OK3568_Linux_fs/yocto/poky/meta/recipes-support/libgcrypt/libgcrypt_1.9.4.bb (revision 4882a59341e53eb6f0b4789bf948001014eff981) 
1SUMMARY = "General purpose cryptographic library based on the code from GnuPG"
2DESCRIPTION = "A cryptography library developed as a separated module of GnuPG. \
3It can also be used independently of GnuPG, but depends on its error-reporting \
4library Libgpg-error."
5HOMEPAGE = "http://directory.fsf.org/project/libgcrypt/"
6BUGTRACKER = "https://bugs.g10code.com/gnupg/index"
7SECTION = "libs"
8
9# helper program gcryptrnd and getrandom are under GPL, rest LGPL
10LICENSE = "GPL-2.0-or-later & LGPL-2.1-or-later & GPL-3.0-or-later"
11LICENSE:${PN} = "LGPL-2.1-or-later"
12LICENSE:${PN}-dev = "GPL-2.0-or-later & LGPL-2.1-or-later"
13LICENSE:dumpsexp-dev = "GPL-3.0-or-later"
14
15LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
16                    file://COPYING.LIB;md5=bbb461211a33b134d42ed5ee802b37ff \
17                    file://LICENSES;md5=42fa35a25e138166cc40588387f9159d \
18                    "
19
20DEPENDS = "libgpg-error"
21
22UPSTREAM_CHECK_URI = "https://gnupg.org/download/index.html"
23SRC_URI = "${GNUPG_MIRROR}/libgcrypt/libgcrypt-${PV}.tar.bz2 \
24           file://0001-libgcrypt-fix-m4-file-for-oe-core.patch \
25           file://0003-tests-bench-slope.c-workaround-ICE-failure-on-mips-w.patch \
26           file://0002-libgcrypt-fix-building-error-with-O2-in-sysroot-path.patch \
27           file://0004-tests-Makefile.am-fix-undefined-reference-to-pthread.patch \
28           file://0001-Makefile.am-add-a-missing-space.patch \
29           "
30SRC_URI[sha256sum] = "ea849c83a72454e3ed4267697e8ca03390aee972ab421e7df69dfe42b65caaf7"
31
32# Below whitelisted CVEs are disputed and not affecting crypto libraries for any distro.
33CVE_CHECK_IGNORE += "CVE-2018-12433 CVE-2018-12438"
34
35BINCONFIG = "${bindir}/libgcrypt-config"
36
37inherit autotools texinfo binconfig-disabled pkgconfig
38
39EXTRA_OECONF = "--disable-asm"
40EXTRA_OEMAKE:class-target = "LIBTOOLFLAGS='--tag=CC'"
41
42PACKAGECONFIG ??= "capabilities"
43PACKAGECONFIG[capabilities] = "--with-capabilities,--without-capabilities,libcap"
44
45do_configure:prepend () {
46	# Else this could be used in preference to the one in aclocal-copy
47	rm -f ${S}/m4/gpg-error.m4
48}
49
50# libgcrypt.pc is added locally and thus installed here
51do_install:append() {
52	install -d ${D}/${libdir}/pkgconfig
53	install -m 0644 ${B}/src/libgcrypt.pc ${D}/${libdir}/pkgconfig/
54}
55
56PACKAGES =+ "dumpsexp-dev"
57
58FILES:${PN}-dev += "${bindir}/hmac256"
59FILES:dumpsexp-dev += "${bindir}/dumpsexp"
60
61BBCLASSEXTEND = "native nativesdk"
62