1SUMMARY = "An L2TP client/server, designed for VPN use."
2DESCRIPTION = "OpenL2TP is an open source L2TP client / server, written \
3specifically for Linux. It has been designed for use as an enterprise \
4L2TP VPN server or in commercial, Linux-based, embedded networking \
5products and is able to support hundreds of sessions, each with \
6different configuration. It is used by several ISPs to provide \
7L2TP services and by corporations to implement L2TP VPNs."
8HOMEPAGE = "http://www.openl2tp.org/"
9SECTION = "net"
10
11# cli and usl use license LGPL-2.1
12LICENSE = "GPL-2.0-only & LGPL-2.1-only"
13LIC_FILES_CHKSUM = "file://COPYING;md5=e9d9259cbbf00945adc25a470c1d3585 \
14                    file://LICENSE;md5=f8970abd5ea9be701a0deedf5afd77a5 \
15                    file://cli/LICENSE;md5=9c1387a3c5213aa40671438af3e00793 \
16                    file://usl/LICENSE;md5=9c1387a3c5213aa40671438af3e00793 \
17                    "
18
19DEPENDS = "popt flex readline rpcsvc-proto-native bison-native"
20
21SRC_URI = "${SOURCEFORGE_MIRROR}/${BPN}/${PV}/${BP}.tar.gz \
22           file://Makefile-modify-CFLAGS-to-aviod-build-error.patch \
23           file://openl2tp-simplify-gcc-warning-hack.patch \
24           file://Makefile-obey-LDFLAGS.patch \
25           file://0001-test-pppd_dummy.c-Fix-return-value.patch \
26           file://0001-Use-1-instead-of-WAIT_ANY.patch \
27           file://0002-cli-include-fcntl.h-for-O_CREAT-define.patch \
28           file://0003-cli-Define-_GNU_SOURCE-for-getting-sighandler_t.patch \
29           file://0001-l2tp_api-Included-needed-headers.patch \
30           file://openl2tpd-initscript-fix.patch \
31           file://openl2tpd-initscript-fix-sysconfig.patch \
32           file://openl2tpd-initscript-fix-warning.patch \
33           file://openl2tpd.service \
34           file://openl2tpd-enable-tests.patch \
35           file://run-ptest \
36           file://fix_linux_4.15_compile.patch \
37           file://0002-user-ipv6-structures.patch \
38           "
39SRC_URI[md5sum] = "e3d08dedfb9e6a9a1e24f6766f6dadd0"
40SRC_URI[sha256sum] = "1c97704d4b963a87fbc0e741668d4530933991515ae9ab0dffd11b5444f4860f"
41
42inherit autotools-brokensep pkgconfig systemd ptest
43
44SYSTEMD_SERVICE:${PN} = "openl2tpd.service"
45SYSTEMD_AUTO_ENABLE = "disable"
46
47DEPENDS += "libtirpc"
48CPPFLAGS += "-I${STAGING_INCDIR}/tirpc"
49CFLAGS += "-I${STAGING_INCDIR}/tirpc"
50LDFLAGS += "-ltirpc"
51
52PARALLEL_MAKE = ""
53EXTRA_OEMAKE = 'CFLAGS="${CFLAGS} -Wno-unused-but-set-variable" CPPFLAGS="${CPPFLAGS}" OPT_CFLAGS="${CFLAGS}"'
54
55do_compile:prepend() {
56    sed -i -e "s:SYS_LIBDIR=.*:SYS_LIBDIR=${libdir}:g" \
57        -e 's:$(CROSS_COMPILE)as:${AS}:g' \
58        -e 's:$(CROSS_COMPILE)ld:${LD}:g' \
59        -e 's:$(CROSS_COMPILE)gcc:${CC}:g' \
60        -e 's:$(CROSS_COMPILE)ar:${AR}:g' \
61        -e 's:$(CROSS_COMPILE)nm:${NM}:g' \
62        -e 's:$(CROSS_COMPILE)strip:${STRIP}:g' \
63        -e 's:$(CROSS_COMPILE)install:install:g' \
64        -e 's:CPPFLAGS-y:CPPFLAGS:g' \
65        ${S}/Makefile
66}
67
68do_install:append () {
69    install -d ${D}${sysconfdir}/init.d
70    install -d ${D}${sysconfdir}/default
71    install -m 0755 ${S}/etc/rc.d/init.d/openl2tpd ${D}${sysconfdir}/init.d/openl2tpd
72    install -m 0755 ${S}/etc/sysconfig/openl2tpd ${D}${sysconfdir}/default/openl2tpd
73
74    if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
75        install -D -m 0644 ${WORKDIR}/openl2tpd.service ${D}${systemd_system_unitdir}/openl2tpd.service
76        sed -i -e 's,@STATEDIR@,${localstatedir},g' \
77               -e 's,@SYSCONFDIR@,${sysconfdir},g' \
78               -e 's,@SBINDIR@,${sbindir},g' \
79               -e 's,@BINDIR@,${bindir},g' \
80               -e 's,@BASE_SBINDIR@,${base_sbindir},g' \
81               -e 's,@BASE_BINDIR@,${base_bindir},g' \
82               ${D}${systemd_system_unitdir}/openl2tpd.service
83    fi
84}
85
86do_install_ptest () {
87    for i in all.tcl configfile.test peer_profile.test ppp_profile.test \
88    session_profile.test session.test system.test test_procs.tcl \
89    thirdparty_lns.test tunnel_profile.test tunnel.test; do
90        install -m 0755 ${S}/test/$i ${D}${PTEST_PATH}
91    done
92}
93
94RDEPENDS:${PN} = "ppp ppp-l2tp bash"
95