1SUMMARY = "A user-mode PPPoE client and server suite for Linux"
2HOMEPAGE = "http://www.roaringpenguin.com/products/pppoe"
3SECTION = "net"
4LICENSE = "GPL-2.0-only"
5LIC_FILES_CHKSUM = "file://doc/LICENSE;md5=a194eaefae2be54ee3221339b10d0581"
6
7PR = "r10"
8
9SRC_URI = "https://dianne.skoll.ca/projects/rp-pppoe/download/rp-pppoe-${PV}.tar.gz \
10           file://top-autoconf.patch \
11           file://configure_in_cross.patch \
12           file://update-config.patch \
13           file://dont-swallow-errors.patch \
14           file://discard-use-of-dnl-in-Makefile.am.patch \
15           file://configure.patch \
16           file://pppoe-server.default \
17           file://pppoe-server.init \
18           file://configure.in-Error-fix.patch \
19           file://pppoe-server.service \
20           file://0001-ppoe-Dont-include-linux-if_ether.h.patch \
21           file://0002-Enable-support-for-the-kernel-module.patch \
22           "
23
24SRC_URI[md5sum] = "ec9dccd9a367a1f71f2dc81069796dd8"
25SRC_URI[sha256sum] = "8cd6bc71ba46bd5f6eb4daf60220ccdcd991a8525111dee466501b1b9717e676"
26
27inherit autotools-brokensep update-rc.d systemd
28
29CACHED_CONFIGUREVARS += "${@oe.utils.conditional('SITEINFO_ENDIANNESS', 'be', 'rpppoe_cv_pack_bitfields=normal', 'rpppoe_cv_pack_bitfields=rev', d)}"
30
31do_install:append() {
32    install -d ${D}${systemd_unitdir}/system
33    install -m 0644 ${WORKDIR}/pppoe-server.service ${D}${systemd_unitdir}/system
34    sed -i -e 's#@SYSCONFDIR@#${sysconfdir}#g' ${D}${systemd_unitdir}/system/pppoe-server.service
35    sed -i -e 's#@SBINDIR@#${sbindir}#g' ${D}${systemd_unitdir}/system/pppoe-server.service
36    install -d ${D}${datadir}/doc/${PN}
37    if [ -f ${D}${datadir}/doc/README ]; then
38        mv ${D}${datadir}/doc/README ${D}${datadir}/doc/${PN}/
39    fi
40}
41
42do_install() {
43    # Install init script and default settings
44    install -m 0755 -d ${D}${sysconfdir}/default ${D}${sysconfdir}/init.d
45    install -m 0644 ${WORKDIR}/pppoe-server.default ${D}${sysconfdir}/default/pppoe-server
46    install -m 0755 ${WORKDIR}/pppoe-server.init ${D}${sysconfdir}/init.d/pppoe-server
47    # Install
48    oe_runmake -C ${S} DESTDIR=${D} docdir=${docdir} install
49    chmod 4755 ${D}${sbindir}/pppoe
50}
51
52SYSTEMD_PACKAGES = "${PN}-server"
53SYSTEMD_SERVICE:${PN}-server = "pppoe-server.service"
54SYSTEMD_AUTO_ENABLE = "disable"
55# Insert server package before main package
56PACKAGES = "${PN}-dbg ${PN}-server ${PN}-relay ${PN}-sniff ${PN} ${PN}-doc"
57
58FILES:${PN}-server = "${sysconfdir}/default/pppoe-server \
59                      ${sysconfdir}/init.d/pppoe-server \
60                      ${sbindir}/pppoe-server \
61                      ${sysconfdir}/ppp/pppoe-server-options"
62FILES:${PN}-relay = "${sbindir}/pppoe-relay"
63FILES:${PN}-sniff = "${sbindir}/pppoe-sniff"
64
65CONFFILES:${PN} = "${sysconfdir}/ppp/pppoe.conf \
66                   ${sysconfdir}/ppp/firewall-standalone \
67                   ${sysconfdir}/ppp/firewall-masq"
68CONFFILES:${PN}-server = "${sysconfdir}/ppp/pppoe-server-options \
69                          ${sysconfdir}/default/pppoe-server"
70
71INITSCRIPT_PACKAGES            = "${PN}-server"
72INITSCRIPT_NAME:${PN}-server   = "pppoe-server"
73INITSCRIPT_PARAMS:${PN}-server = "defaults 92 8"
74
75RDEPENDS:${PN} = "ppp"
76RDEPENDS:${PN}-server = "${PN}"
77RRECOMMENDS:${PN} = "ppp-oe"
78
79