1SUMMARY = "Unbound is a validating, recursive, and caching DNS resolver"
2DESCRIPTION = "Unbound's design is a set of modular components which incorporate \
3	features including enhanced security (DNSSEC) validation, Internet Protocol \
4	Version 6 (IPv6), and a client resolver library API as an integral part of the \
5	architecture"
6
7HOMEPAGE = "https://www.unbound.net/"
8SECTION = "net"
9LICENSE = "BSD-3-Clause"
10LIC_FILES_CHKSUM = "file://LICENSE;md5=5308494bc0590c0cb036afd781d78f06"
11
12SRC_URI = "git://github.com/NLnetLabs/unbound.git;protocol=http;branch=master;protocol=https \
13	file://0001-contrib-add-yocto-compatible-init-script.patch \
14"
15SRCREV = "c29b0e0a96c4d281aef40d69a11c564d6ed1a2c6"
16
17inherit autotools pkgconfig systemd update-rc.d
18
19DEPENDS = "openssl libevent libtool-native bison-native expat"
20RDEPENDS:${PN} = "bash openssl-bin daemonize"
21
22S = "${WORKDIR}/git"
23
24EXTRA_OECONF = "--with-libexpat=${STAGING_EXECPREFIXDIR} \
25		--with-ssl=${STAGING_EXECPREFIXDIR}"
26
27
28PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'largefile systemd', d)}"
29PACKAGECONFIG[dnscrypt] = "--enable-dnscrypt, --disable-dnscrypt, libsodium"
30PACKAGECONFIG[largefile] = "--enable-largefile,--disable-largefile,,"
31PACKAGECONFIG[systemd] = "--enable-systemd,--disable-systemd,systemd"
32
33do_install:append() {
34	install -d ${D}${systemd_unitdir}/system
35	install -m 0644 ${B}/contrib/unbound.service ${D}${systemd_unitdir}/system
36
37	install -d ${D}${sysconfdir}/init.d
38	install -m 0755 ${S}/contrib/unbound.init ${D}${sysconfdir}/init.d/unbound
39}
40
41SYSTEMD_SERVICE:${PN} = "${BPN}.service"
42
43INITSCRIPT_NAME = "unbound"
44INITSCRIPT_PARAMS = "defaults"
45