1SUMMARY = "Network scanning and manipulation tool"
2DESCRIPTION = "Scapy is a powerful interactive packet manipulation program. \
3It is able to forge or decode packets of a wide number of protocols, send \
4them on the wire, capture them, match requests and replies, and much more. \
5It can easily handle most classical tasks like scanning, tracerouting, probing, \
6unit tests, attacks or network discovery (it can replace hping, 85% of nmap, \
7arpspoof, arp-sk, arping, tcpdump, tethereal, p0f, etc.). It also performs very \
8well at a lot of other specific tasks that most other tools can't handle, like \
9sending invalid frames, injecting your own 802.11 frames, combining technics \
10(VLAN hopping+ARP cache poisoning, VOIP decoding on WEP encrypted channel, ...), etc."
11SECTION = "security"
12LICENSE = "GPL-2.0-only"
13
14LIC_FILES_CHKSUM = "file://LICENSE;md5=b234ee4d69f5fce4486a80fdaf4a4263"
15
16# If you want ptest support, use the git repo
17# UTscapy does not exist in the pypi pkg
18#
19SRCREV = "32cd7eb0f620d9adf171c48d55514e8326a538d7"
20SRC_URI = "git://github.com/secdev/scapy.git;branch=master;protocol=https \
21           file://run-ptest"
22
23S = "${WORKDIR}/git"
24
25UPSTREAM_CHECK_COMMITS = "1"
26
27inherit setuptools3 ptest
28
29do_install:append() {
30        mv ${D}${bindir}/scapy ${D}${bindir}/scapy3
31        mv ${D}${bindir}/UTscapy ${D}${bindir}/UTscapy3
32}
33
34do_install_ptest() {
35    install -m 0644 ${S}/test/regression.uts ${D}${PTEST_PATH}
36    sed -i 's,@PTEST_PATH@,${PTEST_PATH},' ${D}${PTEST_PATH}/run-ptest
37}
38
39RDEPENDS:${PN} = "tcpdump ${PYTHON_PN}-compression ${PYTHON_PN}-cryptography ${PYTHON_PN}-netclient  \
40                  ${PYTHON_PN}-netserver ${PYTHON_PN}-pydoc ${PYTHON_PN}-pkgutil ${PYTHON_PN}-shell \
41                  ${PYTHON_PN}-threading ${PYTHON_PN}-numbers"
42