xref: /OK3568_Linux_fs/yocto/meta-openembedded/meta-oe/recipes-extended/minifi-cpp/minifi-cpp_0.7.0.bb (revision 4882a59341e53eb6f0b4789bf948001014eff981) 
1SUMMARY = "A subproject of Apache NiFi to collect data where it originates."
2DESCRIPTION = "MiNiFi--a subproject of Apache NiFi--is a complementary \
3data collection approach that supplements the core tenets of NiFi in dataflow \
4management, focusing on the collection of data at the source of its creation."
5HOMEPAGE = "https://nifi.apache.org/minifi/index.html"
6SECTION = "console/network"
7LICENSE = "Apache-2.0"
8LIC_FILES_CHKSUM = "file://LICENSE;md5=f9534eb5f4ab800b573a37bffc62f3a7"
9
10DEPENDS = "virtual/crypt expat flex python3 bison-native libxml2 nettle lz4"
11RDEPENDS:${PN} = "python3-core"
12
13SRCREV = "aa42957a2e227df41510047cece3cd606dc1cb6a"
14SRC_URI = "git://github.com/apache/nifi-minifi-cpp.git;branch=master;protocol=https \
15            https://curl.haxx.se/download/curl-7.64.0.tar.bz2;name=curl;subdir=git/thirdparty \
16            https://ftp.openbsd.org/pub/OpenBSD/LibreSSL/libressl-2.8.3.tar.gz;name=libressl;subdir=git/thirdparty \
17            ${DEBIAN_MIRROR}/main/o/ossp-uuid/ossp-uuid_1.6.2.orig.tar.gz;name=ossp-uuid;subdir=git/thirdparty \
18            file://fix-minifi-compile.patch \
19            file://fix-libressl-compile.patch \
20            file://fix-libressl-avoid-BSWAP-assembly-for-ARM-v6.patch \
21            file://fix-osspuuid-compile.patch \
22            file://fix-osspuuid-cross-compile.patch \
23            file://fix-osspuuid-musl-compile.patch \
24            file://fix-rocksdb-cross-compile.patch \
25            file://remove_const_due_to_std_lock_guard.patch \
26            file://0001-Add-lxml2-to-linker-cmdline-of-xml-is-found.patch \
27            file://0001-CMakeLists.txt-use-curl-local-source-tarball.patch \
28            file://0002-cmake-LibreSSL.cmake-use-libressl-local-source-tarba.patch \
29            file://0003-cmake-BundledOSSPUUID.cmake-use-ossp-uuid-local-sour.patch \
30            file://0001-civetweb-CMakeLists.txt-do-not-search-gcc-ar-and-gcc.patch \
31            file://0001-cxxopts-Add-limits-header.patch \
32            file://0001-Fix-build-with-libc.patch \
33            file://minifi.service \
34            file://systemd-volatile.conf \
35            file://sysvinit-volatile.conf \
36            "
37
38SRC_URI[curl.md5sum] = "d0bcc586873cfef08b4b9594e5395a33"
39SRC_URI[curl.sha256sum] = "d573ba1c2d1cf9d8533fadcce480d778417964e8d04ccddcc76e591d544cf2eb"
40SRC_URI[libressl.md5sum] = "0f1127bd21b4aa8495a910379c2ad936"
41SRC_URI[libressl.sha256sum] = "9b640b13047182761a99ce3e4f000be9687566e0828b4a72709e9e6a3ef98477"
42SRC_URI[ossp-uuid.md5sum] = "5db0d43a9022a6ebbbc25337ae28942f"
43SRC_URI[ossp-uuid.sha256sum] = "11a615225baa5f8bb686824423f50e4427acd3f70d394765bdff32801f0fd5b0"
44
45S = "${WORKDIR}/git"
46
47inherit pkgconfig cmake systemd
48
49SYSTEMD_PACKAGES = "minifi-cpp"
50SYSTEMD_SERVICE:${PN} = "minifi.service"
51SYSTEMD_AUTO_ENABLE = "disable"
52
53OECMAKE_FIND_ROOT_PATH_MODE_PROGRAM = "BOTH"
54
55EXTRA_OECMAKE += " \
56    -DHOST_SYS=${HOST_SYS} -DBUILD_SYS=${BUILD_SYS} \
57    -DSKIP_TESTS=ON \
58    -DGCC_AR=${STAGING_BINDIR_TOOLCHAIN}/${AR} \
59    -DGCC_RANLIB=${STAGING_BINDIR_TOOLCHAIN}/${RANLIB} \
60    "
61EXTRA_OECMAKE:append:toolchain-clang = " -DCMAKE_RANLIB=${STAGING_BINDIR_TOOLCHAIN}/${TARGET_PREFIX}llvm-ranlib"
62LDFLAGS:append:toolchain-clang = " -fuse-ld=lld"
63
64# RV lld errors out:
65# riscv64-yoe-linux-ld.lld: error: init.c:(.text+0x0): relocation R_RISCV_ALIGN requires unimplemented linker relaxation; recompile with -mno-relax
66LDFLAGS:remove:riscv32 = "-fuse-ld=lld"
67LDFLAGS:remove:riscv64 = "-fuse-ld=lld"
68
69# There are endian issues when communicating with the x86 nifi on the the mips and the ppc machines.
70COMPATIBLE_MACHINE:mips = "(!.*mips).*"
71COMPATIBLE_MACHINE:mips64 = "(!.*mips64).*"
72COMPATIBLE_MACHINE:powerpc = "(!.*ppc).*"
73
74TARGET_CFLAGS:append:riscv32 = " -fpic"
75TARGET_CXXFLAGS:append:riscv32 = " -fpic"
76TARGET_CFLAGS:append:riscv64 = " -fpic"
77TARGET_CXXFLAGS:append:riscv64 = " -fpic"
78
79do_install[cleandirs] += "${WORKDIR}/minifi-install"
80PSEUDO_CONSIDER_PATHS .= ",${WORKDIR}/minifi-install"
81
82do_install() {
83    DESTDIR='${WORKDIR}/minifi-install' cmake_runcmake_build --target ${OECMAKE_TARGET_INSTALL}
84    MINIFI_BIN=${bindir}
85    MINIFI_HOME=${sysconfdir}/minifi
86    MINIFI_RUN=${localstatedir}/lib/minifi
87    MINIFI_LOG=${localstatedir}/log/minifi
88
89    install -d ${D}${MINIFI_BIN}
90    install -d ${D}${MINIFI_HOME}/conf
91    install -m 755 -d ${D}${localstatedir}/lib/minifi
92    install -m 755 -d ${D}${libexecdir}/minifi-python
93    cp -a ${WORKDIR}/minifi-install/usr/bin/*   ${D}${MINIFI_BIN}/
94    cp -a ${WORKDIR}/minifi-install/usr/conf/*  ${D}${MINIFI_HOME}/conf/
95
96    sed -i 's|#appender.rolling.directory=.*|appender.rolling.directory='${MINIFI_LOG}'|g' \
97        ${D}${MINIFI_HOME}/conf/minifi-log.properties
98    sed -i 's|nifi.provenance.repository.directory.default=.*|nifi.provenance.repository.directory.default='${MINIFI_RUN}'/provenance_repository|g' \
99        ${D}${MINIFI_HOME}/conf/minifi.properties
100    sed -i 's|nifi.flowfile.repository.directory.default=.*|nifi.flowfile.repository.directory.default='${MINIFI_RUN}'/flowfile_repository|g' \
101        ${D}${MINIFI_HOME}/conf/minifi.properties
102    sed -i 's|nifi.database.content.repository.directory.default=.*|nifi.database.content.repository.directory.default='${MINIFI_RUN}'/content_repository|g' \
103        ${D}${MINIFI_HOME}/conf/minifi.properties
104    sed -i 's|nifi.flow.configuration.file=.*|nifi.flow.configuration.file='${MINIFI_HOME}'/conf/config.yml|g' \
105        ${D}${MINIFI_HOME}/conf/minifi.properties
106    sed -i 's|nifi.python.processor.dir=.*|nifi.python.processor.dir=${libexecdir}/minifi-python|g' \
107        ${D}${MINIFI_HOME}/conf/minifi.properties
108
109    sed -i 's|export MINIFI_HOME=.*|export MINIFI_HOME='${MINIFI_HOME}'|g' ${D}${MINIFI_BIN}/minifi.sh
110    sed -i 's|bin_dir=${MINIFI_HOME}/bin|bin_dir='${MINIFI_BIN}'|g' ${D}${MINIFI_BIN}/minifi.sh
111    sed -i 's|pid_file=${bin_dir}/.|pid_file='${localstatedir}/run/'|g' ${D}${MINIFI_BIN}/minifi.sh
112
113    if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
114        install -d ${D}${sysconfdir}/tmpfiles.d/
115        install -m 0644 ${WORKDIR}/systemd-volatile.conf ${D}${sysconfdir}/tmpfiles.d/minifi.conf
116        install -m 0755 -d ${D}${systemd_unitdir}/system
117        install -m 0644 ${WORKDIR}/minifi.service ${D}${systemd_unitdir}/system/
118
119        sed -i 's|@LOCALSTATEDIR@|${localstatedir}|g' ${D}${systemd_unitdir}/system/minifi.service
120        sed -i 's|@SYSCONFDIR@|${sysconfdir}|g' ${D}${systemd_unitdir}/system/minifi.service
121        sed -i 's|@BINDIR@|${bindir}|g' ${D}${systemd_unitdir}/system/minifi.service
122
123        sed -i 's|@MINIFI_LOG@|'${MINIFI_LOG}'|g' ${D}${sysconfdir}/tmpfiles.d/minifi.conf
124
125    elif ${@bb.utils.contains('DISTRO_FEATURES', 'sysvinit', 'true', 'false', d)}; then
126        install -d ${D}${sysconfdir}/default/volatiles
127        install -m 0644 ${WORKDIR}/sysvinit-volatile.conf ${D}${sysconfdir}/default/volatiles/99_minifi
128
129        sed -i 's|@MINIFI_LOG@|'${MINIFI_LOG}'|g' ${D}${sysconfdir}/default/volatiles/99_minifi
130    fi
131}
132
133pkg_postinst:${PN}() {
134    if [ -z "$D" ]; then
135        if type systemd-tmpfiles >/dev/null; then
136            systemd-tmpfiles --create
137        elif [ -e ${sysconfdir}/init.d/populate-volatile.sh ]; then
138            ${sysconfdir}/init.d/populate-volatile.sh update
139        fi
140    fi
141}
142
143CLEANBROKEN = "1"
144