1SUMMARY = "Distributed block device driver for Linux"
2DESCRIPTION = "DRBD mirrors a block device over the network to another machine.\
3DRBD mirrors a block device over the network to another machine.\
4Think of it as networked raid 1. It is a building block for\
5setting up high availability (HA) clusters."
6HOMEPAGE = "http://www.drbd.org/"
7SECTION = "admin"
8LICENSE = "GPL-2.0-or-later"
9LIC_FILES_CHKSUM = "file://COPYING;md5=5574c6965ae5f583e55880e397fbb018"
10
11SRC_URI = "git://github.com/LINBIT/drbd-utils;name=drbd-utils;branch=${PV};protocol=https \
12           git://github.com/LINBIT/drbd-headers;name=drbd-headers;destsuffix=git/drbd-headers;branch=master;protocol=https \
13           file://0001-drbdmon-add-LDFLAGS-when-linking.patch \
14           ${@bb.utils.contains('DISTRO_FEATURES','usrmerge','file://0001-drbd-utils-support-usrmerge.patch','',d)} \
15           "
16
17SRCREV_drbd-utils = "087ee6b4961ca154d76e4211223b03149373bed8"
18SRCREV_drbd-headers = "f1529aa84e9d2f66c96ad283a1bbb708aabf03f7"
19
20SRCREV_FORMAT = "drbd-utils_drbd-headers"
21
22S = "${WORKDIR}/git"
23
24UPSTREAM_CHECK_URI = "https://github.com/LINBIT/drbd-utils/releases"
25
26SYSTEMD_SERVICE:${PN} = "drbd.service"
27SYSTEMD_AUTO_ENABLE = "disable"
28
29DEPENDS = "flex-native"
30
31inherit autotools-brokensep systemd
32
33EXTRA_OECONF = " \
34                --with-initdir=/etc/init.d    \
35                --without-pacemaker           \
36                --without-rgmanager           \
37                --without-bashcompletion      \
38                --with-distro debian          \
39                --with-initscripttype=both    \
40                --with-systemdunitdir=${systemd_unitdir}/system \
41                --without-manual \
42               "
43
44# If we have inherited reproducible_build, we want to use it.
45export WANT_DRBD_REPRODUCIBLE_BUILD = "yes"
46
47do_install:append() {
48    # don't install empty /var/lock and /var/run to avoid conflict with base-files
49    rm -rf ${D}${localstatedir}/lock
50    rm -rf ${D}${localstatedir}/run
51
52    sed -i -e 's#@nonarch_libdir@#${nonarch_libdir}#g' ${D}${systemd_unitdir}/system/drbd-demote-or-escalate@.service
53    sed -i -e 's#@nonarch_libdir@#${nonarch_libdir}#g' ${D}${systemd_unitdir}/system/drbd-promote@.service
54    sed -i -e 's#@nonarch_libdir@#${nonarch_libdir}#g' ${D}${systemd_unitdir}/system/drbd-wait-promotable@.service
55    sed -i -e 's#@nonarch_libdir@#${nonarch_libdir}#g' ${D}${systemd_unitdir}/system/drbd.service
56    sed -i -e 's#@nonarch_libdir@#${nonarch_libdir}#g' ${D}${systemd_unitdir}/system/drbd@.service
57    sed -i -e 's#@nonarch_libdir@#${nonarch_libdir}#g' ${D}${systemd_unitdir}/system/ocf.ra@.service
58}
59
60RDEPENDS:${PN} += "bash perl-module-getopt-long perl-module-exporter perl-module-constant perl-module-overloading perl-module-exporter-heavy"
61
62# The drbd items are explicitly put under /lib when installed.
63#
64FILES:${PN} += "/run"
65FILES:${PN} += "${nonarch_base_libdir}/drbd \
66                ${nonarch_libdir}/drbd \
67                ${nonarch_libdir}/tmpfiles.d \
68                ${nonarch_libdir}/drbdscripts/* \
69                ${systemd_unitdir}/system/* \
70"
71FILES:${PN}-dbg += "${nonarch_base_libdir}/drbd/.debug"
72
73CLEANBROKEN = "1"
74