1SUMMARY = "A sophisticated network protocol analyzer"
2HOMEPAGE = "http://www.tcpdump.org/"
3SECTION = "net"
4LICENSE = "BSD-3-Clause"
5LIC_FILES_CHKSUM = "file://LICENSE;md5=5eb289217c160e2920d2e35bddc36453"
6
7DEPENDS = "libpcap"
8
9RDEPENDS:${PN}-ptest += " make perl \
10	perl-module-file-basename \
11	perl-module-file-spec \
12	perl-module-file-spec-unix \
13	perl-module-file-path \
14	perl-module-file-glob \
15	perl-module-data-dumper \
16	perl-module-bytes \
17	perl-module-posix \
18	perl-module-carp \
19	perl-module-cwd \
20    perl-module-constant \
21"
22
23SRC_URI = " \
24    http://www.tcpdump.org/release/${BP}.tar.gz \
25    file://add-ptest.patch \
26    file://run-ptest \
27"
28
29SRC_URI[md5sum] = "929a255c71a9933608bd7c31927760f7"
30SRC_URI[sha256sum] = "79b36985fb2703146618d87c4acde3e068b91c553fb93f021a337f175fd10ebe"
31
32UPSTREAM_CHECK_REGEX = "tcpdump-(?P<pver>\d+(\.\d+)+)\.tar"
33
34inherit autotools-brokensep pkgconfig ptest
35
36PACKAGECONFIG ?= "openssl"
37
38PACKAGECONFIG[libcap-ng] = "--with-cap-ng,--without-cap-ng,libcap-ng"
39PACKAGECONFIG[openssl] = "--with-crypto,--without-crypto,openssl"
40PACKAGECONFIG[smi] = "--with-smi,--without-smi,libsmi"
41# Note: CVE-2018-10103 (SMB - partially fixed, but SMB printing disabled)
42PACKAGECONFIG[smb] = "--enable-smb,--disable-smb"
43
44EXTRA_AUTORECONF += "--exclude=aclocal"
45
46do_install:append() {
47    # make install installs an unneeded extra copy of the tcpdump binary
48    rm ${D}${bindir}/tcpdump.${PV}
49}
50
51do_compile_ptest() {
52    oe_runmake buildtest-TESTS
53}
54