1DESCRIPTION = "Different utilities from Android"
2SECTION = "console/utils"
3LICENSE = "Apache-2.0 & GPL-2.0-only & BSD-2-Clause & BSD-3-Clause"
4LIC_FILES_CHKSUM = " \
5    file://${COMMON_LICENSE_DIR}/Apache-2.0;md5=89aea4e17d99a7cacdbeed46a0096b10 \
6    file://${COMMON_LICENSE_DIR}/GPL-2.0-only;md5=801f80980d171dd6425610833a22dbe6 \
7    file://${COMMON_LICENSE_DIR}/BSD-2-Clause;md5=cb641bc04cda31daea161b1bc15da69f \
8    file://${COMMON_LICENSE_DIR}/BSD-3-Clause;md5=550794465ba0ec5312d6919e203a55f9 \
9"
10DEPENDS = "libbsd libpcre zlib libcap"
11DEPENDS:append:class-target = " openssl"
12
13ANDROID_MIRROR = "android.googlesource.com"
14
15# matches with android-5.1.1_r37
16SRCREV_core = "2314b110bdebdbfd2d94c502282f9e57c849897e"
17SRCREV_extras = "3ecbe8d841df96127d7855661293e5ab6ba6c205"
18SRCREV_libhardware = "be55eb1f4d840c82ffaf7c47460df17ff5bc4d9b"
19SRCREV_libselinux = "07e9e1339ad1ba608acfba9dce2d0f474b252feb"
20SRCREV_build = "16e987def3d7d8f7d30805eb95cef69e52a87dbc"
21
22SRCREV_FORMAT = "core_extras_libhardware_libselinux_build"
23SRC_URI = " \
24    git://${ANDROID_MIRROR}/platform/system/core;name=core;protocol=https;nobranch=1;destsuffix=git/system/core \
25    git://${ANDROID_MIRROR}/platform/system/extras;name=extras;protocol=https;nobranch=1;destsuffix=git/system/extras \
26    git://${ANDROID_MIRROR}/platform/hardware/libhardware;name=libhardware;protocol=https;nobranch=1;destsuffix=git/hardware/libhardware \
27    git://${ANDROID_MIRROR}/platform/external/libselinux;name=libselinux;protocol=https;nobranch=1;destsuffix=git/external/libselinux \
28    git://${ANDROID_MIRROR}/platform/build;name=build;protocol=https;nobranch=1;destsuffix=git/build \
29    file://core/0001-adb-remove-selinux-extensions.patch;patchdir=system/core \
30    file://core/0002-adb-Use-local-sockets-where-appropriate.patch;patchdir=system/core \
31    file://core/0003-adb-define-shell-command.patch;patchdir=system/core \
32    file://core/0004-adb-Fix-build-on-big-endian-systems.patch;patchdir=system/core \
33    file://core/0005-adb-add-base64-implementation.patch;patchdir=system/core \
34    file://core/0006-adb-Musl-fixes.patch;patchdir=system/core \
35    file://core/0007-adb-usb_linux.c-fix-build-with-glibc-2.28.patch;patchdir=system/core \
36    file://core/0008-adb-Allow-adbd-to-be-ran-as-root.patch;patchdir=system/core \
37    file://core/0009-mkbootimg-Add-dt-parameter-to-specify-DT-image.patch;patchdir=system/core \
38    file://core/0010-Use-linux-capability.h-on-linux-systems-too.patch;patchdir=system/core \
39    file://core/0011-Remove-bionic-specific-calls.patch;patchdir=system/core \
40    file://core/0012-Fix-implicit-declaration-of-stlcat-strlcopy-function.patch;patchdir=system/core \
41    file://core/adb_libssl_11.diff;patchdir=system/core \
42    file://core/0013-adb-Support-riscv64.patch;patchdir=system/core \
43    file://core/0014-add-u3-ss-descriptor-support-for-adb.patch;patchdir=system/core \
44    file://extras/0001-ext4_utils-remove-selinux-extensions.patch;patchdir=system/extras \
45    file://extras/0002-ext4_utils-add-o-argument-to-preserve-ownership.patch;patchdir=system/extras \
46    file://libselinux/0001-Remove-bionic-specific-calls.patch;patchdir=external/libselinux \
47    file://libselinux/0001-libselinux-Do-not-define-gettid-if-glibc-2.30-is-use.patch;patchdir=external/libselinux \
48    file://android-tools-adbd.service \
49    file://build/0001-Riscv-Add-risc-v-Android-config-header.patch;patchdir=build \
50    file://gitignore \
51    file://adb.mk;subdir=${BPN} \
52    file://adbd.mk;subdir=${BPN} \
53    file://ext4_utils.mk;subdir=${BPN} \
54    file://fastboot.mk;subdir=${BPN} \
55    file://mkbootimg.mk;subdir=${BPN} \
56"
57
58
59S = "${WORKDIR}/git"
60B = "${WORKDIR}/${BPN}"
61
62# http://errors.yoctoproject.org/Errors/Details/133881/
63ARM_INSTRUCTION_SET:armv4 = "arm"
64ARM_INSTRUCTION_SET:armv5 = "arm"
65
66COMPATIBLE_HOST:powerpc = "(null)"
67COMPATIBLE_HOST:powerpc64 = "(null)"
68COMPATIBLE_HOST:powerpc64le = "(null)"
69
70inherit systemd
71
72SYSTEMD_PACKAGES = "${PN}-adbd"
73SYSTEMD_SERVICE:${PN}-adbd = "android-tools-adbd.service"
74
75# Find libbsd headers during native builds
76CC:append:class-native = " -I${STAGING_INCDIR}"
77CC:append:class-nativesdk = " -I${STAGING_INCDIR}"
78
79TOOLS = "adb fastboot ext4_utils mkbootimg adbd"
80
81# Adb needs sys/capability.h, which is not available for native*
82TOOLS:class-native = "fastboot ext4_utils mkbootimg"
83TOOLS:class-nativesdk = "fastboot ext4_utils mkbootimg"
84
85do_compile() {
86    cp ${WORKDIR}/gitignore ${S}/.gitignore
87
88    # Setting both variables below causing our makefiles to not work with
89    # implicit make rules
90    unset CFLAGS
91    unset CPPFLAGS
92
93    export SRCDIR=${S}
94
95    case "${HOST_ARCH}" in
96      arm)
97        export android_arch=linux-arm
98      ;;
99      aarch64)
100        export android_arch=linux-arm64
101      ;;
102      riscv64)
103        export android_arch=linux-riscv64
104      ;;
105      mips|mipsel)
106        export android_arch=linux-mips
107      ;;
108      mips64|mips64el)
109        export android_arch=linux-mips64
110      ;;
111      powerpc|powerpc64)
112        export android_arch=linux-ppc
113      ;;
114      i586|i686|x86_64)
115        export android_arch=linux-x86
116      ;;
117    esac
118
119    for tool in ${TOOLS}; do
120      mkdir -p ${B}/${tool}
121      oe_runmake -f ${B}/${tool}.mk -C ${B}/${tool}
122    done
123}
124
125do_install() {
126    if echo ${TOOLS} | grep -q "ext4_utils" ; then
127        install -D -p -m0755 ${S}/system/core/libsparse/simg_dump.py ${D}${bindir}/simg_dump
128        install -D -p -m0755 ${S}/system/extras/ext4_utils/mkuserimg.sh ${D}${bindir}/mkuserimg
129
130        install -m0755 ${B}/ext4_utils/ext2simg ${D}${bindir}
131        install -m0755 ${B}/ext4_utils/ext4fixup ${D}${bindir}
132        install -m0755 ${B}/ext4_utils/img2simg ${D}${bindir}
133        install -m0755 ${B}/ext4_utils/make_ext4fs ${D}${bindir}
134        install -m0755 ${B}/ext4_utils/simg2img ${D}${bindir}
135        install -m0755 ${B}/ext4_utils/simg2simg ${D}${bindir}
136    fi
137
138    if echo ${TOOLS} | grep -q "adb\>" ; then
139        install -d ${D}${bindir}
140        install -m0755 ${B}/adb/adb ${D}${bindir}
141    fi
142
143    if echo ${TOOLS} | grep -q "adbd" ; then
144        install -d ${D}${bindir}
145        install -m0755 ${B}/adbd/adbd ${D}${bindir}
146    fi
147
148    # Outside the if statement to avoid errors during do_package
149    install -D -p -m0644 ${WORKDIR}/android-tools-adbd.service \
150      ${D}${systemd_unitdir}/system/android-tools-adbd.service
151
152    if echo ${TOOLS} | grep -q "fastboot" ; then
153        install -d ${D}${bindir}
154        install -m0755 ${B}/fastboot/fastboot ${D}${bindir}
155    fi
156
157    if echo ${TOOLS} | grep -q "mkbootimg" ; then
158        install -d ${D}${bindir}
159        install -m0755 ${B}/mkbootimg/mkbootimg ${D}${bindir}
160    fi
161}
162
163PACKAGES =+ "${PN}-fstools ${PN}-adbd"
164
165RDEPENDS:${PN}-adbd = "${PN}-conf"
166RDEPENDS:${PN}-fstools = "bash"
167
168FILES:${PN}-adbd = "\
169    ${bindir}/adbd \
170    ${systemd_unitdir}/system/android-tools-adbd.service \
171"
172
173FILES:${PN}-fstools = "\
174    ${bindir}/ext2simg \
175    ${bindir}/ext4fixup \
176    ${bindir}/img2simg \
177    ${bindir}/make_ext4fs \
178    ${bindir}/simg2img \
179    ${bindir}/simg2simg \
180    ${bindir}/simg_dump \
181    ${bindir}/mkuserimg \
182"
183
184BBCLASSEXTEND = "native"
185
186android_tools_enable_devmode() {
187    touch ${IMAGE_ROOTFS}/var/usb-debugging-enabled
188}
189
190ROOTFS_POSTPROCESS_COMMAND_${PN}-adbd += "${@bb.utils.contains("USB_DEBUGGING_ENABLED", "1", "android_tools_enable_devmode;", "", d)}"
191