xref: /OK3568_Linux_fs/yocto/meta-openembedded/meta-oe/recipes-connectivity/thrift/thrift_0.16.0.bb (revision 4882a59341e53eb6f0b4789bf948001014eff981) 
1SUMMARY = "Apache Thrift"
2DESCRIPTION =  "A software framework, for scalable cross-language services development"
3HOMEPAGE = "https://thrift.apache.org/"
4
5LICENSE = "Apache-2.0"
6LIC_FILES_CHKSUM = "file://LICENSE;md5=c40a383cb3f747e0c7abbf1482f194f0 \
7                    file://NOTICE;md5=2659b43daca219f99a2f2626ea128f73"
8
9DEPENDS = "thrift-native boost flex-native bison-native openssl zlib"
10
11SRC_URI = "https://www-eu.apache.org/dist/thrift//${PV}/${BPN}-${PV}.tar.gz \
12           file://0001-DefineInstallationPaths.cmake-Define-libdir-in-terms.patch \
13          "
14SRC_URI[sha256sum] = "f460b5c1ca30d8918ff95ea3eb6291b3951cf518553566088f3f2be8981f6209"
15
16BBCLASSEXTEND = "native nativesdk"
17
18CVE_PRODUCT = "apache:thrift"
19
20inherit pkgconfig cmake python3native
21
22export STAGING_INCDIR
23export STAGING_LIBDIR
24export BUILD_SYS
25export HOST_SYS
26
27EXTRA_OECMAKE = " \
28    -DBUILD_LIBRARIES=ON \
29    -DBUILD_SHARED_LIBS=ON \
30    -DBUILD_COMPILER=ON \
31    -DBUILD_TESTING=OFF \
32    -DBUILD_TUTORIALS=OFF \
33    -DWITH_AS3=OFF \
34    -DWITH_CPP=ON \
35    -DWITH_JAVA=OFF \
36    -DWITH_OPENSSL=ON \
37    -DWITH_QT5=OFF \
38    -DWITH_ZLIB=ON \
39"
40
41PACKAGECONFIG ??= "glib libevent"
42PACKAGECONFIG[glib] = "-DWITH_C_GLIB=ON,-DWITH_C_GLIB=OFF,glib-2.0"
43PACKAGECONFIG[libevent] = "-DWITH_LIBEVENT=ON,-DWITH_LIBEVENT=OFF,libevent"
44PACKAGECONFIG[javascript] = "-DWITH_JAVASCRIPT=ON,-DWITH_JAVASCRIPT=OFF,nodejs"
45PACKAGECONFIG[nodejs] = "-DWITH_NODEJS=ON,-DWITH_NODEJS=OFF,nodejs"
46PACKAGECONFIG[python] = "-DWITH_PYTHON=ON,-DWITH_PYTHON=OFF,python"
47
48do_install:append () {
49    ln -sf thrift ${D}/${bindir}/thrift-compiler
50}
51
52LEAD_SONAME = "libthrift.so.${PV}"
53
54# thrift packages
55PACKAGE_BEFORE_PN = "${PN}-compiler lib${BPN} lib${BPN}z lib${BPN}nb lib${BPN}-c-glib"
56FILES:lib${BPN} = "${libdir}/libthrift.so.*"
57FILES:lib${BPN}z = "${libdir}/libthriftz.so.*"
58FILES:lib${BPN}nb = "${libdir}/libthriftnb.so.*"
59FILES:lib${BPN}-c-glib = "${libdir}/libthrift_c_glib.so.*"
60FILES:${PN}-compiler = "${bindir}/*"
61
62# The thrift packages just pulls in some default dependencies but is otherwise empty
63RRECOMMENDS:${PN} = "${PN}-compiler lib${BPN}"
64ALLOW_EMPTY:${PN} = "1"
65RRECOMMENDS:${PN}:class-native = ""
66RRECOMMENDS:${PN}:class-nativesdk = ""
67