xref: /OK3568_Linux_fs/yocto/meta-openembedded/meta-oe/recipes-support/libtinyxml/libtinyxml_2.6.2.bb (revision 4882a59341e53eb6f0b4789bf948001014eff981) 
1# (c) Copyright 2012  Hewlett-Packard Development Company, L.P.
2
3SUMMARY = "a simple, small, minimal, C++ XML parser"
4HOMEPAGE = "http://www.sourceforge.net/projects/tinyxml"
5LICENSE = "Zlib"
6LIC_FILES_CHKSUM = "file://readme.txt;md5=f8f366f3370dda889f60faa7db162cf4"
7SECTION = "libs"
8
9PR = "r5"
10
11SRC_URI = "${SOURCEFORGE_MIRROR}/tinyxml/tinyxml_${@'${PV}'.replace('.', '_')}.tar.gz \
12           file://enforce-use-stl.patch \
13           file://entity-encoding.patch"
14SRC_URI[md5sum] = "c1b864c96804a10526540c664ade67f0"
15SRC_URI[sha256sum] = "15bdfdcec58a7da30adc87ac2b078e4417dbe5392f3afb719f9ba6d062645593"
16
17S = "${WORKDIR}/tinyxml"
18
19EXTRA_CXXFLAGS = "-I. -fPIC"
20
21do_compile() {
22    ${CXX} ${CXXFLAGS} ${EXTRA_CXXFLAGS} -c -o tinyxml.o tinyxml.cpp
23    ${CXX} ${CXXFLAGS} ${EXTRA_CXXFLAGS} -c -o tinyxmlerror.o tinyxmlerror.cpp
24    ${CXX} ${CXXFLAGS} ${EXTRA_CXXFLAGS} -c -o tinyxmlparser.o tinyxmlparser.cpp
25    ${CXX} ${CXXFLAGS} \
26            -shared \
27            -Wl,-soname,libtinyxml.so.${PV} \
28            -o libtinyxml.so.${PV} \
29            ${LDFLAGS} \
30            tinyxml.o \
31            tinyxmlparser.o \
32            tinyxmlerror.o
33
34}
35
36do_install() {
37    install -d ${D}${libdir}
38    install -m 0755 ${S}/libtinyxml.so.${PV} ${D}${libdir}
39    ln -sf libtinyxml.so.${PV} ${D}${libdir}/libtinyxml.so
40
41    install -d ${D}${includedir}
42    install -m 0644 ${S}/tinyxml.h ${D}${includedir}
43}
44
45BBCLASSEXTEND = "native"
46