xref: /OK3568_Linux_fs/yocto/meta-openembedded/meta-oe/recipes-bsp/lm_sensors/lmsensors_3.6.0.bb (revision 4882a59341e53eb6f0b4789bf948001014eff981) 
1SUMMARY = "Hardware health monitoring applications"
2HOMEPAGE = "https://hwmon.wiki.kernel.org/"
3LICENSE = "GPL-2.0-or-later & LGPL-2.1-or-later"
4LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe \
5                    file://COPYING.LGPL;md5=4fbd65380cdd255951079008b364516c"
6
7DEPENDS = " \
8    bison-native \
9    flex-native \
10    virtual/libiconv \
11"
12
13SRC_URI = "git://github.com/lm-sensors/lm-sensors.git;protocol=https;branch=master \
14           file://fancontrol.init \
15           file://sensord.init \
16           file://0001-Change-PIDFile-path-from-var-run-to-run.patch \
17"
18SRCREV = "1667b850a1ce38151dae17156276f981be6fb557"
19
20inherit update-rc.d systemd
21
22RDEPENDS:${PN}-dev = ""
23
24PACKAGECONFIG ??= "sensord"
25PACKAGECONFIG[sensord] = "sensord,,rrdtool"
26
27INITSCRIPT_PACKAGES = "\
28    ${PN}-fancontrol \
29    ${@bb.utils.contains('PACKAGECONFIG', 'sensord', '${PN}-sensord', '', d)} \
30    "
31INITSCRIPT_NAME:${PN}-fancontrol = "fancontrol"
32INITSCRIPT_NAME:${PN}-sensord = "sensord"
33INITSCRIPT_PARAMS:${PN}-fancontrol = "defaults 66"
34INITSCRIPT_PARAMS:${PN}-sensord = "defaults 67"
35
36SYSTEMD_PACKAGES = "\
37    ${PN} \
38    ${PN}-fancontrol \
39    ${@bb.utils.contains('PACKAGECONFIG', 'sensord', '${PN}-sensord', '', d)} \
40    "
41SYSTEMD_SERVICE:${PN} = "lm_sensors.service"
42SYSTEMD_SERVICE:${PN}-fancontrol = "fancontrol.service"
43SYSTEMD_SERVICE:${PN}-sensord = "sensord.service"
44SYSTEMD_AUTO_ENABLE = "disable"
45
46S = "${WORKDIR}/git"
47
48EXTRA_OEMAKE = 'EXLDFLAGS="${LDFLAGS}" \
49        MACHINE=${TARGET_ARCH} PREFIX=${prefix} MANDIR=${mandir} \
50        LIBDIR=${libdir} \
51        CC="${CC}" AR="${AR}"'
52
53do_compile() {
54    sed -i -e 's:^# \(PROG_EXTRA\):\1:' ${S}/Makefile
55    # Respect LDFLAGS
56    sed -i -e 's/\$(LIBDIR)$/\$(LIBDIR) \$(LDFLAGS)/g' ${S}/Makefile
57    sed -i -e 's/\$(LIBSHSONAME) -o/$(LIBSHSONAME) \$(LDFLAGS) -o/g' \
58                ${S}/lib/Module.mk
59    oe_runmake user PROG_EXTRA="sensors ${PACKAGECONFIG_CONFARGS}"
60}
61
62do_install() {
63    oe_runmake user_install DESTDIR=${D}
64    if ${@bb.utils.contains('PACKAGECONFIG', 'sensord', 'true', 'false', d)}; then
65        install -m 0755 ${S}/prog/sensord/sensord ${D}${sbindir}
66        install -m 0644 ${S}/prog/sensord/sensord.8 ${D}${mandir}/man8
67    fi
68
69    # Install directory
70    install -d ${D}${INIT_D_DIR}
71
72    # Install fancontrol init script
73    install -m 0755 ${WORKDIR}/fancontrol.init ${D}${INIT_D_DIR}/fancontrol
74
75    if ${@bb.utils.contains('PACKAGECONFIG', 'sensord', 'true', 'false', d)}; then
76        # Install sensord init script
77        install -m 0755 ${WORKDIR}/sensord.init ${D}${INIT_D_DIR}/sensord
78    fi
79
80    # Insall sensord service script
81    install -d ${D}${systemd_unitdir}/system
82    install -m 0644 ${S}/prog/init/*.service ${D}${systemd_unitdir}/system
83    if ! ${@bb.utils.contains('PACKAGECONFIG', 'sensord', 'true', 'false', d)}; then
84        rm ${D}${systemd_system_unitdir}/sensord.service
85    fi
86}
87
88RPROVIDES:${PN}-dbg += "${PN}-libsensors-dbg ${PN}-sensors-dbg ${PN}-sensord-dbg ${PN}-isatools-dbg"
89
90ALLOW_EMPTY:${PN} = "1"
91RDEPENDS:${PN} += " \
92    ${PN}-libsensors \
93    ${PN}-sensors \
94    ${@bb.utils.contains('PACKAGECONFIG', 'sensord', '${PN}-sensord', '', d)} \
95    ${PN}-fancontrol \
96    ${PN}-sensorsdetect \
97    ${PN}-sensorsconfconvert \
98    ${PN}-pwmconfig \
99    ${@bb.utils.contains('MACHINE_FEATURES', 'x86', '${PN}-isatools', '', d)} \
100"
101
102# libsensors packages
103PACKAGES =+ "${PN}-libsensors ${PN}-libsensors-dev ${PN}-libsensors-staticdev ${PN}-libsensors-doc"
104
105# sensors command packages
106PACKAGES =+ "${PN}-sensors ${PN}-sensors-doc"
107
108# sensord logging daemon
109PACKAGES =+ "${@bb.utils.contains('PACKAGECONFIG', 'sensord', '${PN}-sensord ${PN}-sensord-doc', '', d)}"
110
111# fancontrol script
112PACKAGES =+ "${PN}-fancontrol ${PN}-fancontrol-doc"
113
114# sensors-detect script
115PACKAGES =+ "${PN}-sensorsdetect ${PN}-sensorsdetect-doc"
116
117# sensors-conf-convert script
118PACKAGES =+ "${PN}-sensorsconfconvert ${PN}-sensorsconfconvert-doc"
119
120# pwmconfig script
121PACKAGES =+ "${PN}-pwmconfig ${PN}-pwmconfig-doc"
122
123# isadump and isaset helper program
124PACKAGES =+ "${PN}-isatools ${PN}-isatools-doc"
125
126
127# libsensors files
128FILES:${PN}-libsensors = "${libdir}/libsensors.so.* ${sysconfdir}/sensors3.conf ${sysconfdir}/sensors.d"
129FILES:${PN}-libsensors-dev = "${libdir}/libsensors.so ${includedir}"
130FILES:${PN}-libsensors-staticdev = "${libdir}/libsensors.a"
131FILES:${PN}-libsensors-doc = "${mandir}/man3"
132RRECOMMENDS:${PN}-libsensors = "lmsensors-config-libsensors"
133
134# sensors command files
135FILES:${PN}-sensors = "${bindir}/sensors"
136FILES:${PN}-sensors-doc = "${mandir}/man1 ${mandir}/man5"
137RDEPENDS:${PN}-sensors = "${PN}-libsensors"
138
139# sensord logging daemon
140FILES:${PN}-sensord = "${sbindir}/sensord ${INIT_D_DIR}/sensord ${systemd_system_unitdir}/sensord.service"
141FILES:${PN}-sensord-doc = "${mandir}/man8/sensord.8"
142RDEPENDS:${PN}-sensord = "${PN}-sensors rrdtool"
143RRECOMMENDS:${PN}-sensord = "lmsensors-config-sensord"
144
145# fancontrol script files
146FILES:${PN}-fancontrol = "${sbindir}/fancontrol ${INIT_D_DIR}/fancontrol"
147FILES:${PN}-fancontrol-doc = "${mandir}/man8/fancontrol.8"
148RDEPENDS:${PN}-fancontrol = "bash"
149RRECOMMENDS:${PN}-fancontrol = "lmsensors-config-fancontrol"
150
151# sensors-detect script files
152FILES:${PN}-sensorsdetect = "${sbindir}/sensors-detect"
153FILES:${PN}-sensorsdetect-doc = "${mandir}/man8/sensors-detect.8"
154RDEPENDS:${PN}-sensorsdetect = "${PN}-sensors perl perl-modules"
155
156# sensors-conf-convert script files
157FILES:${PN}-sensorsconfconvert = "${bindir}/sensors-conf-convert"
158FILES:${PN}-sensorsconfconvert-doc = "${mandir}/man8/sensors-conf-convert.8"
159RDEPENDS:${PN}-sensorsconfconvert = "${PN}-sensors perl perl-modules"
160
161# pwmconfig script files
162FILES:${PN}-pwmconfig = "${sbindir}/pwmconfig"
163FILES:${PN}-pwmconfig-doc = "${mandir}/man8/pwmconfig.8"
164RDEPENDS:${PN}-pwmconfig = "${PN}-fancontrol bash"
165
166# isadump and isaset helper program files
167FILES:${PN}-isatools = "${sbindir}/isa*"
168FILES:${PN}-isatools-doc = "${mandir}/man8/isa*"
169