1DESCRIPTION = "netkit-ft includes the ftp client."
2SECTION = "net"
3HOMEPAGE="ftp://ftp.uk.linux.org/pub/linux/Networking/netkit"
4LICENSE = "BSD-4-Clause"
5
6LIC_FILES_CHKSUM = "file://ftp/ftp.c;beginline=2;endline=3;md5=2d40a75a50d83b8f6317b3f53db72bfa"
7
8SRC_URI = "${DEBIAN_MIRROR}/main/n/netkit-ftp/netkit-ftp_${PV}.orig.tar.gz;name=archive \
9           ${DEBIAN_MIRROR}/main/n/netkit-ftp/netkit-ftp_${PV}-31.debian.tar.xz;name=patch31 \
10           file://Add_ARG_MAX_define.patch \
11           file://0001-ftp-include-sys-types.h-for-u_long.patch \
12           "
13
14SRC_URI[archive.md5sum] = "94441610c9b86ef45c4c6ec609444060"
15SRC_URI[archive.sha256sum] = "61c913299b81a4671ff089aac821329f7db9bc111aa812993dd585798b700349"
16SRC_URI[patch31.md5sum] = "93d71e28ce70df69e080c7f90da63cac"
17SRC_URI[patch31.sha256sum] = "4edd46a32d70daa7ba00f0ebf0118dc5d17dff23d6e46aa21a2722be2e22d1c1"
18
19inherit autotools-brokensep update-alternatives
20
21CLEANBROKEN = "1"
22
23do_configure () {
24    ./configure --prefix=${prefix}
25    echo "LDFLAGS=${LDFLAGS}" >> MCONFIG
26}
27
28BINMODE = "0755"
29MANMODE = "0644"
30
31do_install () {
32    install -d ${D}${bindir}
33    install -d ${D}${mandir}/man1
34    install -d ${D}${mandir}/man5
35
36    install -m${BINMODE} ${S}/ftp/ftp ${D}${bindir}
37    ln -sf ftp ${D}${bindir}/pftp
38    install -m${MANMODE} ${S}/ftp/ftp.1 ${D}${mandir}/man1
39    ln -sf ftp.1 ${D}${mandir}/man1/pftp.1
40    install -m${MANMODE} ${S}/ftp/netrc.5 ${D}${mandir}/man5
41}
42
43PACKAGES = "${PN} ${PN}-doc ${BPN}-dbg"
44FILES:${PN} = "${bindir}/*"
45FILES:${PN}-doc = "${mandir}"
46FILES:${PN}-dbg = "${prefix}/src/debug \
47            ${bindir}/.debug"
48
49RDEPENDS:${PN} = "readline"
50
51ALTERNATIVE_PRIORITY = "100"
52ALTERNATIVE:${PN} = "ftp"
53ALTERNATIVE_LINK_NAME[ftp] = "${bindir}/ftp"
54