1SUMMARY = "Real-time performance monitoring"
2DESCRIPTION = "Netdata is high-fidelity infrastructure monitoring and troubleshooting. \
3               Open-source, free, preconfigured, opinionated, and always real-time."
4HOMEPAGE = "https://github.com/netdata/netdata/"
5LICENSE = "GPL-3.0-only"
6LIC_FILES_CHKSUM = "file://LICENSE;md5=fc9b848046ef54b5eaee6071947abd24"
7
8DEPENDS += "libuv util-linux zlib"
9
10SRC_URI = "https://github.com/${BPN}/${BPN}/releases/download/v${PV}/${BPN}-v${PV}.tar.gz"
11SRC_URI[sha256sum] = "8ea0786df0e952209c14efeb02e25339a0769aa3edc029e12816b8ead24a82d7"
12
13# default netdata.conf for netdata configuration
14SRC_URI += "file://netdata.conf"
15
16# file for providing systemd service support
17SRC_URI += "file://netdata.service"
18
19UPSTREAM_CHECK_URI = "https://github.com/netdata/netdata/releases"
20
21S = "${WORKDIR}/${BPN}-v${PV}"
22
23# Stop sending anonymous statistics to Google Analytics
24NETDATA_ANONYMOUS ??= "enabled"
25
26inherit pkgconfig autotools-brokensep useradd systemd
27
28LIBS:toolchain-clang:x86 = "-latomic"
29LIBS:riscv64 = "-latomic"
30LIBS:riscv32 = "-latomic"
31LIBS:mips = "-latomic"
32export LIBS
33
34#systemd
35SYSTEMD_PACKAGES = "${PN}"
36SYSTEMD_SERVICE:${PN} = "netdata.service"
37SYSTEMD_AUTO_ENABLE:${PN} = "enable"
38
39#User specific
40USERADD_PACKAGES = "${PN}"
41USERADD_PARAM:${PN} = "--system --no-create-home --home-dir ${localstatedir}/run/netdata --user-group netdata"
42
43PACKAGECONFIG ??= "https"
44PACKAGECONFIG[cloud] = "--enable-cloud, --disable-cloud, json-c"
45PACKAGECONFIG[compression] = "--enable-compression, --disable-compression, lz4"
46PACKAGECONFIG[https] = "--enable-https, --disable-https, openssl"
47
48# ebpf doesn't compile (or detect) the cross compilation well
49EXTRA_OECONF += "--disable-ebpf"
50
51do_install:append() {
52    #set S UID for plugins
53    chmod 4755 ${D}${libexecdir}/netdata/plugins.d/apps.plugin
54
55    if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
56        # Install systemd unit files
57        install -d ${D}${systemd_unitdir}/system
58        install -m 0644 ${WORKDIR}/netdata.service ${D}${systemd_unitdir}/system
59        sed -i -e 's,@@datadir,${datadir_native},g' ${D}${systemd_unitdir}/system/netdata.service
60    fi
61
62    # Install default netdata.conf
63    install -d ${D}${sysconfdir}/netdata
64    install -m 0644 ${WORKDIR}/netdata.conf ${D}${sysconfdir}/netdata/
65    sed -i -e 's,@@sysconfdir,${sysconfdir},g' ${D}${sysconfdir}/netdata/netdata.conf
66    sed -i -e 's,@@libdir,${libexecdir},g' ${D}${sysconfdir}/netdata/netdata.conf
67    sed -i -e 's,@@datadir,${datadir},g' ${D}${sysconfdir}/netdata/netdata.conf
68
69    if [ "${NETDATA_ANONYMOUS}" = "enabled" ]; then
70        touch ${D}${sysconfdir}/netdata/.opt-out-from-anonymous-statistics
71    fi
72
73    install --group netdata --owner netdata --directory ${D}${localstatedir}/cache/netdata
74    install --group netdata --owner netdata --directory ${D}${localstatedir}/lib/netdata
75
76    chown -R netdata:netdata ${D}${datadir}/netdata/web
77}
78
79FILES:${PN} += "${localstatedir}/cache/netdata/ ${localstatedir}/lib/netdata/"
80
81RDEPENDS:${PN} = "bash zlib"
82