xref: /OK3568_Linux_fs/yocto/meta-openembedded/meta-networking/recipes-daemons/postfix/postfix.inc (revision 4882a59341e53eb6f0b4789bf948001014eff981) 
1SUMMARY = "Postfix Mail Transport Agent"
2DESCRIPTION = "Postfix is Wietse Venema's mail server that started life at \
3IBM research as an alternative to the widely-used Sendmail program. \
4Postfix attempts to be fast, easy to administer, and secure. The outsidei \
5has a definite Sendmail-ish flavor, but the inside is completely different."
6
7HOMEPAGE= "http://www.postfix.org"
8SECTION = "mail"
9DEPENDS = "db icu libpcre libnsl2 m4-native openssl postfix-native \
10    ${@bb.utils.contains('DISTRO_FEATURES', 'ldap', 'openldap', '', d)} \
11    ${@bb.utils.contains('DISTRO_FEATURES', 'sasl', 'cyrus-sasl', '', d)} \
12"
13
14LICENSE = "IPL-1.0 | EPL-2.0"
15LIC_FILES_CHKSUM = "file://LICENSE;md5=b181651ad99a7dc4cc8c4ce2f491ed1a"
16
17S = "${WORKDIR}/postfix-${PV}"
18
19CLEANBROKEN = "1"
20
21BBCLASSEXTEND = "native"
22
23inherit pkgconfig update-rc.d useradd update-alternatives systemd lib_package
24
25INITSCRIPT_NAME = "postfix"
26INITSCRIPT_PARAMS = "start 58 3 4 5 . stop 13 0 1 6 ."
27USERADD_PACKAGES = "${PN}-bin"
28USERADD_PARAM:${PN}-bin = \
29"-d /var/spool/postfix -r -g postfix --shell /bin/false postfix; \
30 -d /var/spool/vmail -r -g vmail --shell /bin/false vmail \
31"
32GROUPADD_PARAM:${PN}-bin = "--system postfix;--system postdrop;--system vmail"
33
34export SYSLIBS = "${LDFLAGS}"
35
36# CCARGS specifies includes, defines
37# AUXLIBS specifies libraries
38# Linux2/Linux3 has HAS_DB defined
39# makedefs will make CC to be CC+CCARGS
40
41# ldap support
42export CCARGS-ldap  = "\
43    ${@bb.utils.contains('DISTRO_FEATURES', 'ldap', '-DHAS_LDAP', '', d)}"
44export AUXLIBS-ldap = "\
45    ${@bb.utils.contains('DISTRO_FEATURES', 'ldap', '-lldap -llber', '', d)}"
46
47# no native openldap
48export CCARGS-ldap:class-native = ""
49export AUXLIBS-ldap:class-native = ""
50
51export CCARGS-nonis:libc-musl = "-DNO_NIS"
52export CCARGS-nonis = ""
53
54# SASL support -DUSE_LDAP_SASL -DUSE_SASL_AUTH
55# current openldap didn't enable SASL
56export CCARGS-sasl  = "\
57    ${@bb.utils.contains('DISTRO_FEATURES', 'sasl', '-DUSE_SASL_AUTH -DUSE_CYRUS_SASL -I${STAGING_INCDIR}/sasl', '', d)}"
58export AUXLIBS-sasl = "\
59    ${@bb.utils.contains('DISTRO_FEATURES', 'sasl', '-lsasl2', '', d)}"
60export CCARGS-sasl:class-native = ""
61export AUXLIBS-sasl:class-native = ""
62
63# PCRE, TLS support default
64export CCARGS  = "${CFLAGS} -DHAS_PCRE -DUSE_TLS -I${STAGING_INCDIR}/openssl ${CCARGS-ldap} ${CCARGS-sasl} ${CCARGS-nonis}"
65export AUXLIBS = "-lpcre -lssl -lcrypto ${AUXLIBS-sasl} ${AUXLIBS-ldap}"
66export POSTCONF = "${STAGING_DIR_NATIVE}${sbindir_native}/postconf"
67
68# OPT,DEBUG is aready in CFLAGS
69# ignore the OPTS="CC=$CC" in Makefile it will not use the CC=$CC $CCARGS
70EXTRA_OEMAKE += "OPT= DEBUG= OPTS= "
71
72do_compile () {
73    unset CFLAGS CPPFLAGS CXXFLAGS
74    local native_build
75
76    native_build="${@['0', '1'][bb.data.inherits_class('native', d) or bb.data.inherits_class('nativesdk', d)]}"
77
78    # if not native build, then pass SYSTEM and RELEASE to makedefs
79    if [ "${native_build}" != "1" ]; then
80        # uname -s for target
81        SYSTEM="Linux"
82
83        # uname -r, use 2.6 as bottomline, even target kernel ver > 2.6
84        RELEASE="2.6.34"
85        sed -i -e \
86            "s:\$(SHELL) makedefs):\$(SHELL) makedefs $SYSTEM $RELEASE):" \
87            ${S}/Makefile.in
88        export BUILD_SYSROOT="${STAGING_DIR_HOST}"
89    else
90        # native build
91        export BUILD_SYSROOT="${STAGING_DIR_NATIVE}"
92    fi
93
94    oe_runmake makefiles
95    oe_runmake
96}
97
98do_install:prepend:class-native() {
99    export POSTCONF="bin/postconf"
100}
101
102SYSTEMD_SERVICE:${PN} = "postfix.service"
103
104do_install () {
105    sh ./postfix-install 'install_root=${D}' \
106        'config_directory=${sysconfdir}/postfix' \
107        'daemon_directory=${libexecdir}/postfix' \
108        'command_directory=${sbindir}' \
109        'queue_directory=${localstatedir}/spool/postfix' \
110        'sendmail_path=${sbindir}/sendmail.postfix' \
111        'newaliases_path=${bindir}/newaliases' \
112        'mailq_path=${bindir}/mailq' \
113        'manpage_directory=${mandir}' \
114        'readme_directory=${datadir}/doc/postfix' \
115        'data_directory=${localstatedir}/lib/postfix' \
116        -non-interactive
117    rm -rf ${D}${localstatedir}/spool/postfix
118    mv ${D}${sysconfdir}/postfix/main.cf ${D}${sysconfdir}/postfix/sample-main.cf
119    install -m 755 ${S}/bin/smtp-sink ${D}/${sbindir}/
120    install -d ${D}${sysconfdir}/init.d
121    install -m 644 ${WORKDIR}/main.cf ${D}${sysconfdir}/postfix/main.cf
122    sed -i 's#@LIBEXECDIR@#${libexecdir}#' ${D}${sysconfdir}/postfix/main.cf
123
124    install -m 755 ${WORKDIR}/check_hostname.sh ${D}${sbindir}/
125
126    install -m 755 ${WORKDIR}/postfix ${D}${sysconfdir}/init.d/postfix
127    install -m 644 ${WORKDIR}/internal_recipient ${D}${sysconfdir}/postfix/internal_recipient
128
129    install -d ${D}${systemd_unitdir}/system
130    install -m 0644 ${WORKDIR}/postfix.service ${D}${systemd_unitdir}/system
131    sed -i -e 's#@LIBEXECDIR@#${libexecdir}#g' ${D}${systemd_unitdir}/system/postfix.service
132    sed -i -e 's#@LOCALSTATEDIR@#${localstatedir}#g' ${D}${systemd_unitdir}/system/postfix.service
133    sed -i -e 's#@SBINDIR@#${sbindir}#g' ${D}${systemd_unitdir}/system/postfix.service
134
135    install -m 0755 ${WORKDIR}/aliasesdb ${D}${libexecdir}/postfix
136
137    install -m 770 -d ${D}${localstatedir}/spool/postfix
138    chown postfix:postfix ${D}${localstatedir}/spool/postfix
139
140    install -m 0755 -d ${D}${localstatedir}/lib/postfix
141    chown postfix:nogroup ${D}${localstatedir}/lib/postfix
142    install -m 0755 -d ${D}${localstatedir}/spool/postfix
143    chown root:postfix ${D}${localstatedir}/spool/postfix
144    install -m 0700 -d ${D}${localstatedir}/spool/postfix/active
145    chown postfix:root ${D}${localstatedir}/spool/postfix/active
146    install -m 0700 -d ${D}${localstatedir}/spool/postfix/bounce
147    chown postfix:root ${D}${localstatedir}/spool/postfix/bounce
148    install -m 0700 -d ${D}${localstatedir}/spool/postfix/corrupt
149    chown postfix:root ${D}${localstatedir}/spool/postfix/corrupt
150    install -m 0700 -d ${D}${localstatedir}/spool/postfix/defer
151    chown postfix:root ${D}${localstatedir}/spool/postfix/defer
152    install -m 0700 -d ${D}${localstatedir}/spool/postfix/deferred
153    chown postfix:root ${D}${localstatedir}/spool/postfix/deferred
154    install -m 0700 -d ${D}${localstatedir}/spool/postfix/flush
155    chown postfix:root ${D}${localstatedir}/spool/postfix/flush
156    install -m 0700 -d ${D}${localstatedir}/spool/postfix/hold
157    chown postfix:root ${D}${localstatedir}/spool/postfix/hold
158    install -m 0700 -d ${D}${localstatedir}/spool/postfix/incoming
159    chown postfix:root ${D}${localstatedir}/spool/postfix/incoming
160    install -m 0700 -d ${D}${localstatedir}/spool/postfix/saved
161    chown postfix:root ${D}${localstatedir}/spool/postfix/saved
162    install -m 0700 -d ${D}${localstatedir}/spool/postfix/trace
163    chown postfix:root ${D}${localstatedir}/spool/postfix/trace
164    install -m 0730 -d ${D}${localstatedir}/spool/postfix/maildrop
165    chown postfix:postdrop ${D}${localstatedir}/spool/postfix/maildrop
166    install -m 0755 -d ${D}${localstatedir}/spool/postfix/pid
167    chown root:root ${D}${localstatedir}/spool/postfix/pid
168    install -m 0700 -d ${D}${localstatedir}/spool/postfix/private
169    chown postfix:root ${D}${localstatedir}/spool/postfix/private
170    install -m 0710 -d ${D}${localstatedir}/spool/postfix/public
171    chown postfix:postdrop ${D}${localstatedir}/spool/postfix/public
172    install -m 0755 -d ${D}${localstatedir}/spool/vmail
173    chown vmail:vmail ${D}${localstatedir}/spool/vmail
174
175    chown :postdrop ${D}${sbindir}/postqueue
176    chown :postdrop ${D}${sbindir}/postdrop
177    chmod g+s ${D}${sbindir}/postqueue
178    chmod g+s ${D}${sbindir}/postdrop
179
180    rm -rf ${D}/etc/postfix/makedefs.out
181}
182
183do_install:append:class-native() {
184    ln -sf ../sbin/sendmail.postfix ${D}${bindir}/newaliases
185    ln -sf ../sbin/sendmail.postfix ${D}${bindir}/mailq
186}
187
188ALTERNATIVE:${PN}-bin = "sendmail mailq newaliases"
189# /usr/lib/sendmial is required by LSB core test
190ALTERNATIVE:${PN}-bin:linuxstdbase = "sendmail mailq newaliases usr-lib-sendmail"
191ALTERNATIVE_TARGET[mailq] = "${bindir}/mailq"
192ALTERNATIVE_TARGET[newaliases] = "${bindir}/newaliases"
193ALTERNATIVE_TARGET[sendmail] = "${sbindir}/sendmail.postfix"
194ALTERNATIVE_LINK_NAME[sendmail] = "${sbindir}/sendmail"
195ALTERNATIVE_TARGET[usr-lib-sendmail] = "${sbindir}/sendmail.postfix"
196ALTERNATIVE_LINK_NAME[usr-lib-sendmail] = "/usr/lib/sendmail"
197
198ALTERNATIVE_PRIORITY = "120"
199
200ALTERNATIVE:${PN}-doc += "mailq.1 newaliases.1 sendmail.1"
201ALTERNATIVE_LINK_NAME[mailq.1] = "${mandir}/man1/mailq.1"
202ALTERNATIVE_LINK_NAME[newaliases.1] = "${mandir}/man1/newaliases.1"
203ALTERNATIVE_LINK_NAME[sendmail.1] = "${mandir}/man1/sendmail.1"
204
205pkg_postinst_ontarget:${PN}-cfg () {
206    touch /etc/aliases
207    newaliases
208
209    # generate virtual_alias, default is hash
210    touch /etc/postfix/virtual_alias
211    postmap /etc/postfix/virtual_alias
212}
213
214PACKAGES =+ "${PN}-cfg"
215RDEPENDS:${PN}-cfg:class-target += "${PN}-bin"
216RDEPENDS:${PN}:class-target += "${PN}-cfg"
217# Exclude .debug directories from the main package
218FILES:${PN}-bin += "${localstatedir} ${bindir}/* ${sbindir}/* \
219               ${libexecdir}/* ${systemd_unitdir}/*"
220FILES:${PN}-cfg = "${sysconfdir}"
221FILES:${PN}-dbg += "${libexecdir}/postfix/.debug"
222ALLOW_EMPTY:${PN} = "1"
223