1SUMMARY = "High Availability monitor built upon LVS, VRRP and service pollers"
2DESCRIPTION = "Keepalived is a routing software written in C. The main goal \
3of this project is to provide simple and robust facilities for loadbalancing \
4and high-availability to Linux system and Linux based infrastructures. \
5Loadbalancing framework relies on well-known and widely used Linux Virtual \
6Server (IPVS) kernel module providing Layer4 loadbalancing \
7"
8HOMEPAGE = "http://www.keepalived.org/"
9
10LICENSE = "GPL-2.0-only"
11LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
12
13SRC_URI = "http://www.keepalived.org/software/${BP}.tar.gz \
14           file://0001-layer4-Change-order-of-include-files.patch \
15           "
16SRC_URI[sha256sum] = "103692bd5345a4ed9f4581632ea636214fdf53e45682e200aab122c4fa674ece"
17UPSTREAM_CHECK_URI = "https://github.com/acassen/keepalived/releases"
18
19DEPENDS = "libnfnetlink openssl"
20
21inherit autotools pkgconfig systemd
22
23PACKAGECONFIG ??= "libnl snmp \
24    ${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} \
25"
26PACKAGECONFIG[libnl] = "--enable-libnl,--disable-libnl,libnl"
27PACKAGECONFIG[snmp] = "--enable-snmp,--disable-snmp,net-snmp"
28PACKAGECONFIG[systemd] = "--with-init=systemd --with-systemdsystemunitdir=${systemd_system_unitdir},--with-init=SYSV,systemd"
29
30EXTRA_OEMAKE = "initdir=${sysconfdir}/init.d"
31
32do_install:append() {
33    if [ -f ${D}${sysconfdir}/init.d/${BPN} ]; then
34        chmod 0755 ${D}${sysconfdir}/init.d/${BPN}
35        sed -i 's#rc.d/##' ${D}${sysconfdir}/init.d/${BPN}
36    fi
37
38    if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
39        install -D -m 0644 ${B}/${BPN}/${BPN}.service ${D}${systemd_system_unitdir}/${BPN}.service
40    fi
41}
42
43FILES:${PN} += "${datadir}/snmp/mibs/KEEPALIVED-MIB.txt"
44
45SYSTEMD_SERVICE:${PN} = "keepalived.service"
46SYSTEMD_AUTO_ENABLE ?= "disable"
47