1SUMMARY = "VMcore extraction tool"
2DESCRIPTION = "\
3    This program is used to extract a subset of the memory available either \
4    via /dev/mem or /proc/vmcore (for crashdumps). It is used to get memory \
5    images without extra uneeded information (zero pages, userspace programs, \
6    etc). \
7"
8HOMEPAGE = "https://github.com/makedumpfile/makedumpfile"
9
10LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
11LICENSE = "GPL-2.0-only"
12
13SRCBRANCH ?= "master"
14SRCREV = "74bbdd14ec861552ace1ca63953eb2ef73e1f965"
15
16DEPENDS = "bzip2 zlib elfutils xz"
17RDEPENDS:${PN}-tools = "perl ${PN}"
18
19# mips would not compile.
20COMPATIBLE_HOST = "(x86_64|i.86|powerpc|arm|aarch64).*-linux"
21
22PACKAGES =+ "${PN}-tools"
23FILES:${PN}-tools = "${bindir}/*.pl"
24
25SRC_URI = "\
26    git://github.com/makedumpfile/makedumpfile;branch=${SRCBRANCH};protocol=https \
27    file://0001-makedumpfile-replace-hardcode-CFLAGS.patch \
28"
29
30S = "${WORKDIR}/git"
31
32UPSTREAM_CHECK_GITTAGREGEX = "(?P<pver>\d+(\.\d+)+)"
33
34SECTION = "base"
35
36# If we do not specify TARGET, makedumpfile will build for the host but use the
37# target gcc.
38#
39
40MAKEDUMPFILE_TARGET ?= "${TARGET_ARCH}"
41MAKEDUMPFILE_TARGET:powerpc = "ppc"
42
43EXTRA_OEMAKE = "\
44    LINKTYPE=static \
45    TARGET=${MAKEDUMPFILE_TARGET} \
46    ${PACKAGECONFIG_CONFARGS} \
47"
48
49PACKAGECONFIG ??= ""
50PACKAGECONFIG[lzo] = "USELZO=on,USELZO=off,lzo"
51PACKAGECONFIG[snappy] = "USESNAPPY=on,USESNAPPY=off,snappy"
52PACKAGECONFIG[zstd] = "USEZSTD=on,USEZSTD=off,zstd"
53
54do_install () {
55    mkdir -p ${D}/usr/bin
56    install -m 755 ${S}/makedumpfile ${D}/usr/bin
57    install -m 755 ${S}/makedumpfile-R.pl ${D}/usr/bin
58
59    mkdir -p ${D}/etc/
60    install -m 644 ${S}/makedumpfile.conf ${D}/etc/makedumpfile.conf.sample
61}
62